Graphics
Graphics[primitives,options]
represents a two-dimensional graphical image.
Details and Options
- Graphics is displayed in StandardForm as a graphical image. In InputForm, it is displayed as an explicit list of primitives.
- The following graphics primitives can be used: »
-
AASTriangle[α,β,a] angle-angle-side triangle Arrow[{{x1,y1},…}] arrow ASATriangle[α,c,β] angle-side-angle triangle BezierCurve[{pt1,pt2,…}] Bézier curve BSplineCurve[{pt1,pt2,…}] B-spline curve Circle[{x,y},r] circle Circumsphere[{pt1,…}] circumcircle specified by three points ConicHullRegion[…] linear cone Disk[{x,y},r] filled disk FilledCurve[{seg1,seg2,…}] filled curve GraphicsComplex[pts,prims] complex of graphics objects GraphicsGroup[{g1,g2,…}] objects selectable as a group HalfLine[{pt1,pt2}] half-infinite line, or ray HalfPlane[{pt1,pt2},v] half-infinite plane Image[…] an image object InfiniteLine[{pt1,pt2}] infinite line Inset[obj,…] inset object JoinedCurve[{seg1,seg2,…}] joined curve segments Line[{pt1,…}] line segments Locator[{x,y}] dynamic locator Parallelogram[pt,{v1,v2}] parallelogram Point[{x,y}] point Polygon[{pt1,…}] polygon Raster[array] array of gray or colored squares Rectangle[{xmin,ymin},{xmax,ymax}] rectangle SASTriangle[a,γ,b] side-angle-side triangle Simplex[{pt1,…}] simplex SSSTriangle[a,b,c] side-side-side triangle Text[expr,{x,y}] text Triangle[{pt1,…}] triangle - The following graphics directives can be used: »
-
AbsoluteDashing[{w1,…}] absolute line dashing specification AbsolutePointSize[d] absolute point size specification AbsoluteThickness[w] absolute line thickness specification Arrowheads[specs] arrowheads specification CapForm[type] line cap specification CMYKColor[c,m,y,k] color specification Dashing[{w1,…}] line dashing specification Directive[g1,g2,…] composite graphics directive EdgeForm[g] edge drawing specification FaceForm[g] face drawing specification GrayLevel[i] intensity specification Hue[h] hue specification JoinForm[type] line joining specification Opacity[a] opacity specification PointSize[d] point size specification RGBColor[r,g,b] color specification Texture[obj] texture specification Thickness[w] line thickness specification - The following wrappers can be used at any level:
-
Annotation[obj,label] give an annotation Button[obj,action] make obj act as a button Dynamic[obj] use the dynamically updated current value EventHandler[obj,…] attach an event handler Hyperlink[obj,URI] make obj a hyperlink Mouseover[obj,over] specify a mouseover form PopupWindow[obj,cont] attach a popup window StatusArea[obj,label] specify a label to appear in the status area Style[obj,opts] specify a style Tooltip[obj,label] attach a tooltip - The following options can be given:
-
AlignmentPoint Center the default point in the graphic to align with AspectRatio Automatic ratio of height to width Axes False whether to draw axes AxesLabel None axes labels AxesOrigin Automatic where axes should cross AxesStyle {} style specifications for the axes Background None background color for the plot BaselinePosition Automatic how to align with a surrounding text baseline BaseStyle {} base style specifications for the graphic ContentSelectable Automatic whether to allow contents to be selected CoordinatesToolOptions Automatic detailed behavior of the coordinates tool Epilog {} primitives rendered after the main plot FormatType TraditionalForm the default format type for text Frame False whether to put a frame around the plot FrameLabel None frame labels FrameStyle {} style specifications for the frame FrameTicks Automatic frame ticks FrameTicksStyle {} style specifications for frame ticks GridLines None grid lines to draw GridLinesStyle {} style specifications for grid lines ImageMargins 0. the margins to leave around the graphic ImagePadding All what extra padding to allow for labels etc. ImageSize Automatic the absolute size at which to render the graphic LabelStyle {} style specifications for labels Method Automatic details of graphics methods to use PlotLabel None an overall label for the plot PlotRange All range of values to include PlotRangeClipping False whether to clip at the plot range PlotRangePadding Automatic how much to pad the range of values PlotRegion Automatic the final display region to be filled PreserveImageOptions Automatic whether to preserve image options when displaying new versions of the same graphic Prolog {} primitives rendered before the main plot RotateLabel True whether to rotate y labels on the frame Ticks Automatic axes ticks TicksStyle {} style specifications for axes ticks - Nested lists of graphics constructs can be given. Directive specifications such as GrayLevel remain in effect only until the end of the list that contains them. »
- Style[obj,opts] can be used to apply the options or directives opts to obj. »
- The following Method options can be given:
-
"AxesInFront" True whether to draw axes on top of primitives "FrameInFront" True whether to draw the graphics frame on top of primitives "GridLinesInFront" False whether to draw grid lines on top of primitives "TransparentPolygonMesh" False whether bordering polygons should be carefully drawn to avoid double rendering edges - The settings for BaseStyle are appended to the default style typically given by the "Graphics" style in the current stylesheet. The settings for AxesStyle, LabelStyle, etc. are appended to the default styles given for "GraphicsAxes", "GraphicsLabel", etc.
- Graphics[] gives an empty graphic with the default image size.
Examples
open all close allBasic Examples (2)
Use lines, polygons, circles, etc. to build up a graphics image:
Graphics[{Thick, Green, Rectangle[{0, -1}, {2, 1}], Red, Disk[], Blue, Circle[{2, 0}], Yellow, Polygon[{{2, 0}, {4, 1}, {4, -1}}], Purple, Arrowheads[Large], Arrow[{{4, 3 / 2}, {0, 3 / 2}, {0, 0}}], Black, Dashed, Line[{{-1, 0}, {4, 0}}]}]Use plot functions to automatically create Graphics from different types of data:
Plot[Evaluate[Table[BesselJ[n, x], {n, 4}]], {x, 0, 10}, Filling -> Axis]GraphPlot[Table[i -> Mod[i ^ 2, 104], {i, 0, 104}]]ReliefPlot[Table[i + Sin[i ^ 2 + j ^ 2], {i, -4, 4, .03}, {j, -4, 4, .03}], ColorFunction -> "SunsetColors"]Scope (13)
Primitives (4)
Graphics primitives are drawn in the order in which they are given in Graphics:
Graphics[{Red, Disk[], Green, Rectangle[{0, 0}, {2, 2}], Blue, Disk[{2, 2}]}]Polygons can fold over themselves:
Graphics[Polygon[{{0, 0}, {1, 1}, {0, 1}, {1, 0}}]]Vertices can be shared by using GraphicsComplex:
v = Table[15{Cos[t], Sin[t]}, {t, 0, 4Pi, 4Pi / 5}];Graphics[GraphicsComplex[v, {Point[{1, 2, 3, 4, 5, 6}], Green, Line[{1, 2, 3, 4, 5, 6}]}]]Inset an expression in a graphic:
Graphics[{Circle[], Inset[x ^ 2 + y ^ 2 == 1, {0, 0}]}]Directives (5)
Directives can specify color and opacity of faces:
{Graphics[{Red, Disk[]}], Graphics[{Green, Disk[], Yellow, Opacity[.7], Disk[{0, 1}]}],
Graphics[{Hue[2 / 3, 1 / 2, 1], Rectangle[]}]}Colors, thickness, and dashing directives affect lines, arrows, and edges:
{Graphics[{Blue, Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Thick, Blue, Line[{{0, 0}, {2, 1}}]}], Graphics[{Dashed, Red, Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Thick, Dashed, Red, Line[{{0, 0}, {2, 1}}]}]}{Graphics[{Pink, Rectangle[]}], Graphics[{EdgeForm[Thick], Pink, Rectangle[]}], Graphics[{EdgeForm[Dashed], Pink, Rectangle[]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Rectangle[]}]}Some primitives have special directives to specify various properties:
{Graphics[{Dashed, Red, Arrowheads[{-.1, .1}], Arrow[{{0, 0}, {2, 1}}]}], Graphics[{Blue, PointSize[Large], Point[{{0, 0}, {1, 1 / 2}, {2, 1}}]}]}Directives can be applied to individual objects using Style:
Graphics[{Style[Disk[], Pink], Style[Rectangle[{2, -1}, {4, 1}], Blue]}]Graphics directives remain in effect only until the end of the list that contains them:
Graphics[{Pink, Disk[], {Blue, Disk[{1, 0}]}, Disk[{2, 0}]}]Coordinates (4)
Use an ordinary coordinate system:
Graphics[Rectangle[{0, 4}, {10, 6}], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]Specify coordinates by fractions of the plot range:
Graphics[Rectangle[Scaled[{0, .4}], Scaled[{1, .6}]], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]Specify coordinates by fractions of the whole image:
Graphics[Rectangle[ImageScaled[{0, .4}], ImageScaled[{1, .6}]], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]Offset coordinates by printer's points:
Graphics[Rectangle[Offset[{10, 20}, {0, 0}], Offset[{-10, -20}, {1, 1}]], Frame -> True]Options (71)
AlignmentPoint (1)
Specify the coordinates within Inset to be aligned with the center of the enclosing graphic:
Table[Graphics[{Inset[Graphics[Circle[], ImageSize -> 30, AlignmentPoint -> {a, 0}], Center]}, ImageSize -> 70, Axes -> True, Ticks -> None], {a, {-1, 0, 1}}]Table[Graphics[{Inset[Graphics[Circle[], ImageSize -> 30, AlignmentPoint -> {0, a}], Center]}, ImageSize -> 70, Axes -> True, Ticks -> None], {a, {-1, 0, 1}}]AspectRatio (1)
Use numerical values for AspectRatio:
Table[Graphics[Circle[], AspectRatio -> 1 / k], {k, 1, 3}]Axes (2)
AxesLabel (2)
AxesOrigin (2)
AxesStyle (1)
Background (1)
BaselinePosition (3)
Align the center of a graphic with the baseline of the text:
{x, Graphics[Circle[], ImageSize -> 50, BaselinePosition -> Center], y}Specify the baseline of a graphic as a fraction of the height by using Scaled:
Table[{x, Graphics[Circle[], BaselinePosition -> Scaled[b], ImageSize -> 50]}, {b, {0, 0.5, 1}}]Use the axis of a graphic as the baseline:
{x, Graphics[Circle[], Axes -> True, BaselinePosition -> Axis], y}{x, Graphics[Circle[{0, 1}], Axes -> True, BaselinePosition -> Axis], y}BaseStyle (2)
ContentSelectable (3)
Allow the individual graphics objects to be selectable by a single click:
Graphics[{Pink, Disk[], Rectangle[{2, -1}, {4, 1}]}, ContentSelectable -> True]No individual object is selectable; the whole graphic appears as one object:
Graphics[{Pink, Disk[], Rectangle[{2, -1}, {4, 1}]}, ContentSelectable -> False]The first click selects the whole graphic, and subsequent ones select individual objects:
Graphics[{Pink, Disk[], Rectangle[{2, -1}, {4, 1}]}, ContentSelectable -> Automatic]Epilog (1)
FormatType (3)
By default, expressions are displayed using TraditionalForm in graphics:
Graphics[{Circle[], Text[Style[x ^ 2 + y ^ 2 == 1, 20]]}]Display expressions using StandardForm:
Graphics[{Circle[], Text[Style[x ^ 2 + y ^ 2 == 1, 20]]}, FormatType -> StandardForm]Labels are also affected by FormatType setting:
Graphics[Circle[], Axes -> True, AxesLabel -> {Cos[θ], Sin[θ]}, FormatType -> StandardForm]Frame (2)
FrameLabel (1)
FrameStyle (2)
FrameTicks (2)
Graphics[Circle[], Frame -> True, FrameTicks -> None]Tick mark labels on the bottom and the left frame edges:
Graphics[Circle[], Frame -> True, FrameTicks -> Automatic]Frame ticks on the bottom and the right edges:
Graphics[Circle[], Frame -> True, FrameTicks -> {{None, Automatic}, {Automatic, None}}]FrameTicksStyle (2)
Specify frame tick and frame tick label style:
Graphics[{}, Frame -> True, FrameTicksStyle -> Directive[Orange, 12]]Specify frame tick style for each edge:
Graphics[{}, Frame -> True, FrameTicks -> All, FrameTicksStyle -> {{Magenta, Blue}, {Red, Green}}]GridLines (3)
Put grids across a 2D graphic:
Graphics[Circle[], GridLines -> Automatic]Draw grid lines at specific positions:
Graphics[Circle[], Axes -> True, GridLines -> {{-1, 1}, {-1, 1}}]Specify the style of each grid:
Graphics[Circle[], Axes -> True, GridLines -> {{{-1, Orange}, {-.5, Dotted}, {.5, Dotted}, {1, Orange}}, {-1, {-.5, Dotted}, {.5, Dotted}, 1}}]GridLinesStyle (1)
ImageMargins (3)
Allow no margins outside of ImageSize:
Framed[Graphics[Disk[]]]Have 20-point margins on all sides:
Framed[Graphics[Disk[], ImageMargins -> 20]]Leave different margins on each side:
Framed[Graphics[Disk[], ImageMargins -> {{5, 10}, {20, 30}}]]ImagePadding (4)
Leave no padding outside of the plot range:
Graphics[{Thickness[.3], Pink, Circle[]}, ImagePadding -> None, Frame -> True, FrameLabel -> {x, y}]Leave enough padding for all objects and labels that are present:
Framed[Graphics[{Thickness[.3], Pink, Circle[]}, ImagePadding -> All, Frame -> True, FrameLabel -> {x, y}], FrameMargins -> 0]Specify the same padding for all sides in printer's points:
Framed[Graphics[{Thickness[.3], Pink, Circle[]}, ImagePadding -> 40, Frame -> True]]Specify different padding on each side:
Framed[Graphics[{Thickness[.2], Pink, Circle[]}, ImagePadding -> {{40, 10}, {20, 5}}, Frame -> True]]ImageSize (3)
Use predefined symbolic sizes:
Table[Graphics[Circle[], ImageSize -> s], {s, {Tiny, Small}}]{Graphics[Circle[], ImageSize -> 100], Graphics[Circle[{0, 0}, {1, 2}], ImageSize -> 100]}Use an explicit image width and height:
{Graphics[Circle[], ImageSize -> {100, 100}], Graphics[Circle[{0, 0}, {1, 2}], ImageSize -> {100, 100}]}LabelStyle (1)
Method (4)
"AxesInFront" (1)
"FrameInFront" (1)
By default, frames draw in front of graphics primitives:
Graphics[{Red, Polygon[{{0.5, 0}, {.5, 1}, {-.5, 1}}]}, Frame -> True, PlotRange -> {{0, 1}, {0, 1}}]Force the frame to draw behind graphics primitives:
Show[%, Method -> {"FrameInFront" -> False}]"GridLinesInFront" (1)
"TransparentPolygonMesh" (1)
By default, polygon meshes double-paint their edges for efficiency reasons:
Graphics[{Blue, Opacity[0.2], EdgeForm[None],
Polygon[{{{0, 0}, {0, 1}, {1, 0}}, {{1, 1}, {0, 1}, {1, 0}}}]}]The behavior can be turned off using the "TransparentPolygonMesh" method option:
Show[%, Method -> {"TransparentPolygonMesh" -> True}]PlotLabel (2)
Display a label on the top of the graphic in TraditionalForm:
Graphics[Circle[], PlotLabel -> x ^ 2 + y ^ 2 == 1]Use Style and other typesetting functions to modify how the label appears:
Graphics[Circle[], PlotLabel -> Style[Framed[x ^ 2 + y ^ 2 == 1], 16, Red, Background -> Yellow]]PlotRange (3)
Graphics[{Pink, Disk[{0, 0}, 5]}, Frame -> True, PlotRange -> All]
Graphics[{Pink, Disk[]}, PlotRange -> {{-1, 1}, {0, 1}}, Frame -> True]Force clipping at the PlotRange:
Graphics[{Pink, Disk[]}, PlotRange -> {{-1, 1}, {0, 1}}, PlotRangeClipping -> True, Frame -> True]PlotRange->s is equivalent to PlotRange->{{-s,s},{-s,s}}:
Graphics[{Pink, Disk[{0, 0}, 5]}, Frame -> True, PlotRange -> 4]PlotRangeClipping (2)
Allow graphics objects to spread beyond PlotRange:
Graphics[{Pink, Disk[{0, 0}, 5]}, Frame -> True, PlotRange -> 4, PlotRangeClipping -> False]Clip all graphics objects at PlotRange:
Graphics[{Pink, Disk[{0, 0}, 5]}, Frame -> True, PlotRange -> 4, PlotRangeClipping -> True]PlotRangePadding (3)
Include 
coordinate unit of padding on all sides:
Graphics[{Pink, Rectangle[]}, PlotRangePadding -> 1, Frame -> True]Include padding using Scaled coordinates:
Graphics[{Pink, Rectangle[]}, PlotRangePadding -> Scaled[0.1], Frame -> True]Specify different padding on each side:
Graphics[{Pink, Rectangle[]}, PlotRangePadding -> {{0.5, 1}, {0.3, 0.3}}, Frame -> True]PlotRegion (3)
The contents of a graphic use the whole region:
Graphics[{Pink, Disk[]}, Frame -> True, FrameTicks -> False, Background -> StandardGray]Limit the contents of the graphic to the middle half of the region in each direction:
Graphics[{Pink, Disk[]}, Frame -> True, FrameTicks -> False, PlotRegion -> {{0.25, 0.75}, {0.25, 0.75}}, Background -> StandardGray]ImagePadding can also be used to add padding around a graphic:
Graphics[{Pink, Disk[]}, Frame -> True, FrameTicks -> False, ImagePadding -> 30, Background -> StandardGray]Prolog (1)
Define a simple graphic to use as a background:
bg = Graphics[Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Orange, Orange, White, White}], AspectRatio -> Full];Graphics[Circle[], Prolog -> Inset[bg, Scaled[{0, 0}], Scaled[{0, 0}]]]Plot[Sin[x], {x, 0, 10}, Prolog -> Inset[bg, Scaled[{0, 0}], Scaled[{0, 0}], Scaled[{1, 1}]]]RotateLabel (2)
Specify that vertical frame labels should be rotated:
Graphics[Circle[], Frame -> True, FrameLabel -> {None, "y axis"}, RotateLabel -> True]Specify that vertical frame labels should not be rotated:
Graphics[Circle[], Frame -> True, FrameLabel -> {None, "y axis"}, RotateLabel -> False]Ticks (3)
Draw the axes but no tick marks:
Graphics[Circle[], Axes -> True, Ticks -> None]Place tick marks automatically:
Graphics[Circle[], Axes -> True, Ticks -> Automatic]Draw tick marks at the specific positions:
Graphics[Circle[{0, 0}, 3], Ticks -> {{1, 2, 3}, {1, 3}}, Axes -> True]TicksStyle (2)
Specify the styles of the ticks and tick labels:
Graphics[Circle[], Axes -> True, TicksStyle -> Directive[Red, Bold]]Specify the styles of 
and 
axis ticks separately:
Graphics[Circle[], Axes -> True, TicksStyle -> {Directive[Red, Bold], Directive[Blue, 12]}]Applications (1)
Properties & Relations (5)
The StandardForm of Graphics is its rendered form:
Graphics[Disk[]]The InputForm is the textual expression form:
InputForm[%]Graphics can be used as input to functions:
makeDashed[ g_Graphics ] := g /. l_Line :> {Dashed, l}makeDashed[[image]]Two-dimensional plot functions return Graphics:
ParametricPlot[{(v + u) Cos[u], (v + u) Sin[u]}, {u, 0, 4Pi}, {v, 0, 5}, Mesh -> False]ContourPlot[y + Sin[x ^ 2 + 3y], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Rainbow"]Several integrated data sources return Graphics:
CountryData["World", "Shape"]GraphData["DoubleStarSnark"]Many Import and Export formats support Graphics:
First@Import["ExampleData/mathematica.pdf", "PageGraphics"]Import["ExampleData/coneflower.jpg", "Graphics"]Neat Examples (2)
Display an analog clock with current system time:
Dynamic@Module[{hour, min, sec, ht, mt, st}, Clock[];{hour, min, sec} = Take[DateList[], -3];ht = Pi / 2 - 2Pi hour / 12 - 2Pi min / 720;mt = Pi / 2 - 2Pi min / 60;st = Pi / 2 - 2Pi Floor[sec] / 60;Graphics[{Arrowheads[0.1], Arrow[{{0, 0}, 0.6{Cos[ht], Sin[ht]}}], Arrow[{{0, 0}, 0.85{Cos[mt], Sin[mt]}}], Line[{{0, 0}, 0.85{Cos[st], Sin[st]}}], PointSize[Medium], Table[Point[0.9{Cos[i], Sin[i]}], {i, 0, 2Pi, Pi / 6}], Point[{0, 0}], Circle[]}]]Graphics[Table[{Hue[t / 20], Circle[{Cos[2Pi t / 20], Sin[2Pi t / 20]}]}, {t, 20}]]Related Links
-
Fast Introduction for Programmers: Graphics
-
An Elementary Introduction to the Wolfram Language
: Basic Graphics Objects
-
An Elementary Introduction to the Wolfram Language
: Interactive Manipulation
-
An Elementary Introduction to the Wolfram Language
: Coordinates and Graphics
-
An Elementary Introduction to the Wolfram Language
: Ways to Apply Functions
-
An Elementary Introduction to the Wolfram Language
: Layout and Display
Text
Wolfram Research (1988), Graphics, Wolfram Language function, https://reference.wolfram.com/language/ref/Graphics.html (updated 2022).
CMS
Wolfram Language. 1988. "Graphics." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Graphics.html.
APA
Wolfram Language. (1988). Graphics. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Graphics.html