SystemModelAlways
SystemModelAlways[t,texpr]
SystemModelAlways[t,cond,texpr]
is True if texpr is always True in the intervals where the temporal expression cond is True.
Details
- SystemModelAlways is typically used to specify requirements that should always be satisfied, such as always demanding some behavior or always excluding some behavior.
- SystemModelAlways[t,texpr[t]] is True if texpr[t] is True for all validation times
. - SystemModelAlways[t,texpr[t]] is False if texpr[t] is False for some validation time
. - The times
and 
are given by the simulation interval of the system. - The condition cond is often used to select a subset of the validation interval, as in
. - SystemModelAlways[t,cond[t],texpr[t]] is True if texpr[t] is True for all t where cond[t] is True.
- SystemModelAlways or SystemModelEventually is used as the outer wrapper of a temporal specification in functions like SystemModelValidate.
Examples
open all close allBasic Examples (1)
Validate the requirement, "In flight, when one engine is off, the air distribution circuit must provide nominal performance.":
model = ConnectSystemModelComponents[...]Use SystemModelAlways to validate a condition that must always be satisfied:
SystemModelValidate[model, SystemModelAlways[t, "InFlight.y"[t] && "EngineOff.y"[t]"NominalPerformance.y"[t]]]Scope (4)
Basic Uses (2)
Validate requirements in a model of a pendulum:
model = CreateSystemModel["MyPendulum", {θ'[t] == ω[t], ω'[t] == -θ[t], right[t] == (θ[t] ≥ 0), θ[0] == 1}, t, {right∈ Booleans}, <|"SimulationSettings" -> <|"StopTime" -> 10|>|>];
SystemModelPlot[model, {θ, right}]Validate the requirement, "The angle must always be between 1 and 
.":
SystemModelValidate[model, SystemModelAlways[t, -1 ≤ θ[t] ≤ 1]]Validate the numerical solution against the exact result:
SystemModelValidate[model, SystemModelAlways[t, Cos[t] - 10.^-6 ≤ θ[t] ≤ Cos[t] + 10.^-6]]Validate the requirement, "The mass of the pendulum must always be to the right of the central position.":
smv = SystemModelValidate[model, SystemModelAlways[t, right[t]]]smv["FailurePlot", 1]Validate requirements in a model of a RC circuit:
model = CreateSystemModel["RCCircuit", {v[t] + r c v'[t] == 0, v[0] == v0, v0 == 1, r == 10, c == 1 / 5}, t, <|"SimulationSettings" -> <|"StopTime" -> 10|>|>];
SystemModelPlot[model, {v, v0 / E}]Validate a requirement with variables evaluated at specific times:
SystemModelValidate[model, SystemModelAlways[t, t < 2, v[r c] < v[t]]]Validate a requirement with variables evaluated at different times:
SystemModelValidate[model, SystemModelAlways[t, v[t + r c] ≤ v[t]]]Condition (2)
Validate requirements for times satisfying conditions in a model of a pendulum:
model = CreateSystemModel["MyPendulum", {θ'[t] == ω[t], ω'[t] == -θ[t], right[t] == (θ[t] ≥ 0), θ[0] == 1}, t, {right∈ Booleans}, <|"SimulationSettings" -> <|"StopTime" -> 10|>|>];
SystemModelPlot[model, {θ, right}]Validate the requirement, "The angle must always be non-negative for times less than or equal to 
.":
SystemModelValidate[model, SystemModelAlways[t, t ≤ π / 2, θ[t] ≥ 0]]Validate the requirement, "The angle must always be non-negative for times less than or equal to 
or a time between 
and 
.":
SystemModelValidate[model, SystemModelAlways[t, Or[t ≤ π / 4, 7π / 4 ≤ t ≤ 9π / 4], θ[t] ≥ 0]]Validate the requirement with a condition that uses intervals instead:
SystemModelValidate[model, SystemModelAlways[t, {t}∈Interval[{0, π / 4}, {7π / 4, 9π / 4}], θ[t] ≥ 0]]Validate the requirement, "The angle must always be non-negative for times between 
and 
.":
smv = SystemModelValidate[model, SystemModelAlways[t, π ≤ t ≤ 2π, θ[t] ≥ 0]]smv["FailurePlot", 1]Validate a requirement with a parameter-dependent condition:
model = CreateSystemModel["RCCircuit", {v[t] + r c v'[t] == 0, v[0] == v0, v0 == 1, r == 10, c == 1 / 5}, t, <|"SimulationSettings" -> <|"StopTime" -> 10|>|>];
SystemModelPlot[model, {v, v0 / E}]Validate a requirement in a model of an RC circuit:
SystemModelValidate[model, SystemModelAlways[t, t < r c, v[r c] < v[t]]]Applications (1)
Start with a simple model of aircraft collision resolution that uses a simple evasion algorithm:
model = \!\(\*GraphicsBox[«8»]\);Plot the trajectories of the planes:
SystemModelPlot[model]Validate the requirement, "The distance between the planes must stay above the distance parameter 
for each pair of planes.":
val = SystemModelValidate[model, SystemModelAlways[t, p < mind[t]]]The planes happen to get too close. To see this, validate the requirement for all plane distances:
failureDistances = Select[{d12, d13, d14, d15, d23, d24, d25, d34, d35, d45}, !SystemModelValidate[model, SystemModelAlways[t, p < #[t]], "ValidationSucceeded"]&]Plot the distance between a couple of planes and the distance threshold:
SystemModelPlot[model, {First[failureDistances], p}]Related Links
Wolfram System Modeler DocumentationText
Wolfram Research (2025), SystemModelAlways, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemModelAlways.html.
CMS
Wolfram Language. 2025. "SystemModelAlways." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SystemModelAlways.html.
APA
Wolfram Language. (2025). SystemModelAlways. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemModelAlways.html