FilesExpand file tree

main

/

SideEffectInAssert.ql

Copy path

Blame

More file actions

Blame

More file actions

Latest commit

 

History

History

History

49 lines (44 loc) · 1.39 KB

main

/

SideEffectInAssert.ql

Copy path

Top

File metadata and controls

• Code
• Blame

49 lines (44 loc) · 1.39 KB

Raw

Copy raw file

Download raw file

Open symbols panel

Edit and raw actions

1

2

3

4

5

6

7

8

9

10

11

12

13

14

15

16

17

18

19

20

21

22

23

24

25

26

27

28

29

30

31

32

33

34

35

36

37

38

39

40

41

42

43

44

45

46

47

48

49

/**

* @name An assert statement has a side-effect

* @description Side-effects in assert statements result in differences between normal

* and optimized behavior.

* @kind problem

* @tags quality

* reliability

* correctness

* @problem.severity error

* @sub-severity low

* @precision high

* @id py/side-effect-in-assert

*/

import python

private import semmle.python.ApiGraphs

predicate func_with_side_effects(Expr e) {

exists(string name | name = e.(Attribute).getName() or name = e.(Name).getId() |

name in [

"print", "write", "append", "pop", "remove", "discard", "delete", "close", "open", "exit"

]

)

}

predicate call_with_side_effect(Call e) {

exists(ControlFlowNode eCfg | eCfg.getNode() = e |

eCfg =

API::moduleImport("subprocess")

.getMember(["call", "check_call", "check_output"])

.getACall()

.asCfgNode()

)

}

predicate probable_side_effect(Expr e) {

// Only consider explicit yields, not artificial ones in comprehensions

e instanceof Yield and not exists(Comp c | c.contains(e))

or

e instanceof YieldFrom

or

e instanceof Call and func_with_side_effects(e.(Call).getFunc())

or

e instanceof Call and call_with_side_effect(e)

}

from Assert a, Expr e

where probable_side_effect(e) and a.contains(e)

select a, "This 'assert' statement contains an $@ which may have side effects.", e, "expression"