Visitar URL original
IntersectedEntityClass—Wolfram Documentation

WOLFRAM

Wolfram Language & System Documentation Center

IntersectedEntityClass[class1,class2,…]

represents an entity class containing all the entities common to all classi.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
SameTestProperties  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

IntersectedEntityClass

IntersectedEntityClass[class1,class2,…]

represents an entity class containing all the entities common to all classi.

Details and Options

  • IntersectedEntityClass[class1,class2,…] is effectively equivalent to the unsorted intersection of the entities in each classi as they appear when applying EntityList.
  • When the classes appearing in IntersectedEntityClass effectively have the same type after the simplification in EntityList, the resulting entities will have that type. When performing the intersection of incompatible types, the resulting entities will have a new type.
  • IntersectedEntityClass[class1,class2,…,SameTestProperties {props1,props2,…}] uses properties propsi from classi to test for entity equality.
  • EntityProperties[IntersectedEntityClass[class1,class2,…]] returns all the properties of each classi, along with EntityProperty[IntersectedEntityClass[…],"propj"], where "propj" are any of the properties that appear in at least two of the classi when those classes have different entity types.

Examples

open all close all

Basic Examples  (3)

Compute the complement of two entity classes:

Wolfram Language code: EntityList[IntersectedEntityClass[EntityClass["Country", "G7"], EntityClass["Country", "EuropeanUnion"]]]

Mixing different entity types will effectively result in an empty entity class:

Wolfram Language code: IntersectedEntityClass[EntityClass["Movie", "Producers" -> Entity["Person", "WaltDisney::mhtn8"]], EntityClass["Book", "Author" -> Entity["Person", "RudyardKipling::48d9q"]] ]["Name"]

Redefining equality by name yields the correct result:

Wolfram Language code: IntersectedEntityClass[EntityClass["Movie", "Producers" -> Entity["Person", "WaltDisney::mhtn8"]], EntityClass["Book", "Author" -> Entity["Person", "RudyardKipling::48d9q"]], SameTestProperties -> "Name" ]["Name"]

When used with relational-database-backed entities, IntersectedEntityClass corresponds to an INTERSECT statement:

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[FindFile["ExampleData/ecommerce-database.sqlite"]]]]
Wolfram Language code: IntersectedEntityClass[EntityClass["offices", "country" -> "USA"], EntityClass["offices", "city" -> "Boston"]][{"officeCode", "country", "city"}]

Scope  (2)

Use IntersectedEntityClass with entity classes of the same type:

Wolfram Language code: EntityList[IntersectedEntityClass[EntityClass["Country", "NATO"], EntityClass["Country", "EuropeanUnion"]]]

Entities of different types are considered different by default:

Wolfram Language code: EntityList[IntersectedEntityClass[EntityClass["Chemical", "HomonuclearDiatomics"], EntityClass["Element", "Gas"]]]

Use SameTestProperties to match them by name:

Wolfram Language code: EntityList[IntersectedEntityClass[EntityClass["Chemical", "HomonuclearDiatomics"], EntityClass["Element", "Gas"], SameTestProperties -> "Name"]]

Options  (1)

SameTestProperties  (1)

SameTestProperties can be used to define equality between entities:

Wolfram Language code: IntersectedEntityClass[EntityClass["Movie", "Director" -> ContainsExactly[{Entity["Person", "StevenSpielberg::76z25"]}]], EntityClass["Book", "Author" -> ContainsExactly[{Entity["Person", "MichaelCrichton::383m7"]}]], SameTestProperties -> "Name"]["Name"]

Properties & Relations  (2)

IntersectedEntityClass is usually equivalent to Intersection

Wolfram Language code: EntityList[IntersectedEntityClass[EntityClass["Country", "NATO"], EntityClass["Country", "EuropeanUnion"]]] === Intersection[EntityList[EntityClass["Country", "NATO"]], EntityList[EntityClass["Country", "EuropeanUnion"]]]

When performing the intersection of implicit EntityClass or FilteredEntityClass expressions, it is often more efficient to use conjunction in the condition:

Wolfram Language code: EntityList[IntersectedEntityClass[EntityClass["Element", "Period" -> 2], EntityClass["Element", "Group" -> 2]]]

The resulting classes are equivalent apart from ordering:

Wolfram Language code: EntityList[EntityClass["Element", {"Period" -> 2, "Group" -> 2}]]
Wolfram Research (2020), IntersectedEntityClass, Wolfram Language function, https://reference.wolfram.com/language/ref/IntersectedEntityClass.html.

Text

Wolfram Research (2020), IntersectedEntityClass, Wolfram Language function, https://reference.wolfram.com/language/ref/IntersectedEntityClass.html.

CMS

Wolfram Language. 2020. "IntersectedEntityClass." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/IntersectedEntityClass.html.

APA

Wolfram Language. (2020). IntersectedEntityClass. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/IntersectedEntityClass.html

BibTeX

@misc{reference.wolfram_2026_intersectedentityclass, author="Wolfram Research", title="{IntersectedEntityClass}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/IntersectedEntityClass.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_intersectedentityclass, organization={Wolfram Research}, title={IntersectedEntityClass}, year={2020}, url={https://reference.wolfram.com/language/ref/IntersectedEntityClass.html}, note=[Accessed: 14-November-2026]}