SocketOpen
SocketOpen[port]
opens a socket that accepts TCP connections to localhost:port and returns a SocketObject representing the socket.
SocketOpen[address]
opens a socket that accepts TCP connections to the specified local address.
SocketOpen[address,"protocol"]
opens a socket that accepts connections with the specified protocol.
SocketOpen[address,{"protocol","type"}]
opens a socket that accepts connections of the specified protocol and type.
Details
- Supported protocols include:
-
"TCP" raw TCP stream protocol "ZMQ" ZeroMQ one-to-one message protocol {"ZMQ","type"} ZeroMQ protocol of the specified type - For ZMQ sockets, possible types include:
-
"Pair" socket that can send/receive with exactly one client peer "Publish" socket that sends messages out to all connected clients "Subscribe" socket that receives messages from a publisher socket "Request" socket to send request messages to a corresponding reply socket and receive response messages "Reply" socket to receive request messages from a corresponding "Request" socket and send response messages back "Dealer" same as "Request" socket except sent messages are delivered in round-robin style to all connected clients "Router" same as "Reply" socket except messages are received in fair-queueing style from all connected clients and maintains routing information "Pull" socket for pipeline topologies to receive messages "Push" socket for pipeline topologies to send messages "XPublish" same as "Publish", but received messages on this socket are subscriptions "XSubscribe" same as "Subscribe", but messages sent over this socket are used as subscriptions to the corresponding "XPublish" socket "Stream" socket for connecting a ZMQ socket to non-ZMQ TCP sockets - With no ZMQ protocol type specified, the underlying socket is a {"ZMQ","Pair"} socket.
- SocketOpen opens sockets only on your local machine.
- SocketOpen can use local addresses only. Possible forms include:
-
{host,port} local hostname or IP address and port number {host,"service"} local hostname or IP address and service name "host:port" local hostname or IP address with port {host,Automatic} an available port on the specified host Automatic an available port on localhost - Hostnames have forms like "www.wolfram.com".
- IP addresses can be given as "140.177.0.0" or IPAddress[string], where string is an IPv4 or IPv6 IP address.
- SocketConnect can be used to connect to sockets opened by SocketOpen. The fact that a socket is open on one machine does not guarantee that another machine can connect to it.
- For a connection to be established, the protocol must be consistent, and there must be no firewalls etc. blocking it.
- Information on how to use the different ZMQ socket types can be found in the ZeroMQ documentation.
- Close can be used to close a connection opened by SocketOpen.
Examples
open all close allBasic Examples (2)
Open a socket to allow client connections to it:
server = SocketOpen[Automatic]client = SocketConnect[server]Close /@ {server, client}zmqserver = SocketOpen[Automatic, "ZMQ"]Connect a client to the server:
zmqclient = SocketConnect[zmqserver]Write a message from the client to the server:
Write[zmqclient, "hello world"]Read the message on the server:
Read[zmqserver]Close /@ {zmqclient, zmqserver}Scope (3)
After clients have connected to an opened TCP socket, the clients can each be accessed as a SocketObject with the property "ConnectedClients".
Open a server socket to allow connections, and connect a client to the socket:
server = SocketOpen[Automatic];
clients = Table[SocketConnect[server], 2];List the client sockets from the server's perspective:
server["ConnectedClients"]These sockets also show up as remote sockets with Sockets:
SubsetQ[Sockets["Remote"], server["ConnectedClients"]]Close /@ Append[clients, server]Open a server socket on a specified IP address:
server1 = SocketOpen[{"127.0.0.1", Automatic}]Open a server socket on a specified port:
server2 = SocketOpen[{"127.0.0.1", 8000}]Close /@ {server1, server2}Open a ZMQ socket of type "Push", which can be used for a one-way message pipeline:
push = SocketOpen[Automatic, {"ZMQ", "Push"}]Connect with a "Pull" socket type:
pull = SocketConnect[push["DestinationPort"], {"ZMQ", "Pull"}]Write a message on the "Push" socket:
WriteString[push, "message"]Read the message on the "Pull" socket:
ByteArrayToString[SocketReadMessage[pull]]Close /@ {push, pull}Applications (1)
Implement a web server in the Wolfram Language with SocketOpen.
Start listening on a TCP port:
s = SocketOpen[Automatic, "TCP"]Initially there are no connected clients:
s["ConnectedClients"]Connect to a the server from a web browser:
SystemOpen["http://" <> First[s["DestinationIPAddress"]] <> ":" <> ToString[s["DestinationPort"]]]Now there is at least one client from the web browser:
s["ConnectedClients"]Write a generic response to all clients:
With[{html = "<html>
<body>
<h1>Hello from the Wolfram Language</h1>
<p>
Today's date is : " <> DateString[] <> "
<p>
</body>
</html>"}, WriteString[#,
"HTTP/1.1 200 OK
Date: " <> DateString[] <> " CDT
Content-Type: text/html
Content-Length: " <> ToString[StringLength[html]] <> "
" <> html <> "
"]]& /@ s["ConnectedClients"]Finally, close the server and the connections to the clients:
Close /@ s["ConnectedClients"]Close[s]Possible Issues (2)
It is not possible to create servers for web sockets:
SocketOpen[{"127.0.0.1", "ws"}]Writing on a socket returned from SocketOpen only works for ZMQ sockets; for TCP sockets, you must use the "ConnectedClients" property.
Open a TCP and a ZMQ socket and connect clients:
tcpServer = SocketOpen[Automatic, "TCP"];
zmqServer = SocketOpen[Automatic, "ZMQ"];
{tcpClient, zmqClient} = SocketConnect /@ {tcpServer, zmqServer};Writing on the TCP socket fails because you have to write to a specific client:
WriteString[tcpServer, "hello world"]
SocketReadyQ[tcpClient]In contrast, writing to a ZMQ socket directly works:
WriteString[zmqServer, "hello world"];
ByteArrayToString@SocketReadMessage[zmqClient]Close /@ {zmqClient, tcpClient, zmqServer, tcpServer}Related Links
ZMQ Socket Type DocumentationText
Wolfram Research (2017), SocketOpen, Wolfram Language function, https://reference.wolfram.com/language/ref/SocketOpen.html (updated 2020).
CMS
Wolfram Language. 2017. "SocketOpen." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/SocketOpen.html.
APA
Wolfram Language. (2017). SocketOpen. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SocketOpen.html