Wolfram Language & System Documentation Center

LogNormalDistribution

LogNormalDistribution[μ,σ]

represents a lognormal distribution derived from a normal distribution with mean μ and standard deviation σ.

Details

LogNormalDistribution is also known as the Galton distribution.
LogNormalDistribution[0,1] is also known as Gibrat distribution.
The lognormal distribution LogNormalDistribution[μ,σ] is equivalent to TransformedDistribution[Exp[x],xNormalDistribution[μ,σ]].
LogNormalDistribution allows μ to be any real number and σ to be any positive real number.
LogNormalDistribution allows μ and σ to be dimensionless quantities.
LogNormalDistribution can be used with such functions as Mean, CDF, and RandomVariate. »

Background & Context

LogNormalDistribution[μ,σ] represents a continuous statistical distribution supported over the interval and parametrized by a real number μ and by a positive real number σ that together determine the overall shape of its probability density function (PDF). Depending on the values of σ and μ, the PDF of a lognormal distribution may be either unimodal with a single "peak" (i.e. a global maximum) or monotone decreasing with a potential singularity approaching the lower boundary of its domain. In addition, the PDF of the lognormal distribution has tails that are "fat", in the sense that its PDF decreases algebraically rather than decreasing exponentially for large values of . (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of the distribution.) The lognormal distribution is sometimes called the Galton distribution, the antilognormal distribution, or the Cobb–Douglas distribution.
LogNormalDistribution is the distribution followed by the logarithm of a normally distributed random variable. In other words, if is a random variable and (where denotes "is distributed as"), then . The origins of the lognormal distribution can be traced to an observation made by Francis Galton in the 1870s demonstrating that the distribution modeling the logarithm of a product of a number of independent positive random variates tends to a standard NormalDistribution as the number of variates gets infinitely large. The theory of the distribution was studied further in the early 1900s and has since been found to accurately model both the weights of humans and the sizes of computer files on a file system. In addition, the lognormal distribution has become a widely utilized tool for modeling various phenomena, including dust concentrations, gold and uranium grades, flood flows, lifetime distributions for manufactured products, and miscellaneous phenomena in finance and economics.
RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a lognormal distribution. Distributed[x,LogNormalDistribution[μ,σ]], written more concisely as xLogNormalDistribution[μ,σ], can be used to assert that a random variable x is distributed according to a lognormal distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
The probability density and cumulative distribution functions for lognormal distributions may be given using PDF[LogNormalDistribution[μ,σ],x] and CDF[LogNormalDistribution[μ,σ],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
DistributionFitTest can be used to test if a given dataset is consistent with a lognormal distribution, EstimatedDistribution to estimate a lognormal parametric distribution from given data, and FindDistributionParameters to fit data to a lognormal distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic lognormal distribution, and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic lognormal distribution.
TransformedDistribution can be used to represent a transformed lognormal distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a lognormal distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving lognormal distributions.
LogNormalDistribution is related to a number of other distributions. It can be realized as a transformation of NormalDistribution, in the sense that the PDF of TransformedDistribution[Exp[x],xNormalDistribution[μ,σ]] is precisely the same as that of LogNormalDistribution[μ,σ]. Its logarithmic behavior is qualitatively similar to that of LogLogisticDistribution, LogMultinormalDistribution, and LogGammaDistribution. LogNormalDistribution is a special case of JohnsonDistribution. One can derive SuzukiDistribution by combining LogNormalDistribution with RayleighDistribution, in the sense that the PDF of SuzukiDistribution[μ,ν] is precisely the same as that of TransformedDistribution[u v,{uRayleighDistribution[1],vLogNormalDistribution[μ,ν]}]. By way of its connection to NormalDistribution, LogNormalDistribution is also related to StableDistribution, RiceDistribution, MaxwellDistribution, LevyDistribution, LaplaceDistribution, ChiDistribution, and ChiSquareDistribution.

Examples

open all close all

Basic Examples (4)

Probability density function:

Wolfram Language code:

Plot[Table[PDF[LogNormalDistribution[μ, 2], x], {μ, {-1, 2, 3}}]//Evaluate, {x, 0, 4}, Filling -> Axis, PlotRange -> {0, 0.4}]

Wolfram Language code: Plot[Table[PDF[LogNormalDistribution[1, σ], x], {σ, {0.5, 0.75, 1.5}}]//Evaluate, {x, 0, 4}, Filling -> Axis]

Wolfram Language code: PDF[LogNormalDistribution[μ, σ], x]

Cumulative distribution function:

Wolfram Language code:

Plot[Table[CDF[LogNormalDistribution[μ, 2], x], {μ, {-1, 2, 3}}]//Evaluate, {x, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

Wolfram Language code:

Plot[Table[CDF[LogNormalDistribution[1, σ], x], {σ, {0.5, 0.75, 1.5}}]//Evaluate, {x, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

Wolfram Language code: CDF[LogNormalDistribution[μ, σ], x]

Mean and variance:

Wolfram Language code: Mean[LogNormalDistribution[μ, σ]]

Wolfram Language code: Variance[LogNormalDistribution[μ, σ]]

Median:

Wolfram Language code: Median[LogNormalDistribution[μ, σ]]

Scope (7)

Generate a sample of pseudorandom numbers from a log-normal distribution:

Wolfram Language code: data = RandomVariate[LogNormalDistribution[2, .3], 10 ^ 4];

Compare the histogram to the PDF:

Wolfram Language code: Show[Histogram[data, {0, 15, 0.5}, "PDF"], Plot[PDF[LogNormalDistribution[2, .3], x], {x, 0, 15}, PlotStyle -> Thick]]

Distribution parameters estimation:

Wolfram Language code: sample = RandomVariate[LogNormalDistribution[1, 1 / 2], 10 ^ 3];

Estimate the distribution parameters from sample data:

Wolfram Language code: edist = EstimatedDistribution[sample, LogNormalDistribution[μ, σ]]

Compare the density histogram of the sample with the PDF of the estimated distribution:

Wolfram Language code: Show[Histogram[sample, Automatic, "PDF"], Plot[PDF[edist, x], {x, 0, 10}, PlotStyle -> Thick]]

Skewness grows exponentially with standard deviation σ:

Wolfram Language code: Plot[Skewness[LogNormalDistribution[μ, σ]], {σ, 0, 2}]

Wolfram Language code: Skewness[LogNormalDistribution[μ, σ]]

Limiting values:

Wolfram Language code: Limit[Skewness[LogNormalDistribution[μ, σ]], σ -> 0]

Wolfram Language code: Limit[Skewness[LogNormalDistribution[μ, σ]], σ -> ∞]

Kurtosis grows exponentially with standard deviation σ:

Wolfram Language code: Plot[Kurtosis[LogNormalDistribution[μ, σ]], {σ, 0, 1}]

Wolfram Language code: Kurtosis[LogNormalDistribution[μ, σ]]

Limiting values:

Wolfram Language code: Limit[Kurtosis[LogNormalDistribution[μ, σ]], σ -> 0]

Wolfram Language code: Limit[Kurtosis[LogNormalDistribution[μ, σ]], σ -> ∞]

Different moments with closed forms as functions of parameters:

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[LogNormalDistribution[μ, σ], k]//Factor, {k, 5}], M]

Closed form for symbolic order:

Wolfram Language code: Moment[LogNormalDistribution[μ, σ], r]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[LogNormalDistribution[μ, σ], k]//Factor, {k, 5}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[LogNormalDistribution[μ, σ], k]//Factor, {k, 5}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[LogNormalDistribution[μ, σ], k]//Factor, {k, 5}], C]

Hazard function:

Wolfram Language code: Plot[Table[HazardFunction[LogNormalDistribution[μ, 1.5], x], {μ, {-1, 0, 1}}]//Evaluate, {x, 0, 0.7}, Filling -> Axis]

Wolfram Language code:

Plot[Table[HazardFunction[LogNormalDistribution[1, σ], x], {σ, {0.5, 0.6, 0.8}}]//Evaluate, {x, 0, 4}, Filling -> Axis]

Wolfram Language code: HazardFunction[LogNormalDistribution[μ, σ], x]

Quantile function:

Wolfram Language code: Plot[Table[Quantile[LogNormalDistribution[2, σ], q], {σ, {0.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[Quantile[LogNormalDistribution[μ, 2], q], {μ, {1, 3, 5}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[LogNormalDistribution[μ, σ], q]

Applications (4)

Lognormal distribution can be used to model stock prices:

Wolfram Language code: googleStock = FinancialData["GOOGL", {{2006, 3, 10}, {2010, 3, 15}, "Day"}, "Value"]

Fit the distribution to the data:

Wolfram Language code: edist = EstimatedDistribution[googleStock, LogNormalDistribution[μ, σ]]

Compare the histogram to the PDF:

Wolfram Language code:

Show[Histogram[googleStock, 20, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "USDollars"]], {x, 0, 750}, PlotStyle -> Thick]]

Find the probability that the price is above $500:

Wolfram Language code: Probability[x > Quantity[500, "$"], xedist]

Find the mean price:

Wolfram Language code: Mean[edist]

Simulate the price for the consecutive 30 days:

Wolfram Language code: ListPlot[RandomVariate[edist, 30], Joined -> True, AxesLabel -> Automatic]

Lognormal distribution can be used to approximate wind speeds:

Wolfram Language code:

wind = WeatherData["Chicago", "WindSpeed", 
	{{2006, 1, 1}, {2009, 12, 31}, "Day"}];

Find the estimated distribution:

Wolfram Language code: windEstimate = EstimatedDistribution[wind, LogNormalDistribution[μ, σ]]

Compare the PDF to the histogram of the wind data:

Wolfram Language code:

Show[Histogram[wind["Values"], Automatic, "PDF", AxesLabel -> Automatic], Plot[PDF[windEstimate, Quantity[x, "kmph"]], {x, 0, 50}, PlotStyle -> Thick]]

Find the probability of a day with wind speed greater than 30 km/h:

Wolfram Language code: NProbability[x > Quantity[30, "kmph"], xwindEstimate]

Find the mean wind speed:

Wolfram Language code: Mean[windEstimate]

Simulate wind speeds for a month:

Wolfram Language code:

ListPlot[{RandomVariate[windEstimate, 30], {{0, Mean[windEstimate]}, {30, Mean[windEstimate]}}}, Joined -> {False, True}, Filling -> Axis, AxesOrigin -> {0, 0}, AxesLabel -> Automatic]

The fractional change of stock price at time (in years) is assumed to be lognormally distributed with parameters and :

Wolfram Language code: f𝒟[μ_, σ_, t_] = LogNormalDistribution[μ t, σ Sqrt[t]];

Compute expected stock price at epoch :

Wolfram Language code: PriceAtEpoch[S0_, μ_, σ_, t_] = S0 Mean[f𝒟[μ, σ, t]]

Assuming an investor can invest money for a year at a continuously compounded yearly rate risk-free, the risk-neutral pricing condition requires:

Wolfram Language code: PriceAtEpoch[Subscript[S, 0], μ, σ, t + 1] == PriceAtEpoch[Subscript[S, 0], μ, σ, t] Exp[r]

Solve for parameter :

Wolfram Language code: {sol} = Solve[ForAll[{t, Subscript[S, 0]}, %], μ, Reals]

Consider an option to buy this stock a year from now, at a fixed price . The value of such an option is:

Wolfram Language code: optVal[s_, 𝒦_] = Max[s - 𝒦, 0];

The risk-neutral price of the option is determined as the present value of the expected option value:

Wolfram Language code:

BlackScholesOptionPrice = Assuming[Subscript[S, 0] > 0 && r > 0 && σ > 0 && t > 0 && 𝒦 > 0, Exp[-r t]Expectation[optVal[𝒻 Subscript[S, 0], 𝒦], 𝒻f𝒟[μ /. sol, σ, t]]//FullSimplify]

Assuming rate of 5%, volatility parameter of 0.087, an initial price of $200 per share of stock, and a strike price of $190 per share, the Black–Scholes option price is:

Wolfram Language code: BlackScholesOptionPrice /. {r -> 0.05, σ -> 0.087, t -> 1, Subscript[S, 0] -> 200, 𝒦 -> 190}

GammaDistribution data can be approximated by a lognormal distribution:

Wolfram Language code: sample = RandomVariate[GammaDistribution[4, .5], 10 ^ 4];

Wolfram Language code: edist1 = EstimatedDistribution[sample, LogNormalDistribution[μ, σ]]

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist1, x], {x, 0, 6}, PlotStyle -> Thick]]

Comparing log-likelihoods with estimation by gamma distribution:

Wolfram Language code: edist2 = EstimatedDistribution[sample, GammaDistribution[α, β]]

Wolfram Language code: {LogLikelihood[edist1, sample], LogLikelihood[edist2, sample]}

Properties & Relations (9)

Lognormal distribution is closed under scaling by a positive factor:

Wolfram Language code: TransformedDistribution[c u, uLogNormalDistribution[μ, σ]]

Power of a LogNormalDistribution follows a lognormal distribution:

Wolfram Language code: TransformedDistribution[u ^ k, uLogNormalDistribution[μ, σ]]

In particular, a reciprocal of a lognormal distribution follows a lognormal distribution:

Wolfram Language code: TransformedDistribution[1 / u, uLogNormalDistribution[μ, ν]]

The product of two independent lognormally distributed variates follows lognormal distribution:

Wolfram Language code: TransformedDistribution[u v, {u LogNormalDistribution[μ1, σ1], vLogNormalDistribution[μ2, σ2]}]

Quotient of two independent lognormally distributed variates follows lognormal distribution:

Wolfram Language code: TransformedDistribution[u / v, {uLogNormalDistribution[μ1, σ1], vLogNormalDistribution[μ2, σ2]}]

Geometric mean of independent identically lognormally distributed variates follows lognormal distribution:

Wolfram Language code:

𝒟 = TransformedDistribution[(u v w) ^ (1 / 3), {u, v, w}ProductDistribution[{LogNormalDistribution[μ, σ Sqrt[3]], 3}]];

Wolfram Language code:

Block[{μ = 0.5, σ = 0.3}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[LogNormalDistribution[μ, σ], x], {x, 0, 4}, PlotStyle -> Thick]]]

Relationships to other distributions:

NormalDistribution is exponentially related to LogNormalDistribution:

Wolfram Language code: TransformedDistribution[Log[u], uLogNormalDistribution[μ, σ]]

Reverse transformation:

Wolfram Language code: TransformedDistribution[Exp[u], uNormalDistribution[μ, σ]]

Lognormal distribution is a special case of SL JohnsonDistribution:

Wolfram Language code: PDF[LogNormalDistribution[-γ / δ, 1 / δ], x]

Wolfram Language code: PDF[JohnsonDistribution["SL", γ, δ, 0, 1], x]

Wolfram Language code: % - %%//FullSimplify[#, δ > 0 && x > 0]&

SuzukiDistribution can be obtained from lognormal distribution and RayleighDistribution:

Wolfram Language code: 𝒟 = TransformedDistribution[u v, {uRayleighDistribution[1], vLogNormalDistribution[μ, ν]}];

Wolfram Language code:

Block[{μ = -1, ν = .2}, Show[Histogram[RandomVariate[𝒟, 10 ^ 4], 20, "PDF"], Plot[PDF[SuzukiDistribution[μ, ν], x], {x, 0, 2}, PlotStyle -> Thick]]]

Possible Issues (2)

LogNormalDistribution is not defined when μ is not a real number:

Wolfram Language code: Mean[LogNormalDistribution[3 + I, 6]]

LogNormalDistribution is not defined when σ is not a positive real number:

Wolfram Language code: Mean[LogNormalDistribution[3, -6]]

Substitution of invalid parameters into symbolic outputs gives results that are not meaningful:

Wolfram Language code: Mean[LogNormalDistribution[μ, σ]] /. {μ -> I, σ -> -1}

Neat Examples (2)

LogNormalDistribution is not uniquely determined by its sequence of moments:

Wolfram Language code:

log𝒩[μ_, σ_, k_, ϵ_] = ProbabilityDistribution[Refine[PDF[LogNormalDistribution[μ, σ], x], x > 0](1 + ϵ Sin[2 π k(Log[x] - μ) / σ^2]), {x, 0, ∞}, Assumptions -> σ > 0 && k > 0 && μ∈Reals && 0 < ϵ < 1]

Compute the sequence of moments:

Wolfram Language code: Assuming[r ≥ 0 && r∈Integers, Expectation[x ^ r, xlog𝒩[μ, σ, 1, 1 / 2]]//FullSimplify]

Compare it to the sequence of moments of the LogNormalDistribution:

Wolfram Language code: % == Moment[LogNormalDistribution[μ, σ], r]

Plot distribution densities:

Wolfram Language code: Plot[{PDF[LogNormalDistribution[0, 1], r], PDF[log𝒩[0, 1, 1, 1 / 2], r]}//Evaluate, {r, 0, 5}, Filling -> {1 -> {2}}]

PDFs for different σ values with CDF contours:

Wolfram Language code:

cdf = Function[{x, σ}, Evaluate[CDF[LogNormalDistribution[1, σ], x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[LogNormalDistribution[1, σ], x], {x, 0, 10}, {σ, 0.5, 1.5}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 80, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

More Learning

Tech Support

Data Science, Finance & Business

Engineering

Science & Technology

Technology for Education

Education Initiatives

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

LogNormalDistribution

Details

Background & Context

Examples

Basic Examples (4)

Scope (7)

Applications (4)

Properties & Relations (9)

Possible Issues (2)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

LogNormalDistribution

Details

Background & Context

Examples

Basic Examples (4)

Scope (7)

Applications (4)

Properties & Relations (9)

Possible Issues (2)

Neat Examples (2)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX