GibbsPointProcess[{"PairPotential",μ, ϕ}, d]
represents a Gibbs point process with density μ and pair-potential function ϕ in 
.
GibbsPointProcess[{"PairInteraction",μ, h}, d]
represents a Gibbs point process with density μ and pair-interaction function h in 
.
GibbsPointProcess[{"Papangelou",λ*}, d]
represents a Gibbs point process with Papangelou conditional density 
in 
.
GibbsPointProcess[{"Density",f}, d]
represents a Gibbs point process with density function proportional to f in 
.
GibbsPointProcess
GibbsPointProcess[{"PairPotential",μ, ϕ}, d]
represents a Gibbs point process with density μ and pair-potential function ϕ in 
.
GibbsPointProcess[{"PairInteraction",μ, h}, d]
represents a Gibbs point process with density μ and pair-interaction function h in 
.
GibbsPointProcess[{"Papangelou",λ*}, d]
represents a Gibbs point process with Papangelou conditional density 
in 
.
GibbsPointProcess[{"Density",f}, d]
represents a Gibbs point process with density function proportional to f in 
.
Details
- GibbsPointProcess is also known as a Markov point process.
- The Gibbs model is typically used to model interaction between points, such as trees or plants competing for resources, or particles repulsing or attracting each other.
- Gibbs point processes that only have interactions between pairs of points can be specified in terms of their density function
and the radial pair potential function 
or a pair interaction function 
. - The density function
is a non-negative function of position 
and models the expected number points in a neighborhood of 
if no point interactions are present. - The pair potential
is a real function of the distance between points; higher values of 
mean it is less likely to find two points at distance 
from each other. - The pair interaction
, given by 
, is a non-negative function of the distance between points; a higher value of 
indicates that it is more likely to find two points at distance 
from each other. - GibbsPointProcess can represent any Gibbs point process; common Gibbs processes have dedicated implementations and are easier to use:
-
process pair potential 
characteristic HardcorePointProcess 
hardcore interaction StraussPointProcess 
constant strength softcore interaction StraussHardcorePointProcess 
inner hardcore with an outer softcore PenttinenPointProcess 
interaction based on overlapping area DiggleGrattonPointProcess 
inner hardcore with decreasing softcore DiggleGatesPointProcess 
smooth transition from point hardcore - More general Gibbs point processes can be specified in terms of either their Papangelou density
or probability density 
. - The Papangelou density
specifies the cost of adding a point 
to collection of points 
and needs to be a non-negative function. - The density
specifies the probability density of a point configuration. The function f needs to be non-negative, but not necessarily normalized. - GibbsPointProcess allows d to be any positive integer.
- All specifications have an equivalent Papangelou density λ* given by:
-
{"PairPotential",μ,ϕ} ![mu exp(-sum_iphi(TemplateBox[{{{p, _, i}, -, q}}, Norm]))](Files/GibbsPointProcess.en/32.png "mu exp(-sum_iphi(TemplateBox[{{{p, _, i}, -, q}}, Norm]))")
{"PairInteraction",μ,h} ![mu product_ip(TemplateBox[{{{p, _, i}, -, q}}, Norm])](Files/GibbsPointProcess.en/33.png "mu product_ip(TemplateBox[{{{p, _, i}, -, q}}, Norm])")
.{"Density",f} 
- GibbsPointProcess can be used with such functions as RipleyK and RandomPointConfiguration.
Examples
open all close allBasic Examples (1)
Sample a Poisson point process by GibbsPointProcess with the appropriate density function:
h = Function[pts, 100 ^ Length[pts]];pts = RandomPointConfiguration[GibbsPointProcess[{"Density", h}, 2], Disk[]]Plot the points over the region:
Show[RegionPlot[pts["ObservationRegion"]], ListPlot[pts]]Scope (4)
Simulate a Gibbs point process with density proportional to the number of points:
β = 30;
h = Function[pts, β ^ Length[pts]];Use the Markov chain Monte Carlo method to simulate 40 samples over a unit disk:
n = 40;
region = Disk[];sample = RandomPointConfiguration[GibbsPointProcess[h, 2], region, n, Method -> {"MCMC", "LengthOfRun" -> 10000}]Compute the average number of points in the region:
Mean[sample["PointCountList"]]//NCompare to the scaled area of the region:
val = β RegionMeasure[region]//NListPlot[{sample["PointCountList"], {{0, val}, {n, val}}}, Joined -> {False, True}]Sample a Strauss point process by GibbsPointProcess:
pairWiseDists[{}] := {}
pairWiseDists[pts_] := Block[{tp = pts}, Table[EuclideanDistance[pt, #]& /@ (tp = Rest[tp]), {pt, Most[pts]}]]straussDensity[gamma_, beta_, R_] := Function[pts, Block[{dists, n = Length[pts]},
dists = Total[Clip[Flatten[pairWiseDists[pts]], {0, R}, {0, 0}]];
beta ^ n * gamma ^ dists
]
];a = RandomPointConfiguration[GibbsPointProcess[straussDensity[.8, 30, 1], 2], Disk[], 1]Sample the same process by specifying the Papangelou conditional density:
straussPapangelouDensity[gamma_, beta_, R_] := Function[{pts, newpt},
beta * gamma ^ Total[Clip[EuclideanDistance[newpt, #]& /@ pts, {0, R}, {0, 0}]]
];b = RandomPointConfiguration[GibbsPointProcess[{"Papangelou", straussPapangelouDensity[.8, 30, 1]}, 2], Disk[], 1]Sample the same process by specifying the pair potential function:
ϕ[γ_, R_] := Function[r, -Log[γ]Boole[r ≤ R]];c = RandomPointConfiguration[GibbsPointProcess[{"PairPotential", 30, ϕ[.8, 1]}, 2], Disk[], 1]Show[RegionPlot[Disk[]], ListPlot[#]]& /@ {a, b, c}Sample from a hardcore point process with radius 0.3 with respect to a Poisson point process with density 
:
R = .3;
reg = Rectangle[{-3, -3}, {3, 3}];μ = Exp[Total[#]]&;
ϕ[R_] = Piecewise[{{∞, # < R}}]&;pts1 = RandomPointConfiguration[GibbsPointProcess[{"PairPotential", μ, ϕ[R]}, 2], reg]Show[RegionPlot[reg], ListPlot[pts1]]pts = pts1["Points"];
dsk = Disk[#, R / 2]& /@ pts;
Show[RegionPlot[reg], Graphics[{{Orange, dsk}, {PointSize[Tiny], Point[pts]}}, Frame -> True]]Compare to the corresponding inhomogeneous Poisson point process simulation:
pts2 = RandomPointConfiguration[InhomogeneousPoissonPointProcess[Function[{x, y}, Exp[x + y]], 2], reg]
Show[RegionPlot[reg], ListPlot[pts2]]Simple Gibbs point processes like the StraussHardcorePointProcess have densities that can be expressed solely in terms of the intensity 
and pair potential 
, but this is not true in general. A point process that depends on the area of the union of disks around the points has interactions that depend on all possible subsets of points, like the density function below demonstrates:
f[β_, γ_, r_] := Function[pts,
With[{len = Length[pts]},
If[len === 0,
1,
β ^ len * γ ^ Area@DiscretizeRegion [RegionUnion@@(Disk[#, r]& /@ pts)]
]
]
]Define a Gibbs point process with this density:
proc = GibbsPointProcess[{"Density", f[20, .3, .1]}, 2];Simulate a point pattern from the process:
pts = RandomPointConfiguration[proc, Disk[], Method -> {"MCMC", "LengthOfRun" -> 100}]Visualize the points with surrounding disks:
Graphics[{Opacity[.5], Disk[#, .1]& /@ pts["Points"]}]Properties & Relations (1)
Compare numbers of points generated with a PoissonPointProcess and a GibbsPointProcess with the appropriate density:
β = 30;
h = Function[pts, β ^ Length[pts]];
region = Disk[];
n = 20;sample1 = RandomPointConfiguration[GibbsPointProcess[h, 2], region, n, Method -> {"MCMC", "LengthOfRun" -> 30000}]sample2 = RandomPointConfiguration[PoissonPointProcess[β, 2], region, n]Compute the average number of points in the region for each process simulation:
Mean /@ {sample1["PointCountList"], sample2["PointCountList"]}//NCompare to the scaled area of the region:
val = β RegionMeasure[region]//NListPlot[{sample1["PointCountList"], sample2["PointCountList"]}, Epilog -> Line[{{0, val}, {n, val}}], PlotLegends -> {"GibbsPointProcess", "PoissonPointProcess"}]Text
Wolfram Research (2020), GibbsPointProcess, Wolfram Language function, https://reference.wolfram.com/language/ref/GibbsPointProcess.html.
CMS
Wolfram Language. 2020. "GibbsPointProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GibbsPointProcess.html.
APA
Wolfram Language. (2020). GibbsPointProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GibbsPointProcess.html