Visitar URL original
GeoModel—Wolfram Documentation

WOLFRAM

Wolfram Language & System Documentation Center

GeoModel

is an option for GeoGraphics that specifies the reference body or model for it for the purposes of geodetic computations and map drawing.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

GeoModel

GeoModel

is an option for GeoGraphics that specifies the reference body or model for it for the purposes of geodetic computations and map drawing.

Details

  • The following settings can be used:
  • Automaticuse the "ITRF00" datum for the Earth
    "datum"any of the datums in GeodesyData["Datum"]
    "ellipsoid"any of GeodesyData["ReferenceEllipsoid"]
    {a,b}an explicit ellipsoid with semiaxes a≥b
    ra sphere of radius r
    entitya planet or planetary moon Entity object
  • The semiaxes lengths a, b in GeoModel{a,b} and the radius r in GeoModelr can be given either as numbers in meters or Quantity lengths.

Examples

open all close all

Basic Examples  (2)

Use the default (ellipsoidal) model of the Earth, where geodesics do not close:

Wolfram Language code: GeoGraphics[{Arrow@GeoPath[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}], GeoDisplacement[{Quantity[120000, "Kilometers"], "NW"}]}]}, GeoCenter -> Entity["City", {"NewYork", "NewYork", "UnitedStates"}], GeoRange -> Quantity[200, "Miles"]]

Use a spherical model of the Earth, where geodesics close:

Wolfram Language code: GeoGraphics[{Arrow@GeoPath[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}], GeoDisplacement[{Quantity[120000, "Kilometers"], "NW"}]}]}, GeoCenter -> Entity["City", {"NewYork", "NewYork", "UnitedStates"}], GeoRange -> Quantity[200, "Miles"], GeoModel -> Quantity[6371, "Kilometers"]]

Use Mars as a reference model:

Wolfram Language code: GeoGraphics[GeoModel -> Entity["Planet", "Mars"], GeoProjection -> "Bonne", GeoRange -> All, GeoGridLines -> Quantity[15, "AngularDegrees"], GeoGridLinesStyle -> Directive[Orange, Opacity[0.5]], Background -> Black, PlotRangePadding -> 0.2]

Use the Moon:

Wolfram Language code: GeoGraphics[GeoModel -> Entity["PlanetaryMoon", "Moon"], GeoRange -> All, GeoProjection -> {"LambertAzimuthal", "Centering" -> {90, 0}}, GeoGridLines -> Quantity[30, "AngularDegrees"], GeoGridLinesStyle -> Directive[Blue, Opacity[0.5]], Background -> Black, PlotRangePadding -> 0.2]

Applications  (1)

Store the coordinates/sizes of the lunar maria:

Wolfram Language code: maria = EntityClass["SolarSystemFeature", "MoonMare"]; coords = EntityValue[maria, "Position"]; sizes = EntityValue[maria, "Size"] / 2; data = Transpose[{coords, sizes, EntityList[maria]}];

Plot the maria together with their names (as tooltips):

Wolfram Language code: GeoGraphics[{GeoStyling[Directive[Opacity[.6], RandomColor[], EdgeForm[Black]]], Tooltip[GeoDisk[#1, #2], CommonName[#3]]}&@@@data, GeoModel -> Entity["PlanetaryMoon", "Moon"], GeoRange -> All, GeoProjection -> "Mollweide", GeoGridLines -> Quantity[15, "AngularDegrees"], GeoGridLinesStyle -> Directive[Thin, Blue, Opacity[0.4]], Background -> Black, PlotRangePadding -> 0.2, ImageSize -> Medium]

Properties & Relations  (2)

Show unclosed geodesics, which are one consequence of the nonsphericity of the Earth:

Wolfram Language code: GeoGraphics[{Thin, GeoPath[{{0, 0}, Quantity[1*10^6, "Kilometers"], Quantity[45, "AngularDegrees"]}]}, GeoRange -> "World"]

Compare with a spherical model:

Wolfram Language code: GeoGraphics[{Thin, GeoPath[{{0, 0}, Quantity[1*10^6, "Kilometers"], Quantity[45, "AngularDegrees"]}]}, GeoRange -> "World", GeoModel -> Quantity[6378, "Kilometers"]]

Large disks accumulating around the antipodal point, using a spherical model of the Earth:

Wolfram Language code: GeoGraphics[Table[GeoDisk[GeoPosition[{0, 80}], r], {r, 19970000, 20030000, 10000}], GeoProjection -> "Equirectangular", GeoRange -> {{-0.7, 0.7}, {-100.7, -99.3}}, GeoModel -> GeodesyData["ITRF00", "SemimajorAxis"]]

The default reference model is an ellipsoid:

Wolfram Language code: GeoGraphics[Table[GeoDisk[GeoPosition[{0, 80}], r], {r, 19970000, 20030000, 10000}], GeoProjection -> "Equirectangular", GeoRange -> {{-0.7, 0.7}, {-100.7, -99.3}}]
Wolfram Research (2014), GeoModel, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoModel.html.

Text

Wolfram Research (2014), GeoModel, Wolfram Language function, https://reference.wolfram.com/language/ref/GeoModel.html.

CMS

Wolfram Language. 2014. "GeoModel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoModel.html.

APA

Wolfram Language. (2014). GeoModel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoModel.html

BibTeX

@misc{reference.wolfram_2026_geomodel, author="Wolfram Research", title="{GeoModel}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/GeoModel.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geomodel, organization={Wolfram Research}, title={GeoModel}, year={2014}, url={https://reference.wolfram.com/language/ref/GeoModel.html}, note=[Accessed: 14-November-2026]}