Visitar URL original
GraphicsGrid—Wolfram Documentation

WOLFRAM

Wolfram Language & System Documentation Center

GraphicsGrid[{{g11,g12,…},…}]

generates a graphic in which the gij are laid out in a two-dimensional grid.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Frames and Grid Lines  
Spanning Elements  
Alignment  
Show More Show More
Styling  
Spacing  
Irregular Shapes  
Nested Grids  
Options  
AspectRatio  
Background  
BaselinePosition  
Frame  
FrameStyle  
ImageSize  
Applications  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Workflows
Related Links
History
Cite this Page

GraphicsGrid

GraphicsGrid[{{g11,g12,…},…}]

generates a graphic in which the gij are laid out in a two-dimensional grid.

Details and Options

  • If the gij are graphics with ImageSize->Automatic, GraphicsGrid will if possible resize them to make them fit into the grid as well as possible, while preserving their individual aspect ratios.
  • The output from GraphicsGrid can interactively be resized, or edited as a graphic.
  • The listi in GraphicsGrid[{list1,list2,…}] do not all need to be the same length; there will be empty space in the grid at the ends of shorter rows.
  • You can specify that an element e should span multiple positions in a grid using, for example, GraphicsGrid[{{e,SpanFromLeft,SpanFromLeft},…}].
  • The following specify that a particular position should be spanned:
  • SpanFromLeftspan from left
    SpanFromAbovespan from above
    SpanFromBothspan from both left and above
  • A particular element can span both multiple rows and multiple columns by having a rectangular section of the array with the form {{e,SpanFromLeft,SpanFromLeft,…}, {SpanFromAbove,SpanFromBoth,SpanFromBoth,…},…}.
  • The following options can be given:
  • Alignment{Center,Center}horizontal and vertical alignment of elements
    AspectRatio Automaticratio of height to width for the whole grid
    Background Nonewhat background colors to use
    BaselinePosition Automaticwhat to align with the surrounding text baseline
    BaseStyle{}base style specifications for the grid
    DividersNonewhere to draw divider lines in the grid
    Frame Nonewhere to draw frames in the grid
    FrameStyle Automaticstyles to use for frames
    ImageSize Automaticoverall size of the whole graphics grid
    ItemAspectRatioAutomaticratio of height to width for each item
    SpacingsScaled[0.1]horizontal and vertical spacings
  • With AspectRatio->Automatic, the aspect ratio of the whole graphics grid will be chosen so as to best fit the individual objects in the grid.
  • Settings for the options Alignment, Background, and Frame can be given as follows to apply separately to different items:
  • specapply spec to all items
    {specx}apply specx at successive horizontal positions
    {specx,specy}apply speck at successive horizontal and vertical positions
    {spec_(x),spec_(y),rules}also allow explicit rules for individual elements
  • The speck can have the following forms:
  • {s1,s2,…,sn}use s_(1) through s_(n), then use defaults
    {{c}}use c in all cases
    {{c1,c2}}alternate between c_(1) and c_(2)
    {{c1,c2,…}}cycle through all ci
    {s,{c}}use s, then repeatedly use c
    {s1,{c},sn}use s_(1), then repeatedly use c, but use s_(n) at the end
    {s1,s2,…,{c1,c2,…},sm,…,sn}use the first sequence of s_i at the beginning, then cyclically use the ci, then use the last sequence of s_i at the end
    {s1,s2,…,{},sm,…,sn}use the first sequence of s_i at the beginning and the last sequence at the end
    {i1->v1,i2->v2,…}specify what to use at positions ik
    {spec,rules}use rules to override specifications in spec
  • With settings of the form {s_(1),s_(2),...,{...},s_(m),...,s_(n)}, if there are more s_i specified than items across the grid, s_i from the beginning are used for the first items, and ones from the end are used for the last items.
  • Settings such as Alignment, Background, and Frame can effectively be specified for individual items in the grid using Item.
  • GraphicsGrid will not change the size of graphics or other objects that have explicit ImageSize settings, unless the GraphicsGrid itself is resized or given an overall ImageSize setting.
  • Common settings for Frame include:
  • Noneno frame
    Trueframe around the whole grid
    Allframe around every item in the grid
    {All,False}put a frame at every horizontal position (column lines)
    {False,All}put a frame at every vertical position (row lines)
  • Settings for Dividers and Spacings can have the following forms:
  • specapply spec to all gaps between items
    {specx,specy}apply speci to successive horizontal and vertical gaps
  • The speci can have the same forms as for Alignment, Background, and other item-oriented options.
  • For a grid with items in a particular direction, Dividers and Spacings can specify settings for the gaps between elements, starting before the first element and ending after the last element.
  • The following settings can be used for BaselinePosition:
  • Axisaxis of the middle row in the grid (default)
    Baselinebaseline of the middle row in the grid
    Bottombottom of the whole grid
    Centerhalfway from top to bottom
    Toptop of the whole grid
    {{i,j},pos}position pos in element
  • The settings for BaseStyle are appended to the default style typically given by the "GraphicsGrid" style in the current stylesheet.

Examples

open all close all

Basic Examples  (2)

Display elements in a graphics grid:

Wolfram Language code: GraphicsGrid[{{Graphics[Rectangle[]], Graphics[Disk[]]}, {Graphics[Disk[]], Graphics[Rectangle[]]}}]

Put a frame around every element:

Wolfram Language code: GraphicsGrid[{{Graphics[Rectangle[]], Graphics[Disk[]]}, {Graphics[Disk[]], Graphics[Rectangle[]]}}, Frame -> All]

Scope  (17)

Frames and Grid Lines  (5)

Put a frame around the whole grid:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Frame -> True]

Put a frame around every element:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Frame -> All]

Draw all the frames in red:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Frame -> All, FrameStyle -> Red]

Put a frame around the first row and column:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Frame -> {{True}, {True}}]

Draw different frames with different styles:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Frame -> {{Red}, {Green}}]

Put dividers at all horizontal positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Dividers -> {All, False}]

Put dividers at all vertical positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Dividers -> {False, All}]

Put dividers at the third horizontal and second vertical positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {5}], Dividers -> {{False, False, True}, {False, True}}]

Spanning Elements  (3)

Make element 4 span the column to its right:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, x, x}, {x, SpanFromLeft, x}, {x, x, x}}, Frame -> All]

Make it span two columns:

Wolfram Language code: GraphicsGrid[{{x, x, x}, {x, SpanFromLeft, SpanFromLeft}, {x, x, x}}, Frame -> All]

Make element 2 span the row below it:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, x, x}, {x, SpanFromAbove, x}, {x, x, x}}, Frame -> All]

Make it span two rows:

Wolfram Language code: GraphicsGrid[{{x, x, x}, {x, SpanFromAbove, x}, {x, SpanFromAbove, x}}, Frame -> All]

Span throughout a 2×2 block:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, SpanFromLeft, x}, {SpanFromAbove, SpanFromBoth, x}, {x, x, x}}, Frame -> All]

Alignment  (1)

Align contents to the left:

Wolfram Language code: GraphicsGrid[{{Graphics[Rectangle[{0, 0}, {5, 1}]]}, {Graphics[Rectangle[{0, 0}, {1, 1}]]}}, Alignment -> Left, Frame -> All]

Align contents to the right:

Wolfram Language code: GraphicsGrid[{{Graphics[Rectangle[{0, 0}, {5, 1}]]}, {Graphics[Rectangle[{0, 0}, {1, 1}]]}}, Alignment -> Right, Frame -> All]

Styling  (5)

Draw the grid with a pink background:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> Pink]

A pink background for the column at the first horizontal position:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{Pink}, None}]

Alternating pink and gray at successive vertical positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{{Pink, Gray}}, None}]

Alternating pink and gray at successive horizontal positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {None, {{Pink, Gray}}}]

Embed styling options with a particular grid item:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{Item[x, Background -> Red, Frame -> True], x}, {x, x}}]

Spacing  (1)

Set the spacing between items:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {3}], Frame -> All, Spacings -> Scaled[.5]]

Set the horizontal and vertical spacings separately:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {3}, {3}], Frame -> All, Spacings -> {Scaled[.5], 0}]

Irregular Shapes  (1)

The overall aspect ratio is automatically adjusted for irregular shapes:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[], AspectRatio -> RandomReal[]], {3}, {5}]]

Nested Grids  (1)

Grids can be nested:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, GraphicsGrid[{{x, x, x}, {x, x, x}, {x, x, x}}], x}, {x, x, x}}, Frame -> All]

Options  (17)

AspectRatio  (2)

If possible GraphicsGrid will choose an aspect ratio suitable to its elements:

Wolfram Language code: GraphicsGrid[Table[Graphics[Rectangle[], AspectRatio -> RandomReal[{.2, .5}]], {5}, {5}]]

When no reasonable choice can be made, a default aspect ratio of 1 is used:

Wolfram Language code: GraphicsGrid[Table[Graphics[Rectangle[], AspectRatio -> RandomReal[{.5, 2}]], {5}, {5}]]

Setting the aspect ratio of each item explicitly:

Wolfram Language code: GraphicsGrid[Table[Graphics[Rectangle[], AspectRatio -> RandomReal[{1, 5}]], {5}, {5}], AspectRatio -> 1]

Background  (7)

Draw the grid with a pink background:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> Pink]

Pink and red backgrounds for the first and second horizontal positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{Pink, Red}, None}]

An equivalent syntax:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{1 -> Pink, 2 -> Red}, None}]

Pink and red backgrounds for the first and second vertical positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {None, {Pink, Red}}]

Alternating pink and red backgrounds:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{{Pink, Red}}, None}]

Alternating backgrounds with gray superimposed in the first and last positions:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{{{Pink, Red}}, {1 -> Gray, -1 -> Gray}}, None}]

Blending of colors:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {{{Orange, None}}, {{Purple, None}}}]

Set the background for specific items:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {None, None, {{1, 1} -> Pink, {3, 3} -> Red}}]

Set the background for a subregion of the grid:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Background -> {None, None, {{{1, 3}, {1, 3}} -> Pink}}]

BaselinePosition  (1)

Align the center of the grid with the baseline of surrounding text:

Wolfram Language code: {x, y, GraphicsGrid[Table[Graphics[Rectangle[]], {2}, {2}], Frame -> True], z}

Align the bottom of the grid with the baseline:

Wolfram Language code: {x, y, GraphicsGrid[Table[Graphics[Rectangle[]], {2}, {2}], BaselinePosition -> Bottom, Frame -> True], z}

Frame  (3)

Frame the entire grid:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Frame -> True]

Frame all elements in the grid:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Frame -> All]

Frame specific elements:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Frame -> {None, None, {{1, 1} -> True, {3, 3} -> True}}]

Frame a region:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Frame -> {None, None, {{{1, 3}, {1, 3}} -> True}}]

FrameStyle  (3)

FrameStyle supports a variety of graphics directives:

Wolfram Language code: GraphicsGrid[Table[Graphics[Circle[]], {4}, {7}], Dividers -> {2 -> True, False}, Frame -> {{True}, False}, FrameStyle -> Directive[Dashing[.05], Thickness[.01], Blue]]

FrameStyle is applied to all sources of grid lines, including Dividers and Item:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, x, x, x, x, x, x}, {x, Item[x, Frame -> Green], x, x, x, x, x}, {x, x, x, x, x, x, x}, {x, x, x, x, x, x, x}}, Dividers -> {False, 2 -> True}, Frame -> {1 -> True, False}, FrameStyle -> Directive[Dashing[.05], Thickness[.01], Blue]]

Directives given with FrameStyle are combined with those specified elsewhere:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, x, x, x, x, x, x}, {x, Item[x, Frame -> Green], x, x, x, x, x}, {x, x, x, x, x, x, x}, {x, x, x, x, x, x, x}}, Dividers -> {2 -> Red, 2 -> Red}, Frame -> {1 -> True, False}, FrameStyle -> Directive[Dashing[.05], Thickness[.01], Blue]]

ImageSize  (1)

By default, GraphicsGrid will display graphics at their specified sizes:

Wolfram Language code: GraphicsGrid[{{Graphics[Rectangle[], ImageSize -> {50, 50}], Graphics[Rectangle[], ImageSize -> {100, 100}]}}]

Giving an ImageSize setting to the GraphicsGrid will scale the graphics appropriately:

Wolfram Language code: GraphicsGrid[{{Graphics[Rectangle[], ImageSize -> {50, 50}], Graphics[Rectangle[], ImageSize -> {100, 100}]}}, ImageSize -> Tiny]

Applications  (2)

Make a picture of the first 64 elementary cellular automata:

Wolfram Language code: GraphicsGrid[Partition[Table[ArrayPlot[CellularAutomaton[n, {{1}, 0}, {30, All}]], {n, 0, 63}], 8]]

Show a collection of discrete mappings:

Wolfram Language code: GraphicsGrid[Table[GraphPlot[Table[i -> Mod[i ^ p, m], {i, m}]], {m, 30, 33}, {p, 2, 5}], Frame -> All]

Possible Issues  (1)

To span across both rows and columns requires appropriate use of SpanFromBoth:

Wolfram Language code: x = Graphics[Circle[]];
Wolfram Language code: GraphicsGrid[{{x, SpanFromLeft, x}, {SpanFromAbove, SpanFromAbove, x}, {x, x, x}}]
Wolfram Language code: GraphicsGrid[{{x, SpanFromLeft, x}, {SpanFromAbove, SpanFromBoth, x}, {x, x, x}}]
Wolfram Research (2007), GraphicsGrid, Wolfram Language function, https://reference.wolfram.com/language/ref/GraphicsGrid.html.

Text

Wolfram Research (2007), GraphicsGrid, Wolfram Language function, https://reference.wolfram.com/language/ref/GraphicsGrid.html.

CMS

Wolfram Language. 2007. "GraphicsGrid." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GraphicsGrid.html.

APA

Wolfram Language. (2007). GraphicsGrid. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GraphicsGrid.html

BibTeX

@misc{reference.wolfram_2026_graphicsgrid, author="Wolfram Research", title="{GraphicsGrid}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/GraphicsGrid.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_graphicsgrid, organization={Wolfram Research}, title={GraphicsGrid}, year={2007}, url={https://reference.wolfram.com/language/ref/GraphicsGrid.html}, note=[Accessed: 14-November-2026]}