Visitar URL original
NHoldAll—Wolfram Documentation

WOLFRAM

Wolfram Language & System Documentation Center

NHoldAll

is an attribute which specifies that none of the arguments to a function should be affected by N.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

NHoldAll

NHoldAll

is an attribute which specifies that none of the arguments to a function should be affected by N.

Details

  • NHoldAll, NHoldFirst, and NHoldRest are useful in ensuring that arguments to functions are maintained as exact integers, rather than being converted by N to approximate numbers.

Examples

open all close all

Basic Examples  (1)

Prevent N from affecting the arguments of a function:

Wolfram Language code: SetAttributes[f, NHoldAll]
Wolfram Language code: N[f[1 + 2, 3 + Pi]]

Scope  (3)

System symbols with the NHoldAll attribute:

Wolfram Language code: ssymb = Cases[Map[ToExpression, Names["System`*"]], _Symbol]; Select[ssymb, MemberQ[Attributes[#], NHoldAll]&]

The arguments of Derivative remain unchanged with N:

Wolfram Language code: der = Derivative[1, 0, 1, 0][f][1, 2, 3, x]

N leaves the derivative order while changing the point of evaluation:

Wolfram Language code: nder = N[der]
Wolfram Language code: nder /. f -> Times

Define a pure function:

Wolfram Language code: f = #1 ^ 2 + Pi ^ 3(#1 ^ 2 - #2) ^ 2&;

The function with coefficients converted to numerical values:

Wolfram Language code: nf = N[f]
Wolfram Language code: nf[1, 2]

The positional parameters remain unchanged with N because Slot has the NHoldAll attribute:

Wolfram Language code: FullForm[f]

Applications  (2)

Use an indexed variable:

Wolfram Language code: SetAttributes[x, NHoldAll]

With this attribute, the variables remain unchanged:

Wolfram Language code: N[2x[1] + 5x[2]^2]

Define a data object that represents a polynomial in a sparse form {{c_(1),p_(1)},...}:

Wolfram Language code: spoly[cp_][x_] := Module[{c, n, p, y}, {p, c} = Transpose[SortBy[cp, Last]]; n = p[[-1]]; y = c[[-1]]; Do[y = c[[k]] + x ^ (n - p[[k]]) * y;n = p[[k]], {k, Length[p] - 1, 1, -1}]; If[n > 0, y *= x ^ n]; y]

Make sure that N only affects the coefficients, not the powers:

Wolfram Language code: N[e : spoly[cp_], pa_] := Module[{p, c, nc}, {c, p} = Transpose[cp]; nc = N[c, pa]; If[nc === c, e, spoly[Transpose[{nc, p}]]]]

Default N evaluation of the argument needs to be prevented for the rule above to work:

Wolfram Language code: SetAttributes[spoly, NHoldAll]

A representation of the polynomial :

Wolfram Language code: sp = spoly[{{1, 1}, {2, 2}, {3, 4}, {4, 8}}]
Wolfram Language code: {sp[x], Expand[sp[x]]}

Get the representation with approximate real coefficients:

Wolfram Language code: nsp = N[sp]

Evaluate at :

Wolfram Language code: nsp[π]

Properties & Relations  (1)

HoldAll prevents evaluation while NHoldAll only prevents numerical evaluation:

Wolfram Language code: SetAttributes[f1, HoldAll]
Wolfram Language code: f1[1 + 2, Pi + E]
Wolfram Language code: N[%]
Wolfram Language code: SetAttributes[f2, NHoldAll]
Wolfram Language code: f2[1 + 2, Pi + E]
Wolfram Language code: N[%]

You can prevent both by setting both attributes:

Wolfram Language code: SetAttributes[f, {HoldAll, NHoldAll}]
Wolfram Language code: f[1 + 2, Pi + E]
Wolfram Language code: N[%]
Wolfram Research (1996), NHoldAll, Wolfram Language function, https://reference.wolfram.com/language/ref/NHoldAll.html.

Text

Wolfram Research (1996), NHoldAll, Wolfram Language function, https://reference.wolfram.com/language/ref/NHoldAll.html.

CMS

Wolfram Language. 1996. "NHoldAll." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/NHoldAll.html.

APA

Wolfram Language. (1996). NHoldAll. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/NHoldAll.html

BibTeX

@misc{reference.wolfram_2026_nholdall, author="Wolfram Research", title="{NHoldAll}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/NHoldAll.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_nholdall, organization={Wolfram Research}, title={NHoldAll}, year={1996}, url={https://reference.wolfram.com/language/ref/NHoldAll.html}, note=[Accessed: 14-November-2026]}