Around
Around[x,δ]
represents an approximate number or quantity with a value around x and an uncertainty δ.
Around[x,{δ-,δ+}]
represents a number or quantity with a value around x and asymmetric uncertainties δ-, δ+.
Around[dist]
gives an approximate number or quantity around the mean of the distribution dist, with an uncertainty corresponding to the standard deviation of the distribution.
Around[list]
gives an approximate object around the mean of the elements of list and with an uncertainty corresponding to their standard deviation.
Around[s]
gives an approximate object derived from the number, interval or string specification s.
Details
- Around[x,δ] is typically displayed as x±δ. If δ is very small compared to x, as in Around[1.2345678,0.0000012], it is instead displayed in a form like
. - Around[x,δ] can be used to represent results of measurements in which there is statistical or other uncertainty.
- Around[x,Scaled[ϕ]] represents a number with relative error ϕ, corresponding to Around[x,ϕ x].
- When Around is used in computations, uncertainties are by default propagated using a first-order series approximation, assuming no correlations.
- Around[…]["prop"] can be used to extract the following properties:
-
"Value" central value x in Around[x,δ] "Uncertainty" uncertainty δ in Around[x,δ] "Number" number with value x and accuracy corresponding to δ "Interval" Interval[{x-δ,x+δ}] - In Around[s], numbers with uncertainty can be specified as follows:
-
x (approximate number) Around[x,(10^-Accuracy[x])/2] Interval[{xmin,xmax}] Around[(xmax+xmin)/2,(xmax-xmin)/2] dist (statistical distribution) Around[Mean[dist],StandardDeviation[dist]] list (list of elements) Around[Mean[list],StandardDeviation[list]] "nn.dddd" (number string) (uncertainty determined by number of significant digits) - For linear computations, Around[x,δ] behaves like a number whose values are distributed according to the normal distribution NormalDistribution[x,δ].
- Relational operators like Less, Equal and Greater on Around objects Around[x1,δ1] and Around[x2,δ2] return True or False depending on whether the distance between centers x1 and x2 is larger or smaller than 2
. Numbers are assigned zero uncertainty when compared to Around objects. - NumericalOrder orders numerical Around objects by their central value, ignoring the uncertainty.
- In Around[x,δ], the value x and the uncertainty δ can be any numeric or symbolic expressions. If δ is a numeric expression, then both x and δ will be made numerical. By default, machine precision will be used, but higher precision may be used if needed to represent the numbers faithfully.
- Around[x,δ] displays with one or two digits of the uncertainty δ shown; x is shown with the same number of digits to the right of the decimal point as is shown in δ.
- In Around[x,δ], x and δ can be quantities with different, though compatible, units.
- Around[{x1,x2,…},δ] threads over the list in its first argument, effectively treating the uncertainties in the xi as being uncorrelated.
Examples
open all close allBasic Examples (7)
Uncertain numbers of different sizes and uncertainties:
Around[1.3421, 0.012]Around[-1.3421 10 ^ -7, 1.2 10 ^ -8]Around[RandomReal[{-1, 1}], 10 ^ -8]Uncertain Quantity objects with different units:
Quantity[Around[140.764, 0.023], "Meters" / "Seconds"]Around[Quantity[23.425, "Meters"], Quantity[13, "Millimeters"]]UnitConvert[%, "Inches"]An Around object with asymmetric uncertainties:
Around[56.723, {0.18, 0.076}]Perform operations with Around objects:
Around[1, .1] + Around[2, .4]Exp[Around[2, .1]]Plot a list of Around objects:
ListPlot[{Around[1, .1], Around[2, .2], Around[3, .3]}]Extract the parts of an Around object:
a = Around[Sqrt[3], 0.012345]a["Value"]a["Uncertainty"]Two different instances of the same Around object are assumed to be uncorrelated:
Around[2, 0.1] + Around[2, 0.1]Therefore, the resulting uncertainty is smaller than that obtained by multiplication by 2:
2Around[2, 0.1]Scope (24)
Uncertain Objects (9)
Around[52.241, 0.123]Around[Sqrt[17], 0.73]Around[-17 / 2, 1 / 2]Around[21 ^ 21, 19 ^ 19]Around[0, 0.004]Uncertain numbers with asymmetric uncertainties:
Around[23.28, {0.31, 0.72}]Around[-23.28, {0.31, 0.72}]Around[Sqrt[101], {Sqrt[5], Sqrt[7]}]Specify a 5% relative uncertainty in input:
Around[4.1836, Scaled[0.05]]Around[4.1836, Scaled[Quantity[5, "Percent"]]]Uncertain Quantity objects:
Quantity[Around[1.73, 0.21], "Yards"]Use a value and an uncertainty of compatible units:
Around[Quantity[5, "Minutes"], Quantity[7, "Seconds"]]Use the same units in value and uncertainty:
Around[Quantity[100, "Kilometers" / "Hours"], Quantity[2, "Kilometers" / "Hours"]]The result is a single Quantity object with an Around magnitude:
InputForm[%]Use asymmetric uncertainties with compatible units:
Around[Quantity[3, "Meters"], {Quantity[5, "Centimeters"], Quantity[2, "Inches"]}]Values of different sizes for the same uncertainty:
Around[12.7172 10 ^ 7, 3.42]Around[12.7172, 3.42]Around[12.7172 10 ^ -7, 3.42]Uncertainties of different sizes for the same value:
Around[12.7172, 3.42]Around[12.7172, 3.42 10 ^ -7]Around[12.7172, 3.42 10 ^ 5]An uncertain number with 30% relative uncertainty:
Around[3.56, Scaled[0.3]]Express the same object using a Quantity percentage:
Around[3.56, Scaled[Quantity[30, "Percent"]]]Use Quantity values of any dimension:
Around[Quantity[-34.78, "Newtons"], Scaled[0.04]]Around[Quantity[-34.78, "Newtons"], Scaled[Quantity[4, "Percent"]]]Use a symbolic Around object:
a = Around[x, δ]a ^ 2Exp[a]Add symbolic Around objects, with uncertainties assumed to be uncorrelated:
Around[x, Subscript[δ, x]] + Around[y, Subscript[δ, y]]Accessors and Conversions (5)
Extract the value and uncertainty of an Around object:
a = Around[-12.4728, 0.0031]a["Value"]a["Uncertainty"]Construct a finite precision number from an Around object:
a = Around[-12.4728, 0.0031]number = a["Number"]Its accuracy coincides with the uncertainty of a:
Accuracy[number](10 ^ -%) / 2Reconstruct the original Around object from the finite-precision number:
Around[number]Construct an interval centered at the value of an Around object and with a semi-width given by its uncertainty:
a = Around[-12.4728, 0.0031]interval = a["Interval"]Reconstruct the original Around object from the interval:
Around[interval]Use Around to convert strings containing numbers, assuming uncertainty 0.5 in the last significant digit:
Around["1.23"]Around["1.2300"]Around["-1.23e7"]Around["-1.2300D-7"]Use Around to convert strings containing numbers with uncertainty:
Around["1.23+-0.06"]Around["-1.23±0.06"]Around["1.7861 pm 6.e-3"]Around["1.7861+0.0048-0.0023"]Operations with Uncertain Objects (4)
Basic operations with numbers:
Around[1, 0.5] + Around[4, 0.4]Around[1, 0.5] + Around[4, {0.7, 0.4}]Around[1, 0.5]Around[4, 0.4]Around[1, 0.5]Around[4, {0.7, 0.4}]Around[2, 0.1] ^ Around[4, 0.2]Around[2, 0.1] ^ Around[4, {0.7, 0.4}]Basic operations with Quantity objects:
Around[Quantity[1, "Meters"], Quantity[5, "Centimeters"]] + Around[Quantity[3, "Feet"], Quantity[2, "Inches"]]UnitConvert[%, "Inches"]Quantity[Around[10, 1], "Kilometers" / "Hours"]Around[Quantity[2, "Minutes"], Quantity[12, "Seconds"]]Construct a QuantityArray object whose elements are Around objects:
QuantityArray[{Quantity[Around[1, 0.1], "Farads"], Quantity[Around[2, 0.2], "Farads"]}]Perform operations, preserving the QuantityArray structure:
% ^ 2Normal[%]Basic operations with symbolic Around objects:
a = Around[x, δ]3aa ^ 4Log[5a]Tanh[a + 1]Comparisons and Ordering of Uncertain Objects (6)
Compare two Around objects with far apart centers:
a1 = Around[1.18, 0.24]
a2 = Around[4.3, 0.35]{a1 < a2, a1 <= a2, a1 == a2, a1 >= a2, a1 > a2}Their distance is significantly larger than zero:
a2 - a1Compare two Around objects with close centers:
a1 = Around[3.18, 0.34]
a2 = Around[3.55, 0.52]{a1 < a2, a1 <= a2, a1 == a2, a1 >= a2, a1 > a2}Their distance is not significantly larger than zero:
a2 - a1Compare an Around object with a number:
a = Around[2.73, 0.12]x = 2{a < x, a <= x, a == x, a >= x, a > x}The distance is significantly larger than zero:
a - 2Compare Around objects with Quantity centers and uncertainties:
a1 = Around[Quantity[4, "Feet"], Quantity[2, "Inches"]]a2 = Around[Quantity[1, "Meters"], Quantity[2, "Centimeters"]]{a1 < a2, a1 <= a2, a1 == a2, a1 >= a2, a1 > a2}The distance between them is significantly larger than zero:
a1 - a2//UnitConvertOrder numerically a collection of Around objects and numbers:
arounds = Inner[Around, RandomReal[10, 4], RandomReal[2, 4], List]numbers = RandomReal[10, 4]NumericalSort[Join[arounds, numbers]]Order numerically a collection of velocities:
NumericalSort[{Around[Quantity[4., "Meters"/"Seconds"], Quantity[20., "Centimeters"/"Seconds"]], Quantity[Around[5.3, 0.5], "Kilometers"/"Hours"], Quantity[Around[6.2, 0.4], "Knots"]}]Convert to a common base unit to compare values directly:
%//UnitConvertApplications (3)
ListPlot[Table[Around[n, RandomReal[3]], {n, 20}]]Plot exoplanet radius versus mass, including uncertainties in both variables:
rmdata = DeleteMissing[ExoplanetData[EntityClass["Exoplanet", All], {EntityProperty["Exoplanet", "Mass", {"Uncertainty" -> "Around"}], EntityProperty["Exoplanet", "Radius", {"Uncertainty" -> "Around"}]}], 1, 1];Length[rmdata]Take[rmdata, 3]ListPlot[rmdata, ...]Compute the mean value of the masses and radii:
meanM = Mean[rmdata[[All, 1]]]meanR = Mean[rmdata[[All, 2]]]Compare with the mass and radius of the Earth:
meanM / Entity["Planet", "Earth"]["Mass"]meanR / Entity["Planet", "Earth"]["Radius"]Compute the period of oscillation of a pendulum of 
length, using a value of 
for Earth's gravity and assuming an uncertainty of one unit in the last significant digit of those quantities:
First@FormulaData[{"PendulumSmallOscillations", "Standard", "Period"}]% /. {l -> Quantity[Around[75, 1], "Centimeters"], g -> Quantity[Around[9.80, 0.01], "Meters" / "Seconds" ^ 2]}Properties & Relations (3)
Square an Around object, using a first-order series approximation:
Around[10, 1] ^ 2Perform the corresponding exact computation using TransformedDistribution:
dist = TransformedDistribution[s ^ 2, sNormalDistribution[10, 1]]Around[Mean[dist], StandardDeviation[dist]]Using a higher-order series expansion gives a better approximation to the exact result:
AroundReplace[s ^ 2, s -> Around[10, 1], 2]Using Around directly on the asymmetric distribution returns an object with asymmetric uncertainty:
Around[dist]Take a normal distribution and simulate it:
dist = NormalDistribution[5, 0.3];scalars = RandomVariate[dist, 100];Around[scalars] estimates the mean and standard deviation of the distribution:
Around[scalars]Around[dist] gives the true parameters in the distribution dist:
Around[dist]MeanAround[scalars] describes the mean of the distribution and the standard error of the mean:
MeanAround[scalars]Around[x,δ] and CenteredInterval[x,δ] use different propagation rules in numeric operations:
a = Around[12, 1]a ^ 3c = CenteredInterval[12, 1]c ^ 3Text
Wolfram Research (2019), Around, Wolfram Language function, https://reference.wolfram.com/language/ref/Around.html (updated 2023).
CMS
Wolfram Language. 2019. "Around." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/Around.html.
APA
Wolfram Language. (2019). Around. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Around.html