FiniteFieldEmbedding
FiniteFieldEmbedding[ff1,ff2]
gives an embedding of the finite field ff1 in the finite field ff2.
FiniteFieldEmbedding[e1e2]
represents the embedding of the ambient field of e1 in the ambient field of e2, which maps e1 to e2.
Details
- Finite field embeddings are also known as Galois field embeddings or finite field monomorphisms.
- Finite field embeddings are typically used to identify one finite field with a subfield of another.
- If ℰ=FiniteFieldEmbedding[e1e2], where e1∈ff1 and e2∈ff2, then
maps ff1 into ff2, 
, and 
for all 
. - A finite field ff1 can be embedded in ff2 if it has the same characteristic as ff2 and its extension degree divides that of ff2.
- Finite field elements e1∈ff1 and e2∈ff2 define a field embedding of ff1 in ff2 iff they have the same MinimalPolynomial and e1 generates ff1. The latter condition is satisfied iff the degree of the minimal polynomial of e1 is equal to the extension degree of ff1 over
. - For an embedding ℰ=FiniteFieldEmbedding[e1e2], ℰ["Projection"] represents a linear mapping
from the ambient field ff2 of e2 onto the ambient field ff1 of e1, treated as vector spaces over 
, such that 
for all 
.
Examples
open all close allBasic Examples (1)
Represent finite fields 
and 
with characteristic 
and extension degrees 
and 
:
{𝒦, ℱ} = {FiniteField[17, 3], FiniteField[17, 6]}
ℰ = FiniteFieldEmbedding[𝒦, ℱ]Map an element of 
through the embedding:
ℰ[𝒦[123]]
ℰ["Projection"][%]Scope (3)
Represent finite fields 
and 
with characteristic 
and extension degrees 
and 
:
{𝒦, ℱ} = {FiniteField[29, 4], FiniteField[29, 12]}
ℰ = FiniteFieldEmbedding[𝒦, ℱ]A field embedding preserves addition and multiplication:
{a, b} = {𝒦[123], 𝒦[456]}ℰ[a + b] == ℰ[a] + ℰ[b]ℰ[a b] == ℰ[a]ℰ[b]ℰ["Projection"] is a 
-linear mapping but does not preserve multiplication:
{c, d} = {ℱ[123], ℱ[456]}ℰ["Projection"][2c + 3d] == 2ℰ["Projection"][c] + 3ℰ["Projection"][d]ℰ["Projection"][c d] == ℰ["Projection"][c]ℰ["Projection"][d]The composition of ℰ["Projection"] with 
is the identity on 
:
ℰ["Projection"][ℰ[a]] == aThe reverse composition is not the identity on 
:
ℰ[ℰ["Projection"][c]] == cSpecify a field embedding by manually picking a generator and its value:
{𝒦, ℱ} = {FiniteField[97, 4], FiniteField[97, 8]};
a = 𝒦[123]a generates 
if the degree of its minimal polynomial equals the extension degree of 
:
f = MinimalPolynomial[a, x]
Factor[f, Extension -> ℱ]b = -FiniteFieldElement[FiniteField[97, 5 + 32*#1 + #1^2 + 65*#1^3 + #1^8 & , "Polynomial"],
{19, 90, 24, 20, 11, 95, 91, 9}]Represent the embedding of 
in 
that maps a to b:
ℰ = FiniteFieldEmbedding[a -> b]For the embedding to exist, both fields need to have the same characteristic:
FiniteFieldEmbedding[FiniteField[2, 3], FiniteField[3, 6]]
The extension degree of the first field needs to divide the extension degree of the second field:
FiniteFieldEmbedding[FiniteField[2, 4], FiniteField[2, 6]]
Applications (1)
Factor a polynomial in an algebraic extension of a finite field:
𝒦 = FiniteField[59, 3];
f = 𝒦[123]x ^ 2 + 𝒦[234]x + 𝒦[345]IrreduciblePolynomialQ[f]Embed 
in a finite field with 
elements:
ℱ = FiniteField[59, 6];
ℰ = FiniteFieldEmbedding[𝒦, ℱ]ff = f /. a_FiniteFieldElement :> ℰ[a]Factor[ff]Use the Extension option to combine the last two steps:
Factor[f, Extension -> ℰ]Properties & Relations (4)
A field embedding preserves addition and multiplication:
{𝒦, ℱ} = {FiniteField[7, 3], FiniteField[7, 9]};
ℰ = FiniteFieldEmbedding[𝒦, ℱ];{a, b} = {𝒦[123], 𝒦[456]}ℰ[a + b] == ℰ[a] + ℰ[b]ℰ[a b] == ℰ[a]ℰ[b]ℰ["Projection"] is a 
-linear mapping but does not preserve multiplication:
{c, d} = {ℱ[123], ℱ[456]}ℰ["Projection"][2c + 3d] == 2ℰ["Projection"][c] + 3ℰ["Projection"][d]ℰ["Projection"][c d] == ℰ["Projection"][c]ℰ["Projection"][d]The composition of ℰ["Projection"] with 
is the identity on 
:
ℰ["Projection"][ℰ[a]] == aThe reverse composition is not the identity on 
:
ℰ[ℰ["Projection"][c]] == c
ℱ = FiniteField[71, 5];
aut = FiniteFieldEmbedding[ℱ, ℱ]All finite field automorphisms are functional powers of the Frobenius automorphism:
Table[FrobeniusAutomorphism[ℱ[71], k], {k, 4}]Here aut[a]==FrobeniusAutomorphism[a,4]:
aut[ℱ[1234]] == FrobeniusAutomorphism[ℱ[1234], 4]An embedding allows identifying 
with a subfield of 
:
{𝒦, ℱ} = {FiniteField[43, 3], FiniteField[43, 6]};
ℰ = FiniteFieldEmbedding[𝒦, ℱ]Use FiniteFieldElementTrace to compute 
:
FiniteFieldElementTrace[ℱ[123], ℰ]Use FiniteFieldElementNorm to compute 
:
FiniteFieldElementNorm[ℱ[123], ℰ]Use MinimalPolynomial to find the minimal polynomial of an element of 
over 
:
MinimalPolynomial[ℱ[123], x, ℰ]Use Composition to compose finite field embeddings:
𝒦 = FiniteField[71, 3];
ℱ = FiniteField[71, 6];
𝒢 = FiniteField[71, 12];
Subscript[ℰ, 1] = FiniteFieldEmbedding[𝒦, ℱ];
Subscript[ℰ, 2] = FiniteFieldEmbedding[ℱ, 𝒢];
Subscript[ℰ, 21] = Subscript[ℰ, 2] @* Subscript[ℰ, 1]Subscript[ℰ, 21][𝒦[123]] == Subscript[ℰ, 2][Subscript[ℰ, 1][𝒦[123]]]Text
Wolfram Research (2023), FiniteFieldEmbedding, Wolfram Language function, https://reference.wolfram.com/language/ref/FiniteFieldEmbedding.html.
CMS
Wolfram Language. 2023. "FiniteFieldEmbedding." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FiniteFieldEmbedding.html.
APA
Wolfram Language. (2023). FiniteFieldEmbedding. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FiniteFieldEmbedding.html