PointCountDistribution
PointCountDistribution[pproc,reg]
represents the distribution of point counts for the point process pproc in the region reg.
PointCountDistribution[pproc,{reg1,…,regn}]
represents the joint distribution of point counts in regions regi.
Details
- PointCountDistribution is also known as count distribution.
- PointCountDistribution is distribution of point counts in point patterns resulting from the point process pproc.
- PointCountDistribution is typically used to estimate the total number of points in an observation such as the number of trees in a forest, number of cells in sample or number of defects on a surface.
- For a point process pproc, the point count in a full-dimensional region reg is a random variable whose distribution is represented by PointCountDistribution[pproc,reg].
- The mean of the PointCountDistribution[pproc,reg] is the mean measure of the point process pproc in the region reg.
- The regions regi and reg should be full dimensional and bounded as tested by SpatialObservationRegionQ, but in special cases can be defined with parameters.
- PointCountDistribution will simplify to known special distributions whenever possible.
- PointCountDistribution can be used with such functions as Mean, CDF and RandomVariate, etc.
Examples
open all close allBasic Examples (3)
Distribution of the number of points for a PoissonPointProcess in a unit disk:
PointCountDistribution[PoissonPointProcess[μ, 2], Disk[]]Find mean and variance of the number of points:
{Mean[%], Variance[%]}PointCountDistribution for a HardcorePointProcess in a unit ball:
dist = PointCountDistribution[HardcorePointProcess[10, .3, 3], Ball[]]DistributionParameterQ[dist]sample = RandomVariate[dist, 10 ^ 3];Histogram[sample, Automatic, "PDF"]PointCountDistribution for a GeoDisk:
proc = PoissonPointProcess[3 / Quantity[1, "Miles"] ^ 2, 2];PointCountDistribution[proc, GeoDisk[Here, Quantity[5, "Miles"]]]Scope (4)
PointCountDistribution of a BinomialPointProcess on a unit disk:
proc = BinomialPointProcess[10, Disk[]];PointCountDistribution[proc]The distribution of the number of points in a subregion:
reg = ImplicitRegion[1 / 4 ≤ x ^ 2 + y ^ 2 ≤ 1∧1 ≥ y ≥ x ≥ 0, {x, y}];Region[reg]dist = PointCountDistribution[proc, reg]Compute the mean number of points:
Mean[dist]//NPointCountDistribution of a InhomogeneousPoissonPointProcess over a unit disk:
proc = InhomogeneousPoissonPointProcess[Function[{x, y}, Exp[x + y]], 2];proc//PointProcessParameterQPointCountDistribution[proc, Disk[]]Over the union of two disjoint regions:
PointCountDistribution[proc, {Rectangle[{-1, -1}, {1, 1}], Rectangle[{2, 0}, {3, 1}]}]Histogram3D[RandomVariate[%, 10 ^ 6], 30, PDF]Over two intersecting regions:
PointCountDistribution[proc, {Rectangle[{-1, -1}, {1, 1}], Rectangle[{-2, 0}, {3, 1}]}]Histogram3D[RandomVariate[%, 10 ^ 6], 30, PDF]Mean[%%]PointCountDistribution for cluster processes of Neyman–Scott type is a CompoundPoissonDistribution:
reg = Disk[{0, 0}, r];PointCountDistribution[CauchyPointProcess[μ, λ, b, 2], reg]PointCountDistribution[MaternPointProcess[μ, λ, rad, 2], reg]PointCountDistribution[ThomasPointProcess[μ, λ, σ, 2], reg]PointCountDistribution[VarianceGammaPointProcess[μ, λ, α, β, 2], reg]In general, the point count distribution of a Neyman–Scott point process does not depend on the spatial distribution of the cluster points:
PointCountDistribution[NeymanScottPointProcess[μ, λ, NormalDistribution[a, b], 2], reg]PointCountDistribution[NeymanScottPointProcess[μ, λ, BinormalDistribution[ρ], 2], reg]Compute probabilities and expectations in the absence of the closed form of PointCountDistribution:
dist = PointCountDistribution[HardcorePointProcess[10, .3, 3], Ball[]];Compute mean using simulations:
NExpectation[n, ndist, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]Compute event probability using simulations:
NProbability[n > 20, ndist, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 3}]Applications (5)
Compute the average number of points in a unit disk for a Strauss point process:
𝒟 = PointCountDistribution[StraussPointProcess[20, 1, .2, 2], Disk[]];NExpectation[n, n𝒟, Method -> {"MonteCarlo", "SamplingIncrement" -> 10 ^ 4}]Suppose flaws in plywood occur on an average of one flaw per 50 square feet. Simulate the process of finding flaws on a per-square-foot basis:
pp = PoissonPointProcess[1 / 50, 2];
reg1 = Rectangle[{0, 0}, {100, 100}];
sample = RandomPointConfiguration[pp, reg1]ListPlot[sample]The number of flaws in a given region:
flawsDist1 = PointCountDistribution[pp, reg1]Find the probability that a 4-foot-by-8-foot sheet will have no flaws:
reg2 = Rectangle[{0, 0}, {4, 8}];flawsDist2 = PointCountDistribution[pp, reg2]Probability[x == 0, xflawsDist2]//NFor a round mirror with area 7.54 cm
, the probability of no flaws is 0.91. Using the same polishing process, another round mirror with an area of 19.50 cm
is fabricated. Assuming the flaws are independent and randomly located, find the probability of no flaws on the larger mirror:
flawProc[λ_] = PoissonPointProcess[λ, 2];mirror1 = Disk[{0, 0}, Sqrt[7.54 / π]];The distribution of the number of flaws in the mirror:
dist1 = PointCountDistribution[flawProc[λ], mirror1]Find the intensity of the flaw point process:
sol = First[Solve[Probability[x == 0, xdist1] == 0.9100 && λ > 0, λ]]//QuietThe distribution of the number of flaws in the second mirror:
mirror2 = Disk[{0, 0}, Sqrt[19.50 / π]];dist2 = PointCountDistribution[flawProc[λ /. sol], mirror2]The probability of no errors in the larger mirror:
PDF[dist2, 0]An LCD display has 1920×1080 pixels. A display is accepted if it has 15 or fewer faulty pixels. The probability that a pixel is faulty from production is 
and the faulty pixel positions are independent and random. Find the proportion of displays that are accepted:
faultProcess = PoissonPointProcess[5 10^-6, 2];display = Rectangle[{0, 0}, {1920, 1080}];Simulate the faulty pixel configuration:
samples = RandomPointConfiguration[faultProcess, display, 3]ListPlot[samples]The distribution of the number of faulty pixels in the display:
dist = PointCountDistribution[faultProcess, display]Find the probability of no more than 15 faulty pixels in the display:
NProbability[n ≤ 15, ndist]Find the pixel failure rate required to produce 4000×2000 pixel displays and still have an acceptance rate of at least 90%:
display2 = Rectangle[{0, 0}, {4000, 2000}];dist2 = PointCountDistribution[PoissonPointProcess[λ, 2], display2]prob = Probability[n ≤ 15, ndist2]Plot the acceptance rate as a function of the pixel failure rate:
LogLogPlot[prob, {λ, 10^-7, 10^-5}, GridLines -> All, Frame -> True, FrameLabel -> {"Pixel Failure Rate", None}, PlotLabel -> "LCD Acceptance Rate"]Find the maximal acceptable pixel failure rate:
Maximize[{λ, prob ≥ 0.90 && 10^-6 < λ < 2 10^-6}, λ, Reals]
CDF[dist2, 15] /. Last[%]Incidents of car-related thefts in Chicago:
geopos = GeoPosition[{{41.807586328, -87.615127788}, {41.961978526, -87.699709131},
{41.9378739, -87.750043614}, {41.79137343, -87.657233828}, {41.869859534, -87.721345338},
{41.903561493, -87.653509519}, {41.751579291, -87.578075178}, {41.813913673, ... .771736514, -87.66400571}, {41.935270542, -87.740044903},
{41.927801398, -87.754688495}, {41.770131721, -87.611528011}, {41.82467357, -87.626413225},
{41.84418573, -87.701349795}, {41.782546496, -87.64088957}, {41.808896916, -87.611437797}}];geoplot = GeoGraphics[GeoMarker[geopos, "Scale" -> Scaled[0.015]]]pts = Reverse /@ First[geopos];region = ConvexHullMesh[pts];f = HistogramPointDensity[pts]Define inhomogeneous Poisson point process with this intensity:
proc = InhomogeneousPoissonPointProcess[Function[{x, y}, f[{x, y}]], 2];dist = PointCountDistribution[proc, region]
Find the mean number of crimes:
Mean[dist]Compute the probability that the number of crimes is less than 1200:
Probability[n < 1200, ndist]Compute the expected number of incidents in ZIP code 60639:
reg = EntityValue[Entity["ZIPCode", "60639"], "Polygon"][[1, 1, 1, 1]];
reg = Polygon[Reverse /@ %];RegionQ[reg]RegionPlot[reg]Counts[RegionMember[reg, pts]][True]zip𝒟 = PointCountDistribution[proc, reg]
Mean[zip𝒟]Properties & Relations (4)
PointCountDistribution over pairwise disjoint region is a ProductDistribution:
reg1 = Disk[];
reg2 = Rectangle[{1, 1}, {3, 2.5}];
reg3 = Triangle[{{2, 3}, {4, 6}, {0, 3}}];Graphics[{EdgeForm[Gray], GrayLevel[.6], {reg1, reg2, reg3}}]proc = PoissonPointProcess[30, 2];PointCountDistribution over each region:
PointCountDistribution[proc, #]& /@ {reg1, reg2, reg3}Multivariate PointCountDistribution over the list of regions:
PointCountDistribution[proc, {reg1, reg2, reg3}]PointCountDistribution over overlapping regions:
reg1 = Disk[];
reg2 = Rectangle[{0, 0}, {2, 2}];
reg3 = Triangle[{{1, 1}, {4, 6}, {0, 3}}];Graphics[{EdgeForm[Gray], Opacity[.3], {reg1, reg2, reg3}}]proc = PoissonPointProcess[30, 2];PointCountDistribution over each region:
PointCountDistribution[proc, #]& /@ {reg1, reg2, reg3}Multivariate PointCountDistribution over the list of regions:
PointCountDistribution[proc, {reg1, reg2, reg3}]The components are correlated where the regions intersect:
Covariance[%]//MatrixFormPointCountDistribution over region covering for BinomialPointProcess:
reg = Rectangle[];
proc = BinomialPointProcess[100, reg];r1 = Rectangle[{0, 1 / 2}, {1 / 3, 1}];
r2 = RegionDifference[Disk[{0, 0}, 2 / 3, {0, π / 2}], r1];covering = {r1, r2, RegionDifference[reg, RegionUnion[r1, r2]]};Show[Table[Region[Style[covering[[i]], ColorData[97, i]]], {i, 3}]]Point count distribution for the covering:
PointCountDistribution[proc, covering]PointCountDistribution for a region with non-numeric parameters:
PointCountDistribution[PoissonPointProcess[μ, 2], Disk[{0, 0}, r]]Text
Wolfram Research (2020), PointCountDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/PointCountDistribution.html.
CMS
Wolfram Language. 2020. "PointCountDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PointCountDistribution.html.
APA
Wolfram Language. (2020). PointCountDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PointCountDistribution.html