BodePlot
Details and Options
- BodePlot plots the magnitude and phase of the transfer function of lsys.
- The system lsys can be TransferFunctionModel or StateSpaceModel, including descriptor and delay systems.
- For a system lsys with the corresponding transfer function
, the following expressions are plotted: -
continuous-time system 
discrete-time system with sample time 
- BodePlot treats the variable ω as local, effectively using Block.
- BodePlot has the same options as Plot, with the following changes and additions: [List of all options]
-
Exclusions None frequencies to exclude FeedbackType "Negative" the feedback type Frame True whether to draw a frame around each plot MeshFunctions {{#1&},{#1&}} how to determine the placement of mesh divisions PhaseRange Automatic range of phase values to use PlotLayout "VerticalGrid" the layout to be used PlotRange {{Full,Automatic},{Full,Automatic}} range of values to include SamplingPeriod None the sampling period ScalingFunctions {{"Log10","dB"},{"Log10","Degree"}} the scaling functions StabilityMargins False whether to show the stability margins StabilityMarginsStyle Automatic graphics directives to specify the style of the stability margins - ColorData["DefaultPlotColors"] gives the default sequence of colors used by PlotStyle.
- Possible explicit settings for the option PlotLayout are "VerticalGrid" and "List".
- The option PlotLayout accepts the following values:
-
"VerticalGrid" magnitude and phase plot in a vertical grid { 
,
}"List" magnitude and phase plot in a list 
"Magnitude" magnitude plot only 
"Phase" phase plot only - The other options of BodePlot can be specified as a list of two elements, with the first element corresponding to the magnitude plot and the second to the phase plot.
- Option specifications include:
-
opt->val use val for both the magnitude and the phase plot opt->{val} use val for the magnitude plot and the default for the phase plot opt->{val1,val2} use val1 for the magnitude plot and val2 for the phase plot opt->{Automatic,val} use the default for the magnitude plot and val for the phase plot - With the PlotLayout settings "Magnitude" or "Phase", a single setting refers to the plot requested.
- The scaling functions can be specified as ScalingFunctions->{{magfreqscale,magscale},{phasefreqscale,phasescale}}.
- The frequency scales magfreqscale and phasefreqscale can be "Log10" or "Linear", which correspond to the base-10 logarithmic scale and linear scale, respectively.
- The magnitude scale magscale can be "dB" or "Absolute", which correspond to the decibel and absolute values of the magnitude, respectively.
- The phase scale phasescale can be "Degree" or "Radian".
List of all options
Examples
open all close allBasic Examples (3)
BodePlot[TransferFunctionModel[{{{20}}, 20 + s}, s]]lsys[ω_, ζ_] := TransferFunctionModel[{{{ω^2}}, s^2 +
2*s*ζ*ω + ω^2}, s];Plot over an explicit frequency range:
BodePlot[lsys[1, 1], {.01, 100}]Bode plot of a state-space model:
BodePlot[StateSpaceModel[{{{0, 1}, {-0.5, -0.05}}, {{0}, {1}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None,
SystemsModelLabels -> None]]Scope (13)
Bode plot of a constant-gain system:
BodePlot[TransferFunctionModel[{{{10}}, 1}, s]]BodePlot[TransferFunctionModel[{{{1}}, s}, s]]Bode plot of a differentiator:
BodePlot[TransferFunctionModel[{{{s}}, 1}, s]]Bode plot of a first-order lag:
BodePlot[TransferFunctionModel[{{{1}}, 1 + 10*s}, s]]Bode plot of a first-order lead:
BodePlot[TransferFunctionModel[{{{1 + 10*s}}, 1}, s]]Bode plot of a second-order system:
BodePlot[TransferFunctionModel[{{{100}}, 100 + 1.*s + s^2}, s]]A higher-order TransferFunctionModel:
BodePlot[TransferFunctionModel[{{{5*(1 + 0.1*s)}}, s + 0.512*s^2 +
0.0064*s^3 + 0.0002*s^4}, s]]Bode plot of a time-delay system:
BodePlot[TransferFunctionModel[{{{E^(-0.5*s)}}, 1. + 2.*s}, s]]BodePlot[TransferFunctionModel[{{{-0.9 + z}}, -0.8 + z}, z,
SamplingPeriod -> 1]]BodePlot[TransferFunctionModel[{{{-4 + 4.9*z}}, (-4.5 + z)*(-1 + z)},
z, SamplingPeriod -> 1], {0.05, (π/2)}]The Bode plot of a state-space model:
BodePlot[StateSpaceModel[{{{-1, 10, 0}, {-2, -7, 335}, {0, 0, -10}}, {{0}, {0}, {10}}, {{1, 0, 0}}, {{0}}},
SamplingPeriod -> None, SystemsModelLabels -> None]]A system specified using its sinusoidal transfer function:
BodePlot[(10/20ω I + 1), {ω, 0.0005, 10}]The Bode plot of a multiple-input, multiple-output system:
BodePlot[TransferFunctionModel[{{{2, 1}, {0.5, 0.1}}, {{1 + s, 2 + s},
{3 + s, 4 + s}}}, s]]Generalizations & Extensions (1)
Options (21)
CoordinatesToolOptions (5)
To obtain coordinates, select the graphics and press the period key:
BodePlot[TransferFunctionModel[{{{2500}}, 15500 + 400*s + s^2}, s]]If frequency is in rad/s, obtain coordinate frequency values in hertz by dividing it by 
:
BodePlot[TransferFunctionModel[{{{4}}, 4 + 2*s + s^2}, s], CoordinatesToolOptions -> ("DisplayFunction" -> Function[pt, {(pt[[1]]/2 π), pt[[2]]}])]Coordinate frequency values in different units for each plot:
BodePlot[TransferFunctionModel[{{{16}}, (1 + s)*(4 + s)^2}, s], CoordinatesToolOptions -> {"DisplayFunction" -> Function[pt, {(pt[[1]]/2 π), pt[[2]]}]}]Frequency values in original units, magnitude in absolute units, and phase in radians:
BodePlot[TransferFunctionModel[{{{5}}, s*(10 + 6*s + s^2)},
s], CoordinatesToolOptions -> {{"DisplayFunction" -> Function[pt, {pt[[1]], 10^(pt[[2]]/20)}]}, {"DisplayFunction" -> Function[pt, {pt[[1]], pt[[2]] Degree}]}}]Specify radians as both the displayed and copied value of phase:
BodePlot[TransferFunctionModel[{{{100*s}}, 1 + s}, s], CoordinatesToolOptions -> {Automatic, {"DisplayFunction" -> Function[pt, {pt[[1]], pt[[2]] Degree}], "CopiedValueFunction" -> Function[pt, {pt[[1]], pt[[2]]Degree}]}}]GridLines (3)
BodePlot[TransferFunctionModel[{{{1.6}}, 1.6 + 3*s + s^2}, s], GridLines -> Automatic]Show grid lines only on the magnitude plot:
BodePlot[TransferFunctionModel[{{{10}}, (2 + s)*(4 + s)*(6 + s)},
s], GridLines -> {Automatic, None}]BodePlot[TransferFunctionModel[{{{1}}, s^2*(3 + s + s^2)},
s], GridLines -> {{List[0.01, 0.1, 1, 10], Range[-150, 140, 20]}, {List[0.01, 0.1, 1, 10], Range[0, 200, 25]}}]GridLinesStyle (2)
BodePlot[TransferFunctionModel[{{{1}}, 10 + 3*s + s^3}, s], GridLines -> Automatic, GridLinesStyle -> Red]Specify different grid lines styles:
BodePlot[TransferFunctionModel[{{{1 + s}}, s*(2 + s)*
(3 + s)}, s], GridLines -> Automatic, GridLinesStyle -> {{Green, Orange}, {Red, Orange}}]PhaseRange (1)
PlotLayout (1)
By default, the magnitude plot is placed vertically above the phase plot:
tfm = TransferFunctionModel[{{{-5 + s}},
s*(1 + 3*s + s^2)}, s];BodePlot[tfm, PlotLabel -> {"Magnitude Plot", "Phase Plot"}]BodePlot[tfm, PlotLayout -> "list", PlotLabel -> {"magnitude", "phase"}]BodePlot[tfm, PlotLayout -> "Magnitude"]BodePlot[tfm, PlotLayout -> "Phase"]PlotTheme (2)
SamplingPeriod (2)
Specify the sampling period in the system description:
tfm = TransferFunctionModel[{{{0.5}}, (-0.1 + z)*z^2}, z,
SamplingPeriod -> 1];BodePlot[tfm, {0.1, Pi}]Specify the sampling period in the BodePlot function:
BodePlot[(5/(-0.1 + z) z^2), {0.1, π}, SamplingPeriod -> 1]A smaller sampling period results in a higher bandwidth:
BodePlot[(5/(-0.1 + z) z^2), {0.1, π}, SamplingPeriod -> 0.5]ScalingFunctions (2)
Show absolute values of magnitude and phase in radians:
BodePlot[TransferFunctionModel[{{{1}}, (1 + s)*(1 + 10*s)}, s], {0.1, 10}, ScalingFunctions -> {{Automatic, "Absolute"}, {Automatic, "Radian"}}]Plot frequency in the linear scale:
BodePlot[TransferFunctionModel[{{{1 + s}}, 1 + 5*s + s^2},
s], {0.1, 10}, ScalingFunctions -> {{"Linear", Automatic}, {"Linear", Automatic}}]StabilityMargins (2)
Applications (7)
The static position error constant of a type 0 system is the magnitude at steady state:
BodePlot[TransferFunctionModel[{{{10}}, 1 + s}, s], {0.001, 10}, Epilog -> {PointSize[Medium], Red, Point[{Log10[0.001], 20 Log10[Limit[(10/s + 1), s -> 0]]}]}, PlotRange -> {{0.0008, 10}, Automatic}, PlotLayout -> "Magnitude", Frame -> False]BodePlot[ TransferFunctionModel[{{{z}}, (-0.6 + z)*(-0.05 + z)},
z, SamplingPeriod -> 0.5], {0.001, (π/0.5)}, Epilog -> {PointSize[Medium], Red, Point[{Log10[0.001], 20 Log10[Limit[(z/(z - 0.05) (z - 0.6)), z -> 1]]}]}, PlotRange -> {{0.0008, (π/0.5)}, Automatic}, PlotLayout -> "Magnitude", Frame -> False]The static velocity error constant of a type 1 system is approximately the intersection of the initial 
dB/decade segment (or its extension) with the 0 dB line:
BodePlot[TransferFunctionModel[{{{5}}, s*(3 + s)}, s], {0.1, 100}, Epilog -> {Line[{{Log10[0.1], 0}, {Log10[100], 0}}], PointSize[Large], Red, Point[{ Log10[Limit[s (5 /s(s + 3)), s -> 0]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]BodePlot[TransferFunctionModel[{{{1}}, (-1 + z)*(-0.025 + z)}, z,
SamplingPeriod -> 1], {0.1, π}, Epilog -> {Line[{{Log10[0.1], 0}, {Log10[π], 0}}], PointSize[Medium], Red, Point[{Log10[Limit[(z - 1/(z - 1) (z - 0.025)), z -> 1]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]The square root of the static acceleration error constant of a type 2 system is approximately the intersection of the initial 
dB/decade segment (or its extension) with the 0 dB line:
BodePlot[TransferFunctionModel[{{{1}}, s^2*(1 + s)}, s], {0.1, 10}, Epilog -> {Line[{{Log10[0.1], 0}, {Log10[10], 0}}], PointSize[Medium], Red, Point[{ Log10[Sqrt[Limit[s^2(1/s^2(s + 1)), s -> 0]]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]BodePlot[TransferFunctionModel[{{{0.0001*z}}, (-1 + z)^2*
(0.1 - 0.3*z + z^2)}, z, SamplingPeriod -> 1], {0.001, π}, Epilog -> {Line[{{Log10[0.001], 0}, {Log10[π], 0}}], PointSize[Medium], Red, Point[{Log10[Sqrt[Limit[((z - 1)^2 (0.0001 z)/(z - 1)^2 (z^2 - 0.3 z + 0.1)), z -> 1]]], 0}]}, PlotLayout -> "Magnitude", Frame -> False]Visualize the improvement in phase margin by using a proportional-integral (PI) compensator:
BodePlot[{Tooltip[TransferFunctionModel[{{{583900}}, s*(36 + s)*(100 + s)},
s]], Tooltip[TransferFunctionModel[{{{36786*(0.98 + s)}}, s*(0.062 + s)*
(36 + s)*(100 + s)}, s]]}, StabilityMargins -> {True, True}, StabilityMarginsStyle -> {RGBColor[0.24, 0.6, 0.8], RGBColor[0.95, 0.627, 0.1425]}, PlotStyle -> {RGBColor[0.24, 0.6, 0.8], RGBColor[0.95, 0.627, 0.1425]}, PlotLayout -> "Phase", Frame -> False]Visualize the frequency response of a zero-order hold with sampling period 1:
BodePlot[TransferFunctionModel[{{{(-1 + E^s)/E^s}}, s},
s], {0.01, 30}, ScalingFunctions -> {{"Linear", "Absolute"}, {"Linear", "Degree"}}, PlotRange -> All]Obtain the Bode plot with frequency in Hertz, when the Laplace variable is in radians/second:
tfm = TransferFunctionModel[{{{100}}, s*(100 + 10*s + s^2)},
s];BodePlot[tfm[I 2 π f], f]For continuous-time systems, the same result can be obtained by scaling the Laplace variable:
BodePlot[tfm[2 π s]]The plot in Hertz for a discrete-time system with the Z-transform variable in radians/second:
BodePlot[(-0.4 + E^2 I f π/0.5 + E^2 I f π), f, SamplingPeriod -> 1]Properties & Relations (1)
SingularValuePlot generalizes the Bode magnitude plot to MIMO systems:
tfm = TransferFunctionModel[{{{10000}}, (5 + s)*(20 + s)*
(50 + s)}, s];{SingularValuePlot[tfm], BodePlot[tfm, PlotLayout -> "Magnitude", Frame -> False]}Text
Wolfram Research (2010), BodePlot, Wolfram Language function, https://reference.wolfram.com/language/ref/BodePlot.html (updated 2014).
CMS
Wolfram Language. 2010. "BodePlot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/BodePlot.html.
APA
Wolfram Language. (2010). BodePlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BodePlot.html