Visitar URL original
MatrixPropertyDistribution—Wolfram Documentation

WOLFRAM

Wolfram Language & System Documentation Center

MatrixPropertyDistribution[expr,xmdist]

represents the distribution of the matrix property expr where the matrix-valued random variable x follows the matrix distribution mdist.

MatrixPropertyDistribution[expr,{x1mdist1,x2mdist2,…}]

represents the distribution where x1, x2, … are independent and follow the matrix distributions mdist1, mdist2, ….

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
See Also
Related Guides
History
Cite this Page

MatrixPropertyDistribution

MatrixPropertyDistribution[expr,xmdist]

represents the distribution of the matrix property expr where the matrix-valued random variable x follows the matrix distribution mdist.

MatrixPropertyDistribution[expr,{x1mdist1,x2mdist2,…}]

represents the distribution where x1, x2, … are independent and follow the matrix distributions mdist1, mdist2, ….

Details

Examples

open all close all

Basic Examples  (3)

Approximate the mean of for Gaussian orthogonal matrix :

Wolfram Language code: Mean[MatrixPropertyDistribution[Tr[x.x], xGaussianOrthogonalMatrixDistribution[2]]]//N

Draw a sample solution of a random linear system:

Wolfram Language code: RandomVariate[MatrixPropertyDistribution[LinearSolve[m, {v1, v2, v3}], {mCircularRealMatrixDistribution[3], {v1, v2, v3}MultinormalDistribution[{0, 0, 0}, IdentityMatrix[3]]}]]

Estimate distribution of Log10 of condition number of a random matrix:

Wolfram Language code: matrixCondNum[mat_] := Norm[Inverse[mat]]Norm[mat]
Wolfram Language code: log10cn = RandomVariate[MatrixPropertyDistribution[Log10[matrixCondNum[x]], xWishartMatrixDistribution[10, HilbertMatrix[5]]], 10 ^ 5];
Wolfram Language code: SmoothHistogram[log10cn, Filling -> Axis]

Scope  (3)

Define distribution of a scalar-valued function of matrix argument:

Wolfram Language code: MatrixPropertyDistribution[Tr[𝓂.𝓂^], 𝓂MatrixNormalDistribution[IdentityMatrix[3], IdentityMatrix[3]]]

Approximate the mean of the function:

Wolfram Language code: Mean[%]//N

Define distribution of a vector-valued function of matrix argument:

Wolfram Language code: MatrixPropertyDistribution[Diagonal[𝓂], 𝓂InverseWishartMatrixDistribution[5, IdentityMatrix[3]]]

Sample from the distribution:

Wolfram Language code: RandomVariate[%, 3]

Define distribution from a random matrix and a random vector:

Wolfram Language code: cov = {{1, 1 / 2, 0}, {1 / 2, 1, 1 / 2}, {0, 1 / 2, 1}};
Wolfram Language code: 𝒟 = MatrixPropertyDistribution[{x1, x2, x3}.𝓂.{x1, x2, x3}, {𝓂WishartMatrixDistribution[100, cov], {x1, x2, x3}MultinormalDistribution[{0, 0, 0}, cov]}];

Approximate quartiles of the distribution:

Wolfram Language code: RandomVariate[𝒟, 10 ^ 5]//Quartiles

Applications  (4)

Sample determinant of matrix from GaussianOrthogonalMatrixDistribution:

Wolfram Language code: n = 2; dets = RandomVariate[MatrixPropertyDistribution[Det[x], xGaussianOrthogonalMatrixDistribution[n]], 10 ^ 6];

Compare the histogram to the known PDF:

Wolfram Language code: detpdf[y_] := (1/Sqrt[2])Exp[y] Piecewise[{{Erfc[Sqrt[2 y]], y ≥ 0}, {1, y < 0}}]
Wolfram Language code: Show[Histogram[dets, {0.1}, PDF], Plot[detpdf[y], {y, -5, 4}, Exclusions -> None]]

Estimate the spectral density of matrix from GaussianUnitaryMatrixDistribution:

Wolfram Language code: spectrum𝒟[n_] := MatrixPropertyDistribution[Eigenvalues[x], xGaussianUnitaryMatrixDistribution[n]];

The closed form is known to be the following:

Wolfram Language code: spectralPDF[n_Integer, y_] := Sqrt[(2/π n)]Exp[-2n y ^ 2]Sum[(1/2^jj!)HermiteH[j, Sqrt[2n] y]^2, {j, 0, n - 1}]

For smaller matrices, there is a characteristic oscillatory pattern:

Wolfram Language code: n = 3; eigvs = Join@@RandomVariate[spectrum𝒟[n], 10 ^ 5];

Compare the histogram of the sample to the known PDF:

Wolfram Language code: Show[Histogram[eigvs / (2Sqrt[n]), {0.05}, PDF], Plot[spectralPDF[n, x]//Evaluate, {x, -1.5, 1.5}]]

The number of density maxima is equal to the matrix size:

Wolfram Language code: n = 4; eigvs = Join@@RandomVariate[spectrum𝒟[n], 10 ^ 5];
Wolfram Language code: Show[Histogram[eigvs / (2Sqrt[n]), {0.05}, PDF], Plot[spectralPDF[n, x]//Evaluate, {x, -1.5, 1.5}]]

In the limit of large matrices, the density converges to WignerSemicircleDistribution:

Wolfram Language code: n = 250; eigvs = Join@@RandomVariate[spectrum𝒟[n], 10 ^ 2];
Wolfram Language code: Show[Histogram[eigvs / (2Sqrt[n]), {0.05}, PDF], Plot[PDF[WignerSemicircleDistribution[1], x], {x, -1.5, 1.5}, Exclusions -> None]]

The zeros of the Riemann zeta function have been conjectured to be related to the eigenvalues of Hermitian operators and matrices. Compare the normalized spacing of the zeros to the normalized spacing of the bulk eigenvalues of samples from GaussianUnitaryMatrixDistribution:

Wolfram Language code: n = 10 ^ 2; eigs = RandomVariate[MatrixPropertyDistribution[Take[Sort[Eigenvalues[x]], {1, 3}Quotient[n, 4]], xGaussianUnitaryMatrixDistribution[n]], 10 ^ 3];

Compare the histogram of normalized spacings to the known PDF:

Wolfram Language code: spacings = Flatten[(Differences[#] Sqrt[4 n - Most[#] ^ 2]& /@ eigs) / (2 Pi)];
Wolfram Language code: WignerSurmise[x_, 2] := 2(4 x / Pi) ^ 2 Exp[(-4 / Pi) x ^ 2]
Wolfram Language code: Show[Histogram[spacings, 50, PDF], Plot[WignerSurmise[x, 2], {x, 0, 2.5}]]

Compare this PDF to the normalized spacing for the zeros of the zeta function in the critical line for a series of the zeros starting at the ^(th) zero (Odzlyko):

Wolfram Language code: zeros = TemporalData[EventSeries, {{{2.6765339564884753*^11, 2.6765339564936237*^11, 2.6765339564968164*^11, 2.67653395649862*^11, 2.6765339565015765*^11, 2.6765339565043427*^11, 2.676533956505809*^11, 2.6765339565083447*^11, 2.6765339565105847*^ ... 676533982146852*^11, 2.6765339821491986*^11, 2.6765339821520862*^11, 2.6765339821532565*^11, 2.676533982157319*^11, 2.6765339821604626*^11}}, {{0, 9999, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> None}}, False, 10.3]; zlist = zeros["Values"];

Check that they indeed are zeros:

Wolfram Language code: {#, RiemannSiegelZ[#]}& /@ RandomChoice[zlist, 3]

Compare the histogram of normalized spacings to the known PDF for the random matrices:

Wolfram Language code: Show[Histogram[(Differences[zlist]/2 Pi) Log[(Most[zlist]/2 Pi)], 50, PDF], Plot[WignerSurmise[x, 2], {x, 0, 2.5}]]

Define distribution for scaled condition number of a WishartMatrixDistribution:

Wolfram Language code: n = 200; wmd = WishartMatrixDistribution[n, IdentityMatrix[n, SparseArray]]; cn𝒟 = MatrixPropertyDistribution[(1/n)Sqrt[(Max[#]/Min[#])]&[Eigenvalues[𝓂]], 𝓂wmd];

Sample the scaled condition number of a large matrix and check that it agrees with asymptotic closed-form distribution:

Wolfram Language code: asymp𝒟 = ProbabilityDistribution[(2κ + 4/κ^3)Exp[-(2/κ) - (2/κ^2)], {κ, 0, Infinity}];
Wolfram Language code: data = RandomVariate[cn𝒟, 2000];
Wolfram Language code: Show[ Histogram[data, {0.8}, PDF], Plot[PDF[asymp𝒟, κ], {κ, 0.1, 30}, PlotRange -> All]]

The asymptotic scaled condition number distribution has infinite mean:

Wolfram Language code: generalizedMean = Expectation[κ^α, κasymp𝒟, Assumptions -> 0 < α < 1]
Wolfram Language code: meanScaledCN = Limit[generalizedMean, α -> 1, Direction -> 1]

Simulate whether LinearSolve determines the random matrix to be ill‐conditioned:

Wolfram Language code: lucQ[m_] := Quiet[Check[LinearSolve[m];0, 1], LinearSolve::luc]
Wolfram Language code: condIndicators = RandomVariate[MatrixPropertyDistribution[lucQ[𝓂], 𝓂wmd], 5000];

Infer the probability that the random Wishart matrix is badly conditioned:

Wolfram Language code: FindDistributionParameters[condIndicators, BernoulliDistribution[p]]

Use asymptotic distribution to infer the critical ratio of the largest and the smallest eigenvalues:

Wolfram Language code: (n InverseSurvivalFunction[asymp𝒟, p /. %]) ^ 2
Wolfram Research (2015), MatrixPropertyDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html.

Text

Wolfram Research (2015), MatrixPropertyDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html.

CMS

Wolfram Language. 2015. "MatrixPropertyDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html.

APA

Wolfram Language. (2015). MatrixPropertyDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html

BibTeX

@misc{reference.wolfram_2026_matrixpropertydistribution, author="Wolfram Research", title="{MatrixPropertyDistribution}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_matrixpropertydistribution, organization={Wolfram Research}, title={MatrixPropertyDistribution}, year={2015}, url={https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html}, note=[Accessed: 14-November-2026]}