GeoGraphics
GeoGraphics
| Basic Mapping | Geo Primitives |
| Geographical Locations and Computations | Geo Styling |
| Ranges of Coordinates and Projections | Other Celestial Bodies |
Since Version 10.0 of the Wolfram Language, GeoGraphics allows a simple and general way of constructing maps of the surface of the Earth and other celestial bodies. GeoGraphics combines the powerful Graphics functionality with fast and highly precise geodetic computations and also direct access to the Wolfram Knowledgebase through the Entity framework.
The fundamental new ingredient in GeoGraphics with respect to standard 2D Graphics is the fact that the surface of the Earth is curved and therefore must be distorted to produce a flat map (on a piece of paper or the computer screen). This always requires a choice of a cartographic projection, a function that determines how points on the curved surface are mapped to points on the flat map. The GeoProjectionData paclet provides a large collection of projections.
GeoGraphics also introduces new graphical primitives like GeoPath, GeoDisk, and GeoHemisphere, adapted to the Earth's curvature, and even time-dependent geo primitives like DayHemisphere and DayNightTerminator.
The GeoGraphics functionality can easily access the Wolfram Knowledgebase to obtain geographical information using the Entity framework, providing homogeneous access to a large number of properties about dozens of types of objects, from countries and cities to bridges, earthquakes, and artificial satellites.
GeoGraphics is also fully integrated with the geodesy functionality of the Wolfram Language, extensively updated for Version 10.0. This functionality is now much faster and precise to millimeters on the surface of the ellipsoidal Earth. GeoPosition allows specification of any position on the Earth, in any of the large collection of ellipsoids of GeodesyData—for example, the WGS84 reference used by GPS satellites.
This tutorial provides an introduction to GeoGraphics and its associated functions. The tutorial starts by showing how to easily construct maps of arbitrary regions or geographical entities, letting GeoGraphics choose appropriate coordinate ranges, projections, etc. for you. Then it explains how you can choose all those options to fine-tune the maps to your needs.
The simplest and most important operation is obtaining a map of a given region of interest. The Entity framework provides a fast and homogeneous way to obtain the required positional information. GeoGraphics will then choose an adequate projection, generally the "Mercator" projection for small to medium scales (under 2000 km diagonally, approximately).
| GeoGraphics[primitives,options] | draw a map |
GeoGraphics[Entity["Country", "France"]]GeoGraphics[Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]With no argument specification, GeoGraphics gives by default a map of your local area, as determined by $GeoLocation, with a radius of around 10 miles.
$GeoLocationGeoGraphics[Here]Maps of the whole world are obtained by using the option value GeoRange"World". Such maps are given by default using the so-called "Equirectangular" projection, in which the horizontal axis is exactly longitude and the vertical axis is exactly latitude. Similarly, GeoRange"Country" gives a map of your country, and GeoGraphics will choose a projection that minimizes distortion of the map.
GeoGraphics[GeoRange -> "World"]A map of your country, again as determined by $GeoLocation:
GeoGraphics[GeoRange -> "Country"]AbsoluteOptions[%, GeoProjection]AbsoluteOptions[%%, GeoRange]The options GeoRange, GeoRangePadding, GeoCenter, and GeoZoomLevel allow multiple ways of specifying the regions of interest. They will be studied in detail later on in this tutorial.
GeoGraphics[GeoRange -> {{48.7, 49}, {2, 2.5}}]GeoGraphics[GeoRange -> {{48.7, 49}, {2, 2.5}}, GeoRangePadding -> Quantity[10, "Kilometers"]]Table[GeoGraphics[GeoCenter -> Entity["Building", "NotreDameCathedral::95fcw"], GeoZoomLevel -> zoom], {zoom, {1, 5, 8, 11, 15, 18}}]You can also change the zoom level of an image without changing its geo range. This results in increasingly more detail:
Table[GeoGraphics[GeoRange -> {{48.71, 49.02}, {2.12, 2.55}}, GeoZoomLevel -> zoom], {zoom, {7, 8, 9, 10, 11, 12}}]ByteCount /@ %So far maps have been produced showing the geo background image corresponding to a given region. The GeoGraphics language provides a variety of objects, called geo primitives, that can be placed on the map. These geo primitives can be point-like (Point or GeoMarker), line-like (GeoPath, GeoCircle, Line, ...), or area-like (GeoDisk, GeoHemisphere, Polygon, ...).
GeoGraphics[GeoMarker[EntityClass["Country", "SouthAmerica"]["CapitalCity"]], GeoRangePadding -> Quantity[1000, "Miles"], GeoProjection -> "Equirectangular"]GeoGraphics[GeoPath[{Entity["City", {"Santiago", "Metropolitana", "Chile"}], Entity["City", {"Madrid", "Madrid", "Spain"}]}]]GeoGraphics[GeoDisk[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[60, "Miles"]]]GeoGraphics[Polygon[Entity["Country", "UnitedStates"]]]There are multiple ways to stylize a map. You can add parallels and meridians, a scale bar, or change the geo background to depict a relief map of elevation data or a contour plot. You can change colors and opacities, or even place images inside 2D geo primitives like geo disks or polygons—and many more options.
A map of Spain and Portugal with latitude and longitude lines separated 1 degree and a scale bar in kilometers:
GeoGraphics[Entity["Country", "Spain"], GeoGridLines -> Quantity[1, "AngularDegrees"], GeoScaleBar -> "Metric"]GeoGraphics[Entity["Country", "Spain"], GeoBackground -> GeoStyling["ReliefMap"]]GeoGraphics[{GeoStyling[{"Image", Entity["Country", "Spain"]["Flag"]}], Polygon[Entity["Country", "Spain"]]}]GeoGraphics[GeoRange -> All, GeoModel -> Entity["PlanetaryMoon", "Moon"], GeoProjection -> "Orthographic", Background -> Black]GeoGraphics[Entity["SolarSystemFeature", "OlympusMonsMars"], GeoRange -> Quantity[400, "Miles"], GeoModel -> Entity["Planet", "Mars"]]GeoPosition and Geo Entities
Specific locations on the Earth are given as GeoPosition[{lat,lon}] objects, with latitude and longitude coordinates given in degrees, with standard conventions. GeoPosition can also convert other forms of input into that notation for convenience, including geographical Entity and EntityClass objects.
| GeoPosition[{lat,lon}] | position on the surface of the Earth |
| Entity["type",name] | entity of a given type |
| EntityClass["type",name] |
class of entities of a given type, equivalent to a list of entities
|
GeoPosition[{90, 0}]GeoPosition["NorthPole"]GeoPosition["34d 25m 7.5s S, 123° 56' 32.12'' E"]GeoPosition[{"34d 25m 7.5s S", "123° 56' 32.12'' E"}]Give angles as Quantity objects, in any unit:
GeoPosition[{Quantity[1, "Radians"], Quantity[123.456, "AngularDegrees"]}]Convert geographical Entity data into numeric coordinates:
GeoPosition[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]GeoPosition[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}]]EntityValue[Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], "Position"]GeoPosition can also handle arrays of coordinates. This is useful for working efficiently with many points at the same time. Points of the array can be given in different notations, and GeoPosition will convert them all to numeric coordinates.
EntityList[EntityClass["Building", "AcropolisAthens"]]GeoPosition[%]First[%]An EntityClass object is interpreted as representing the list of its members:
GeoPosition[EntityClass["Building", "AcropolisAthens"]]GeoPosition[[image]]GeoPosition[{Entity["City", {"Paris", "IleDeFrance", "France"}], {48.86, 2.34}, {Quantity[48.86, "AngularDegrees"], Quantity[2.34, "AngularDegrees"]}, {"48°51'36.''N", "2°20'24.''E"}}]//FirstDistances and Bearings (Angles)
Together with the coordinate positions of given locations, it is generally important to know distances between any two of them, as well as the compass direction you need to follow to go from one to another. Distances are computed along geodesics, i.e. basically the shortest curve between two positions. Angles are given as bearings, namely the angle from the north to that geodesic line, measured clockwise in degrees. In the Wolfram Language, distances on the surface of the Earth are measured with GeoDistance, and bearings are computed with GeoDirection.
| GeoDistance[loc1,loc2] | geodesic distance between two locations |
| GeoDirection[loc1,loc2] | angle from north at loc1 of the geodesic from loc1 to loc2 |
| GeoDisplacement[loc1,loc2] | distance and angle at loc1 of the geodesic from loc1 to loc2 |
| GeoDestination[loc1,displ] | end position of the geodesic given by displ starting at loc1 |
newyork = GeoPosition[Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]
paris = GeoPosition[Entity["City", {"Paris", "IleDeFrance", "France"}]]GeoGraphics[GeoPath[{newyork, paris}], GeoBackground -> "ReliefMap"]dist = GeoDistance[newyork, paris]$UnitSystemTo change to any other unit, use UnitConvert:
UnitConvert[dist, "Kilometers"]You can also modify the unit system required in the GeoDistance call itself:
GeoDistance[newyork, paris, UnitSystem -> "Metric"]You can use the Entity objects directly to compute distances, but then the Wolfram Language functions try to use polygonal information, when available, rather than purely point-like positions. That means that GeoDistance will return the smallest possible distance when considering all points of the polygons.
borderdist = GeoDistance[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Paris", "IleDeFrance", "France"}]]dist - borderdistGeoDistance[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Paris", "IleDeFrance", "France"}], DistanceFunction -> "Center"]GeoGraphics[{Polygon[Entity["City", {"NewYork", "NewYork", "UnitedStates"}]], GeoMarker[newyork]}]Bearings are computed with GeoDirection. Currently this function does not handle polygonal information, only positional information. A warning message is issued when appropriate.
GeoDirection[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Paris", "IleDeFrance", "France"}]]
DMSString[%]GeoDirection always uses center positions; hence, the previous result equals the following:
%% == GeoDirection[newyork, paris]GeoDirection[Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]
GeoDisplacement reports both distance (in meters) and bearing (in degrees):
GeoDisplacement[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Paris", "IleDeFrance", "France"}]]
Knowing the geo displacement and the initial position, it is possible to recover the final position:
GeoDestination[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], %]
{%, GeoPosition[Entity["City", {"Paris", "IleDeFrance", "France"}]]}Relational Positioning
Given a location, it is frequently important to know instances of a particular type of entity that are at a short distance from it. This is the role of the function GeoNearest. If the locations or entities are extended, you may also be interested in inclusion relations.
| GeoNearest[enttype,loc] | entities of type enttype closest to loc |
| GeoIdentify[enttype,loc] | entities of type enttype that contain loc |
| GeoEntities[reg,enttype] | entities of type enttype contained in the region reg |
| GeoWithinQ[reg,loc] | check whether loc is contained in the region reg |
GeoNearest["Ocean", Here]GeoNearest["Country", GeoPosition[{50, 20}], 4]Other relations are essentially derivates of GeoNearest. For example, GeoIdentify returns all entities containing a given location, by default your current geo location.
GeoIdentify[]EntityTypeName /@ %GeoIdentify["AdministrativeDivision", Entity["City", {"Rome", "Lazio", "Italy"}]]Vice versa, GeoEntities lists the entities contained in a given extended entity.
GeoEntities[Entity["AdministrativeDivision", {"Toscana", "Italy"}], "AdministrativeDivision2"]GeoEntities[Entity["City", {"Dallas", "Texas", "UnitedStates"}], "Building"]The function GeoWithinQ checks inclusion of a geographical location (extended or not) inside a geographical region.
GeoWithinQ[Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}]]GeoWithinQ[Entity["Ocean", "AtlanticOcean"], Entity["Island", "Tenerife"]]GeoWithinQ[Entity["Ocean", "MediterraneanSea"], Entity["Island", "Tenerife"]]All these computations are sent to the Wolfram geo server, and results are then downloaded from it. In some cases it is possible to perform the operations locally using Nearest.
country = $GeoLocationCountrypoints = EntityValue[country, "Polygon"][[1]]Nearest[points, Here][[1]]GeoGraphics[{Polygon[country], Red, Arrow[GeoPath[{Here, %}]]}]Geo Entity Variants
Sometimes you want a map of the main area of a country, without including smaller islands or dependencies that may be very far away. Or you may need a map including all territories. In those cases, the Wolfram Language specifies the additional information using the head GeoVariant.
| GeoVariant[entity,variant] | a geographical variant of an entity |
GeoGraphics[{EdgeForm[Thick], Polygon[Entity["Country", "UnitedStates"]]}]GeoGraphics[{EdgeForm[Thick], Polygon[GeoVariant[Entity["Country", "UnitedStates"], "AllAreas"]]}]Something intermediate is given by the variant "PrincipalArea" and its downsampled form "SimplifiedArea". In this case the US map includes Alaska and Hawaii:
GeoGraphics[{EdgeForm[Thick], Polygon[GeoVariant[Entity["Country", "UnitedStates"], "SimplifiedArea"]]}]GeoGraphics[{EdgeForm[Thick], Polygon[GeoVariant[Entity["Country", "UnitedStates"], "DefaultMapArea"]]}]Other geo functions can also handle geo entity variants. However, the defaults are not necessarily the same. For example, the default variants for GeoNearest are sometimes larger than the corresponding defaults in GeoGraphics.
GeoNearest["Country", Entity["Country", "Netherlands"], 4]GeoNearest["Country", GeoVariant[Entity["Country", "Netherlands"], "AllAreas"], 4]$GeoLocation and FindGeoLocation
The Wolfram Language can determine your approximate location using GeoIP information. This is done with FindGeoLocation, and the result is stored in the global variable $GeoLocation. The variable Here is an alternative way of accessing the current geo location. Many of the functions related to GeoGraphics will default to that position when location information is not provided. You can manually set $GeoLocation to any other position you want, and then your Wolfram Language session will behave as if you were at that position. When the value of $GeoLocation is set, the variables $GeoLocationCity and $GeoLocationCountry are automatically assigned to the city and country containing $GeoLocation, or the nearest possible city and country. Note that changing your $GeoLocation does not automatically change $TimeZone.
| $GeoLocation | resettable variable containing your current geo location |
| Here | a simpler way to obtain your current geo location |
| $GeoLocationCity | nearest city to your current geo location |
| $GeoLocationCountry | nearest country to your current geo location |
| FindGeoLocation[] | find your current geo location using GeoIP information |
The current $GeoLocation:
$GeoLocationHereGeoGraphics[Here]Change $GeoLocation to some other position:
$GeoLocation = GeoPosition[Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]GeoGraphics[Here]$GeoLocation = FindGeoLocation[]Use FindGeoLocation to find approximate locations for addresses.
FindGeoLocation["Times Square, New York, US"]GeoGraphics[GeoMarker[%], GeoRange -> Quantity[1, "Miles"]]Latitude and Longitude: GeoRange
The most general way of specifying the region covered by a map in latitude and longitude coordinates is using the option GeoRange{{latmin,latmax},{lonmin,lonmax}}. As usual, the angles are given in degrees, with standard conventions. Any other specification of a geo region is eventually converted internally into one such range specification, perhaps extended as determined by the GeoRangePadding option.
| GeoRange | option of GeoGraphics that specifies the ranges of the map |
GeoBounds computes the latitude and longitude ranges of any geographical region:
bounds = GeoBounds[Entity["Country", "France"]]A map using the "Equirectangular" projection will show that region with axes corresponding to those coordinate ranges. When using a specific numerical geo range, there is no padding added:
GeoGraphics[GeoRange -> bounds, GeoProjection -> "Equirectangular", Frame -> True]GeoGraphics[GeoRange -> "World", Frame -> True]{GeoGraphics[GeoRange -> {{-90, 90}, {-90, 90}}, Frame -> True], GeoGraphics[GeoRange -> {{-90, 90}, {90, 270}}, Frame -> True]}Longitudes {lonmin,lonmax} can be given in any determination. lonmax is adjusted modulo 360 to be larger than lonmin:
GeoGraphics[GeoRange -> {{-90, 90}, {90, -90}}, Frame -> True]The determination used in the longitude range is preserved in the result, though only for cylindrical projections (see types of projections below):
GeoGraphics[GeoRange -> {{-90, 90}, {1000, 1180}}, Frame -> True]GeoCenter
An alternative way to provide a geo range is to give a center point and a distance radius, defining a geo disk on the Earth's surface. The geo range is then the rectangle in {lat,lon} coordinates that fully encloses that geo disk. This is done by using the options GeoCenter and GeoRange, the latter now containing only the distance radius.
| GeoCenter | option of GeoGraphics that specifies the center of the map |
GeoGraphics[GeoCenter -> Entity["City", {"Dublin", "Dublin", "Ireland"}], GeoRange -> Quantity[100, "Miles"]]The GeoCenter option can also be used to select the center point of a map whose GeoRange was automatically obtained from the input. If the option GeoRange explicitly specifies a region, it will always override any other information provided by GeoCenter.
GeoGraphics[Polygon[Entity["Country", "Germany"]], GeoCenter -> Entity["City", {"Munich", "Bavaria", "Germany"}]]GeoGraphics[Polygon[Entity["Country", "Germany"]], GeoCenter -> Entity["City", {"Munich", "Bavaria", "Germany"}], GeoRange -> Entity["Country", "Germany"]]GeoGraphics[GeoRange -> "World", GeoCenter -> 100]Other Specifications of the Map Region
GeoGraphics accepts location information in input, not inside geo primitives. That information contributes to the specification of the ranges of the map, but nothing is rendered on the map associated to it. Again, when only center information is available, the default scale of the map is approximately 10 miles in radius.
GeoGraphics[GeoPosition[{41.9, 12.5}]]GeoGraphics[{Blue, GeoCircle[GeoPosition[{41.9, 12.5}], Quantity[10, "Miles"]]}, GeoScaleBar -> "Imperial"]GeoGraphics[GeoPosition[{41.9, 12.5}], GeoRange -> Quantity[100, "Kilometers"]]When using an Entity object, GeoGraphics consults with EntityValue about whether position and polygon information exists. If a geo polygon can be obtained, then that means there is also a clear sense of scale. If a polygon cannot be obtained, then you proceed with the center position and the default scale as before.
This is the polygon surrounding Seattle. It contains a GeoPosition object with multiple {lat,lon} pairs inside:
EntityValue[Entity["City", {"Seattle", "Washington", "UnitedStates"}], "Polygon"]GeoGraphics[Entity["City", {"Seattle", "Washington", "UnitedStates"}]]GeoGraphics[GeoPosition[Entity["City", {"Seattle", "Washington", "UnitedStates"}]]]Currently there is no polygon information for Rome, and hence these two maps cover identical ranges:
With[{rome = Entity["City", {"Rome", "Lazio", "Italy"}]}, AbsoluteOptions[#, GeoRange]& /@ {GeoGraphics[rome], GeoGraphics[GeoPosition[rome]]}]Projected Coordinates
For large areas of the world, the default projection is "Equirectangular", in which the map coordinates are directly longitude and latitude. However, for smaller areas of the world it is more convenient to choose other projections, to decrease distortion. The map coordinates do not then have immediate angular meaning. For example, for low scales (approximately under 2000 km diagonally) the default projection is "Mercator", which preserves shapes. In this case, the horizontal axis still represents longitude, but the vertical axis is not latitude anymore.
The Mercator projection is frequently used in map services on the internet. However, it highly distorts distances and areas near the poles. In fact, the poles are mapped at infinite distance along the vertical axes, and therefore the Mercator projection cannot show the whole world in a map. GeoGraphics allows you to choose the projection needed, and the paclet GeoProjectionData provides one of the most extensive collections of projections available. When no explicit projection is indicated, GeoGraphics will choose an appropriate projection for you, based on the scale and center of the map.
| GeoProjection | option of GeoGraphics that specifies the cartographic projection |
berlin = GeoPosition[Entity["City", {"Berlin", "Berlin", "Germany"}]]map = GeoGraphics[GeoMarker[berlin], GeoRange -> Entity["Country", "Germany"], Frame -> True]This is the projection used in the map, a Mercator projection, with adapted "Centering" and "GridOrigin" parameters so that the horizontal axis still represents true longitude:
proj = GeoProjection /. AbsoluteOptions[map, GeoProjection]GeoGridPosition will give you the exact coordinates in the projection chosen:
GeoGridPosition[berlin, proj]GeoGraphics[GeoMarker[berlin], GeoRange -> Entity["Country", "Germany"], GeoProjection -> proj, Frame -> True]GeoGraphics[GeoMarker[berlin], GeoRange -> EntityClass["Country", "WesternEurope"], GeoProjection -> proj, Frame -> True, GeoGridLines -> Automatic]For intermediate-scale maps, the default projection is "LambertAzimuthal". The coordinate values do not then have an immediate meaning in terms of latitude or longitude angles.
map = GeoGraphics[Polygon[Entity["Country", "UnitedStates"]], Frame -> True]AbsoluteOptions[map, GeoProjection]map = GeoGraphics[Polygon[Entity["Country", "UnitedStates"]], Frame -> True, GeoGridLines -> Quantity[5, "AngularDegrees"], GeoGridLinesStyle -> StandardYellow]GeoGraphics[Polygon[Entity["Country", "UnitedStates"]], Frame -> True, GeoGridLines -> Quantity[5, "AngularDegrees"], GeoGridLinesStyle -> StandardYellow, GeoProjection -> "Mercator"]Introduction to Geo Projections
There are many functions and parameters to control cartographic projections and projected coordinates in the Wolfram Language. This subsection gives a brief summary of them. See the documentation of GeoProjection and GeoProjectionData for more detailed information.
Cartographic projections are functions of points on the surface of the Earth onto points on the surface of a flat map, a process that always involves some form of distortion. There are many possible choices of such functions, and the actual choice must be determined by the practical and aesthetic properties of the result, like minimizing distortion in some sense. This leads to several possible classifications of projections.
Many projections are defined using geometric methods of mapping points on a sphere to points on a tangent plane ("azimuthal" projections), a tangent cylinder ("cylindrical" projections), or a tangent cone ("conic" projections). Formulas can be easily generalized for the respective secant cases. In their basic cases, the axes of cylinders and cones are aligned with the polar axis of the sphere.
Cartographic projections are relevant at all scales, but their differences are clearer when using world maps. This subsection will only use examples of world maps.
GeoProjectionData["Cylindrical"]GeoGraphics[GeoRange -> "World", GeoProjection -> "MillerCylindrical", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "CylindricalEqualArea", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "LambertCylindrical", GeoGridLines -> Automatic]GeoProjectionData["Conic"]GeoGraphics[GeoRange -> "World", GeoProjection -> "Albers", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "ConicEquidistant", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "LambertConicConformal", GeoGridLines -> Automatic]GeoProjectionData["Azimuthal"]GeoGraphics[GeoRange -> "World", GeoProjection -> "Orthographic", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "LambertAzimuthal", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "Airy", GeoGridLines -> Automatic]There are multiple variations of those basic types of projections. For example, if parallels are kept as horizontal straight lines but meridians are allowed to be arbitrary curves, the result is the family of "pseudo-cylindrical" projections. Projections that do not naturally have a particular type are usually classified as "miscellaneous".
GeoProjectionData["PseudoCylindrical"]GeoGraphics[GeoRange -> "World", GeoProjection -> "Mollweide", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "WinkelTripel", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "Sinusoidal", GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> "Shield", GeoGridLines -> Automatic]Another important way of classifying projections is by using the geometric properties they preserve, mainly angles ("conformal" projections), distances ("equidistant" projections), or areas ("equal-area" or "equivalent" or "eumorphic" projections). No projection can preserve everything simultaneously.
GeoProjectionData["Mercator", "Classes"]GeoProjectionData["Albers", "Classes"]The stereographic projection is azimuthal and conformal and is also constructed via perspective mapping:
GeoProjectionData["Stereographic", "Classes"]Geo projections have parameters. GeoProjectionData[projname] gives the default values of the projection parameters.
GeoGraphics[GeoRange -> "World", GeoProjection -> {"Orthographic", "Centering" -> Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}]}, GeoGridLines -> Automatic]GeoGraphics[GeoRange -> "World", GeoProjection -> {"Albers", "StandardParallels" -> {-15, 35}}, GeoGridLines -> Automatic]Change the default map scale to use kilometers (true distance only on the equator for the Mercator projection):
GeoGraphics[GeoRange -> "World", GeoProjection -> {"Mercator", "ReferenceModel" -> 6378.14}, GeoGridLines -> Automatic, Frame -> True]Padding
The GeoRange option with explicit numeric values of latitude and longitude ranges returns a map of exactly the region requested. If the projection is not cylindrical, then the borders of the map will be curved lines, corresponding to the specified parallels and meridians.
| GeoRangePadding | option of GeoGraphics that specifies geo range padding |
bounds = GeoBounds[Entity["GeographicRegion", "NorthAmerica"]]GeoGraphics[GeoRange -> bounds, GeoGridLines -> Automatic, Frame -> True]Use GeoRangePaddingNone to restrict to the actual geo bounds rectangle:
GeoGraphics[GeoRange -> bounds, GeoRangePadding -> None, GeoGridLines -> Automatic, Frame -> True]A map specified by a geographical Entity or EntityClass object is constructed by first computing the latitude and longitude bounds of the object with GeoBounds, adding a small amount of padding, and finally completing the rectangular plot range, effectively using GeoRangePadding->Full.
map = GeoGraphics[Entity["Country", "Australia"]]This is the geo range chosen by GeoGraphics:
AbsoluteOptions[map, GeoRange]bounds = GeoBounds[Entity["Country", "Australia"]]GeoGraphics[GeoRange -> bounds, GeoRangePadding -> None]AbsoluteOptions[%, GeoRange]GeoGraphics[GeoRange -> bounds, GeoRangePadding -> Scaled[0.05]]GeoBounds[Entity["Country", "Australia"], Scaled[0.05]]Finally, to obtain the original map, combine the padding specification with Full:
GeoGraphics[GeoRange -> bounds, GeoRangePadding -> {Scaled[0.05], Full}]The GeoRangePadding option is very flexible. It allows you to specify independent paddings for the four different sides of the map, and also allows different ways of specifying the actual padding: distances, angles, or scaled fractions of the total map. Click the link on its name to explore all the possibilities.
GeoZoomLevel and ImageSize
Yet another way of providing a geo range is by selecting a point (for example, using GeoCenter or giving a point-like object in the first argument of GeoGraphics) and a zoom level. GeoGraphics will then choose a geo range radius so that the geo background image is constructed with a small number (generally around 10) tiles of 256×256 pixels. It is possible to get larger geo ranges by increasing the ImageSize option of the map.
| GeoZoomLevel | option of GeoGraphics that specifies the zoom level |
| ImageSize | option that specifies the size in pixels of the final map |
GeoGraphics[GeoCenter -> Entity["City", {"Paris", "IleDeFrance", "France"}], GeoZoomLevel -> 5]georange = GeoRange /. AbsoluteOptions[%, GeoRange]GeoGraphics[GeoRange -> georange, ImageSize -> 450]GeoGraphics[GeoRange -> georange, ImageSize -> 900]Points and Markers
The simplest primitive to use is Point. It will represent a point on the map, with the standard flexibility in Graphics to control its size, color, opacity, etc.
| GeoMarker[loc,icon] | marker primitive at location loc using the given icon |
| Point[loc] | point primitive at location loc |
volcanos = EntityList[EntityClass["Volcano", "Supervolcanos"]]positions = EntityValue[volcanos, "Position"]GeoGraphics[Point /@ positions, GeoRange -> "World", GeoBackground -> "Basic"]Draw larger points, with a different color. Note that you can also use Point without mapping it over the list of positions:
GeoGraphics[{PointSize[Large], Red, Point[positions]}, GeoRange -> "World", GeoBackground -> "Basic"]The use of GeoPosition inside Point guarantees that the points will be properly placed in the map for any projection:
GeoGraphics[{PointSize[Large], Red, Point[positions]}, GeoRange -> "World", GeoProjection -> "LambertAzimuthal", GeoBackground -> "Basic"]You can also use the list of entities directly. GeoGraphics will internally use EntityValue to get their positions:
GeoGraphics[{PointSize[Large], Red, Point[volcanos]}, GeoRange -> "World", GeoProjection -> "Albers", GeoBackground -> "Basic"]You can even use the EntityClass object itself, because it represents the list of its members:
GeoGraphics[{PointSize[Large], Red, Point[EntityClass["Volcano", "Supervolcanos"]]}, GeoRange -> "World", GeoProjection -> "Bonne", GeoBackground -> "Basic"]The GeoMarker primitive adds the flexibility of placing anything at the given position.
GeoGraphics[GeoMarker[EntityClass["Volcano", "Supervolcanos"]], GeoRange -> "World", GeoBackground -> "Basic"]EntityValue[Entity["Icon", "Volcano"], "Image"]Use it at each location. You could have used the image itself instead of the icon Entity object:
GeoGraphics[GeoMarker[EntityClass["Volcano", "Supervolcanos"], Entity["Icon", "Volcano"], "Color" -> Black, "Scale" -> Scaled[0.1]], GeoRange -> "World", GeoBackground -> "Basic"]Paths
The GeoPath primitive represents any line on the surface of the Earth before it is projected onto the flat map. That is, a GeoPath object is a trajectory that has geometric meaning on the curved surface of the Earth. Currently three types of such lines are supported: "Geodesic" (shortest path between any two given points), "Loxodrome" (curve that crosses all meridians with the same bearing or angle), and "GreatCircle" (curve obtained by cutting the Earth by a plane through its center). Meridians are always both loxodromes and great circles. Parallels are always loxodromes but not necessarily great circles. The equator is the only parallel that is also a great circle.
| GeoPath[locs,pathtype] | primitive joining the given locations with a path of type pathtype |
GeoGraphics[GeoPath[{Entity["City", {"Madrid", "Madrid", "Spain"}], Entity["City", {"Moscow", "Moscow", "Russia"}]}], GeoBackground -> "Plain"]The Lambert azimuthal projection represents the geodesic as nearly straight. Compare to the equirectangular and Mercator projections for the same region:
GeoGraphics[GeoPath[{Entity["City", {"Madrid", "Madrid", "Spain"}], Entity["City", {"Moscow", "Moscow", "Russia"}]}], GeoProjection -> "Equirectangular", GeoBackground -> "Plain"]GeoGraphics[GeoPath[{Entity["City", {"Madrid", "Madrid", "Spain"}], Entity["City", {"Moscow", "Moscow", "Russia"}]}], GeoProjection -> "Mercator", GeoBackground -> "Plain"]GeoGraphics[GeoPath[{Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}], Entity["City", {"Lisbon", "Lisboa", "Portugal"}]}, "RhumbLine"], GeoProjection -> "Mercator", GeoBackground -> "Plain"]GeoDirection[Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}], Entity["City", {"Lisbon", "Lisboa", "Portugal"}]]
p = GeoPosition[{-35, -55}];
q = GeoPosition[{70, 100}];GeoGraphics[{Red, GeoPath[{p, q}, "Geodesic"], White, GeoPath[{p, q}, "Loxodrome"]}]It may seem strange that the red curve above is shorter than the white curve. The orthographic projection explains the difference:
GeoGraphics[{Red, GeoPath[{p, q}, "Geodesic"], White, GeoPath[{p, q}, "Loxodrome"]}, GeoProjection -> "Orthographic", GeoCenter -> {30, -35}, GeoRange -> "World", GeoGridLines -> Automatic]You have seen examples of geo paths between pairs of points. GeoPath[{p1,p2,…,pn},type] gives a continuous line formed by segments of the given type between consecutive points pi, but the complete line is not of that type in general.
Draw the shortest route between several cities. The whole line is not a geodesic between the initial and final points:
GeoGraphics[{Red, GeoPath[{Entity["City", {"Portland", "Oregon", "UnitedStates"}], Entity["City", {"Orlando", "Florida", "UnitedStates"}], Entity["City", {"Boston", "Massachusetts", "UnitedStates"}]}, "Geodesic"]}]GeoGraphics[{Red, GeoPath[{Entity["City", {"Portland", "Oregon", "UnitedStates"}], Entity["City", {"Orlando", "Florida", "UnitedStates"}], Entity["City", {"Boston", "Massachusetts", "UnitedStates"}]}, "Geodesic", CurveClosed -> True]}]There are named types of geo paths, including {"Parallel",lat}, {"Meridian",lon}, and particular cases like "Equator", "PrimeMeridian", or "DateLineMeridian".
GeoGraphics[{Red, GeoPath[{"Parallel", 40}], Blue, GeoPath[{"Parallel", 10}], Orange, GeoPath[{"Parallel", -40}]}, GeoRange -> "World"]Draw parts of parallels, from west to east or from east to west. Use Arrow to add the arrowhead to a geo path:
GeoGraphics[{Arrow@GeoPath[{"Parallel", 40, {-170, 140}}], Arrow@GeoPath[{"Parallel", -30, {170, -140}}]}, GeoRange -> "World"]GeoGraphics[{Red, GeoPath["Equator"], Orange, GeoPath["NorthernTropic"], GeoPath["SouthernTropic"], Blue, GeoPath["ArcticCircle"], GeoPath["AntarcticCircle"], Green, GeoPath["GreenwichMeridian"], GeoPath["DateLineMeridian"]}, GeoProjection -> "WinkelTripel"]GeoGraphics[{Red, GeoPath["DateLine"]}, GeoRange -> {All, {90, 270}}, GeoGridLines -> Quantity[15, "AngularDegrees"], Frame -> True]Circles and Disks
A geo circle with center p and radius r is a closed line surrounding p whose points are all at geo distance r from p. Due to the curvature of the Earth, the total length of the geo circle will be smaller than 2π r, and in fact if r keeps growing, the geo circle will start decreasing in size and focus around the antipode of p.
| GeoDisk[loc,r] | geodesic disk centered at loc, with radius r |
| GeoCircle[loc,r] | geodesic circle centered at loc, with radius r |
GeoGraphics[GeoCircle[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[500, "Kilometers"]]]A geo circle of 5000 kilometers around the same place. It does not look circular in the equirectangular projection:
GeoGraphics[GeoCircle[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[5000, "Kilometers"]]]GeoGraphics[GeoCircle[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[7000, "Kilometers"]], GeoRange -> "World"]GeoGraphics[GeoCircle[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[17000, "Kilometers"]], GeoRange -> "World"]GeoGraphics[Table[{Hue[r / 30000], GeoCircle[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[r, "Kilometers"]]}, {r, 1000, 20000, 1000}], GeoRange -> "World"]GeoGraphics[{Hue[2 / 3], GeoCircle[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[20000, "Kilometers"]]}, GeoScaleBar -> "Metric"]A geo disk is the 2D interior of a geo circle. A geo circle (like any closed curve) separates the surface of the Earth into two finite parts. The interior is the part containing the center point, not necessarily smaller in area than the exterior.
GeoGraphics[GeoDisk[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[500, "Kilometers"]]]GeoGraphics[GeoDisk[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[5000, "Kilometers"]]]GeoGraphics[GeoDisk[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[7000, "Kilometers"]], GeoRange -> "World"]And if it gets even bigger, it will cover most of the Earth, except for a small region around the antipodal point:
GeoGraphics[GeoDisk[Entity["City", {"Chicago", "Illinois", "UnitedStates"}], Quantity[17000, "Kilometers"]], GeoRange -> "World"]Hemispheres
A hemisphere covers exactly half of the Earth's surface, as divided by a plane passing through the Earth's center. Hence the boundary of a hemisphere is a great circle (actually a great ellipse because an ellipsoidal model of the Earth is being used). The Wolfram Language provides two types of geo primitives to work with hemispheres: on the one hand is the hemisphere GeoHemisphere[p] around a point p of the surface, and on the other hand are the especially important hemispheres DayHemisphere[date] and NightHemisphere[date], determined by the position of the Sun at the given date. The boundary of GeoHemisphere[p] is the line GeoHemisphereBoundary[p]. The boundary of the day and night hemispheres is DayNightTerminator[date].
| GeoHemisphere[loc] | hemisphere centered at loc |
| DayHemisphere[date] | daylight hemisphere at the given date |
| NightHemisphere[date] | night hemisphere at the given date |
| GeoHemisphereBoundary[loc] | boundary of the hemisphere centered at loc |
| DayNightTerminator[date] | terminator line between the day and night hemisphere on date |
GeoGraphics[GeoHemisphere[Entity["City", {"Tokyo", "Tokyo", "Japan"}]], GeoRange -> "World"]GeoGraphics[{GeoHemisphere[Entity["City", {"Tokyo", "Tokyo", "Japan"}]], Red, GeoHemisphereBoundary[Entity["City", {"Tokyo", "Tokyo", "Japan"}]]}, GeoRange -> "World"]GeoGraphics[{GeoHemisphere[Entity["City", {"Tokyo", "Tokyo", "Japan"}]], Red, GeoHemisphereBoundary[Entity["City", {"Tokyo", "Tokyo", "Japan"}]]}, GeoRange -> "World", GeoProjection -> {"LambertAzimuthal", "Centering" -> Entity["City", {"Tokyo", "Tokyo", "Japan"}]}]GeoGraphics[GeoHemisphere["NorthPole"], GeoRange -> "World"]The day and night hemispheres are just an application of GeoHemisphere for the projection of the position of the Sun on the Earth's surface, or its antipodal point. To avoid ambiguities, dates must be specified with explicit TimeZone specifications.
GeoGraphics[NightHemisphere[DateObject[{2014, 12, 21}, TimeObject[{16, 57}, TimeZone -> -6.], TimeZone -> -6.]], GeoRange -> "World"]GeoGraphics[NightHemisphere[DateObject[{2015, 3, 20}, TimeObject[{17, 39}, TimeZone -> -5.], TimeZone -> -5.]], GeoRange -> "World"]Region of Visibility from a Height
A geo hemisphere can be considered the part of the Earth that would be visible from very far (actually infinite distance) along some direction. Here the generalization of that concept when the viewing point is at finite height over the surface of the ellipsoidal Earth is introduced. The region obtained is then always smaller than a hemisphere. The geometric construction is very similar though: the region of visibility is also determined by a secant plane, but now it does not pass through the center of the Earth.
| GeoVisibleRegion[loc] | visible region from the elevated position loc |
| GeoVisibleRegionBoundary[loc] | boundary of the visible region from the elevated position loc |
SatelliteData[Entity["Satellite", "25544"], "Position"]GeoGraphics[GeoVisibleRegion[%], GeoRange -> "World"]GeoGraphics[GeoVisibleRegionBoundary[{0, 0, Quantity[35786, "Kilometers"]}], GeoRange -> "World"]Line, Polygon, and Other Standard Graphics Primitives
The standard, non-geo graphical primitives, like Line, Polygon, Circle, etc. can also be used in GeoGraphics, but are interpreted as primitives on the flat map, not on the surface of the Earth as their geo counterparts are. They have the same standard properties they have in Graphics; in particular, the segments in Line and Polygon between any two consecutive points are straight lines.
p1 = GeoPosition[{-60, -30}];
p2 = GeoPosition[{60, -60}];
p3 = GeoPosition[{60, 60}];
p4 = GeoPosition[{-60, 30}];The Line primitive connecting those four points always has straight sides, in every projection, but the GeoPath connecting them has generically curved sides:
GeoGraphics[{Line[{p1, p2, p3, p4, p1}], Red, GeoPath[{p1, p2, p3, p4, p1}]}]On the other hand, the points of the geodesics are uniquely defined, while the Line points are not. For some projections, the black line passes through Brazil, but not for others:
GeoGraphics[{Line[{p1, p2, p3, p4, p1}], Red, GeoPath[{p1, p2, p3, p4, p1}]}, GeoProjection -> "Albers"]In all cases, one geodesic segment passes between Mozambique and Madagascar, but the corresponding Line segment crosses different countries of Africa for different projections:
GeoGraphics[{Line[{p1, p2, p3, p4, p1}], Red, GeoPath[{p1, p2, p3, p4, p1}]}, GeoProjection -> "LambertAzimuthal"]It is possible to use directly projected coordinates in the standard non-geo primitives, but this requires taking into account which projection is being used. This is useful for adding additional graphical elements to the map, not directly related to elements existing on the surface of the Earth. In fact, you can use coordinates that do not even correspond to any point on the surface of the Earth. When this is done, it is highly recommended that the projection being used be made explicit in the input, to avoid GeoGraphics selecting a different projection when more primitives are added.
Add arrows and texts to a map in the "Bonne" projection. Note how GeoPosition specifications are mixed with projected coordinates in some Line primitives:
GeoGraphics[{Arrow@Line[{{-2, 2}, GeoPosition[{40, -100}]}], Text["North America", {-2, 2.2}], Arrow@Line[{{2, -2}, GeoPosition[{0, 20}]}], Text["Africa", {2.5, -2}]}, GeoRange -> "World", GeoProjection -> "Bonne", Frame -> True, PlotRange -> {{-4, 4}, {-3, 3}}]Using a different projection will automatically modify the positions specified with GeoGraphics, but not the positions given with projected coordinates:
GeoGraphics[{Arrow@Line[{{-2, 2}, GeoPosition[{40, -100}]}], Text["North America", {-2, 2.2}], Arrow@Line[{{2, -2}, GeoPosition[{0, 20}]}], Text["Africa", {2.5, -2}]}, GeoRange -> "World", GeoProjection -> "AmericanPolyconic", Frame -> True, PlotRange -> {{-4, 4}, {-3, 3}}]PlotRange and GeoRange are completely independent options. Typically GeoRange is specified and GeoGraphics is allowed to choose an appropriate PlotRange, but you can always specify both. GridLines and GeoGridLines are also independent:
GeoGraphics[GeoRange -> {{0, 40}, {-20, 40}}, PlotRange -> {{-0.6, 0.6}, {-0.5, 1}}, GeoProjection -> "WinkelTripel", Frame -> True, GeoGridLines -> Automatic, GridLines -> Automatic, GeoRangePadding -> None]Advanced: The Structure of a GeoGraphics Result
The output of a GeoGraphics input expression also has head GeoGraphics, but its first argument is now a Graphics object, the actual graphics object that is displayed as the map. This output GeoGraphics also contains a sequence of options with absolute values, both options that were given in input and options that were decided by GeoGraphics.
Analyze the structure of GeoGraphics in output:
g = GeoGraphics[Here]The output still has head GeoGraphics:
Head[g]The first argument is a Graphics object, and then there is a sequence of options:
Head[g[[1]]]list = List@@gGeoProjection /. Rest[list]GeoZoomLevel /. Rest[list]GeoRange /. Rest[list]GeoCenter /. Rest[list]GeoModel /. Rest[list]Options[g, PlotRange]Advanced: Geo Evaluation of Geo Primitives
The geo primitives are converted into standard primitives in the "Equirectangular" projection so that they can be easily displayed using Graphics.
Use Geographics`GeoEvaluate on a GeoCircle, converting it into a Line object containing a list of {lon,lat} pairs:
Short[line = GeoGraphics`GeoEvaluate[GeoCircle[{60, 0}, Quantity[1000, "Kilometers"]]], 3]Graphics[{Red, line, Blue, PointSize[Small], Point@@line}, Frame -> True]A second argument of GeoGraphics`GeoEvaluate specifies the model of the spheroid being used, either a number in meters or a Quantity distance representing a sphere of that radius, or a pair {a,b} of semiaxes of an ellipsoid of revolution, also given as numbers in meters or Quantity lengths. The result is now different.
Short[line = GeoGraphics`GeoEvaluate[GeoCircle[{60, 0}, Quantity[1000, "Kilometers"]], Quantity[2000, "Kilometers"]], 3]Graphics[{Red, line, Blue, PointSize[Small], Point@@line}, Frame -> True]A third argument of GeoGraphics`GeoEvaluate specifies the resolution distance required, in meters. When this number is smaller, then the geo primitives are resolved with more points, to guarantee that neighbors are closer than that distance.
Short[line = GeoGraphics`GeoEvaluate[GeoCircle[{60, 0}, Quantity[1000, "Kilometers"]], Quantity[2000, "Kilometers"], 1000], 3]Graphics[{Red, line, Blue, PointSize[Small], Point@@line}, Frame -> True]Map Stylings
GeoGraphics inherits from Graphics a large variety of directives that can be used to stylize a map, including colors, opacities, textures, and many more. It also adds new elements that are characteristic of maps, which automatically respond to the projection being used. The most important new element is GeoStyling[mapstyle,directive], which specifies how to stylize an arbitrary area of the map; that could be in particular the geo background.
GeoGraphics provides several predefined map styles, like "StreetMap", "ReliefMap", or "ContourMap", and only allows you to place arbitrary images on a polygon.
| GeoStyling[mapstyle] | stylize the interior of 2D geo primitives using mapstyle |
| GeoBackground | option of GeoGraphics that specifies the background map style |
GeoGraphics[Entity["Country", "Morocco"]]GeoGraphics[Entity["Country", "Morocco"], GeoBackground -> GeoStyling["TerrainNoLabels"]]GeoGraphics[Entity["Country", "Morocco"], GeoBackground -> GeoStyling["StreetMap"]]GeoGraphics[Entity["Country", "Morocco"], GeoBackground -> GeoStyling["StreetMapVectorLabels"]]GeoGraphics[Entity["Country", "Morocco"], GeoBackground -> GeoStyling["ReliefMap"]]GeoGraphics[Entity["Country", "Morocco"], GeoBackground -> GeoStyling["Satellite"]]GeoGraphics[Entity["Country", "Morocco"], GeoBackground -> GeoStyling["CountryBorders"]]GeoStyling effectively works like Texture, specifying what to place inside the following 2D primitives, like geo disks or polygons. In that sense, the GeoBackground option can be considered as the particular case of specifying what to place in the whole map.
GeoGraphics[{GeoStyling["ReliefMap"], Polygon[Entity["Country", "Peru"]]}]GeoStyling can be used to show a map confined to the borders of a given area:
GeoGraphics[{GeoStyling["StreetMap"], GeoDisk[Entity["City", {"Paris", "IleDeFrance", "France"}], Quantity[500, "Kilometers"]]}, GeoBackground -> None]GeoGraphics[{GeoStyling["ReliefMap"], Polygon[Entity["Country", "Italy"]]}, GeoBackground -> None]There are two flexible map styles that allow you to place arbitrary images and graphics on a map, namely {"Image",image} and {"GeoImage",image}. The difference is that in the first case the image will be placed in the given area with no transformation (perhaps only a change in aspect ratio), while in the latter case the image will be projected along the map area. Therefore "GeoImage" is adapted to place pieces of maps over other maps.
gauss = EntityValue[Entity["Person", "CarlFriedrichGauss::4vctc"], "Image"]GeoGraphics[{GeoStyling[{"Image", gauss}], Polygon[Entity["Country", "Germany"]]}]With the "Image" map style, the image will preserve its orientation in any projection:
GeoGraphics[{GeoStyling[{"Image", gauss}], Polygon[Entity["Country", "Germany"]]}, GeoProjection -> {"Bonne", "Centering" -> 60}, GeoRange -> Quantity[500, "Miles"], GeoGridLines -> Automatic]brazil = ImageTake[ImageResize[Import["http://upload.wikimedia.org/wikipedia/commons/e/eb/1855_Colton_Map_of_Brazil_and_Guyana_-_Geographicus_-_Brazil-colton-1855.jpg"], {500}], {75, 460}, {5, 388}]GeoGraphics[{GeoStyling[{"GeoImage", brazil}], Polygon[["Brazil"]]}, GeoProjection -> {"Orthographic", "Centering" -> {-50, -30}}, GeoRange -> "World", GeoGridLines -> Automatic, GeoBackground -> "Plain"]Opacity and Color
The Graphics 2D primitives are opaque by default because the background is typically empty, so it can be covered. However, GeoGraphics usually contains a map image as geo background, which should not be fully covered by the primitives over it. Therefore, the default opacity of 2D primitives is small: 0.2. This throws in a slight twist in how opacities are handled in GeoGraphics, because the opacities of the 2D primitives need to be distinguished from the opacities of the rest of the primitives (points and lines), which are still opaque by default. This can be done by using GeoStyling again.
GeoGraphics[{GeoDisk[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]], Blue, Thickness[0.05], GeoCircle[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]]}, GeoBackground -> "StreetMapNoLabels"]GeoGraphics[{Opacity[0.5], GeoDisk[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]], Blue, Thickness[0.05], GeoCircle[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]]}, GeoBackground -> "StreetMapNoLabels"]To change the opacity of the disk, use GeoStyling[opacity], which will not affect the thick geo circle:
GeoGraphics[{GeoStyling[Opacity[0.5]], GeoDisk[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]], Blue, Thickness[0.05], GeoCircle[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]]}, GeoBackground -> "StreetMapNoLabels"]GeoGraphics[{GeoStyling[Opacity[0.5]], Blue, GeoDisk[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]], Thickness[0.05], GeoCircle[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]]}, GeoBackground -> "StreetMapNoLabels"]But colors placed inside GeoStyling take precedence for 2D primitives, even over colors that are given afterward:
GeoGraphics[{GeoStyling[Opacity[0.5], Red], Blue, GeoDisk[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]], Thickness[0.05], GeoCircle[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]]}, GeoBackground -> "StreetMapNoLabels"]GeoStyling[Automatic] undoes the action of any previous GeoStyling specification and recovers the defaults:
GeoGraphics[{GeoStyling[Opacity[0.5], Red], Blue, GeoStyling[Automatic], GeoDisk[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]], Thickness[0.05], GeoCircle[Entity["City", {"Ottawa", "Ontario", "Canada"}], Quantity[400, "Kilometers"]]}, GeoBackground -> "StreetMapNoLabels"]Geo Grid Lines and Scale Bar
Drawing parallels and meridians is always very useful for understanding the orientation of the elements on a map, even more so when using a noncylindrical projection. The option GeoGridLines and its styling counterpart GeoGridLinesStyle provide a flexible interface to drawing the so-called graticule of lines.
| GeoScaleBar | option of GeoGraphics that turns on the use of a scale bar |
| GeoGridLines | option of GeoGraphics that turns on the use of a lines graticule |
| GeoGridLinesStyle | option of GeoGraphics that specifies the style of geo grid lines |
In the "Equirectangular" projection, the parallels and meridians are straight lines (as in all cylindrical projections) and are equally spaced. Let the system choose the lines:
GeoGraphics[GeoRange -> "World", GeoGridLines -> Automatic]AbsoluteOptions[%, GeoGridLines]GeoGraphics[GeoRange -> "World", GeoGridLines -> {8, 30}, GeoProjection -> "Albers"]Specify the graticule subdivision size as Quantity angles:
GeoGraphics[{Green, GeoPath["PrimeMeridian"], Red, GeoPath["Equator"]}, GeoRange -> "World", GeoGridLines -> Quantity[5, "AngularDegrees"], GeoProjection -> {"Orthographic", "Centering" -> GeoPosition[{40, -30}]}]To read scale in a map, you can use the GeoScaleBar option. For large-scale maps, the distance scale factor may vary from point to point, and therefore the scale bar will only represent an average.
GeoGraphics[Entity["Country", "France"], GeoScaleBar -> "Metric"]All of the above has been presented for the Earth, but can be applied to other celestial bodies for which satellite images exist, like Mars, Pluto, or the Moon. GeoGraphics uses appropriate background tiles as determined by the value of the option GeoModel.
| GeoModel | option of GeoGraphics that specifies a datum or celestial globe |
GeoGraphics[GeoModel -> Entity["PlanetaryMoon", "Moon"], GeoRange -> All, GeoProjection -> "Mollweide", GeoGridLines -> Automatic, GeoGridLinesStyle -> Directive[Thin, White, Opacity[0.5]], Background -> Black]GeoGraphics[GeoCenter -> Entity["SolarSystemFeature", "RimaAriadaeusMoon"], GeoRange -> Quantity[50, "Miles"]]GeoGraphics[GeoCenter -> Entity["SolarSystemFeature", "CopernicusMoon"], GeoRange -> Quantity[50, "Miles"]]GeoGraphics[GeoModel -> Entity["Planet", "Mars"], GeoRange -> All, GeoProjection -> "Bonne", GeoGridLines -> Automatic, GeoGridLinesStyle -> Directive[Thin, Orange, Opacity[0.5]], Background -> Black]GeoGraphics[GeoMarker[Entity["DeepSpaceProbe", "MarsScienceLaboratory"]], GeoCenter -> Entity["SolarSystemFeature", "GaleMars"], GeoRange -> Quantity[100, "Kilometers"]]GeoGraphics[GeoCenter -> Entity["SolarSystemFeature", "NoctisLabyrinthusMars"], GeoRange -> Quantity[150, "Miles"]]GeoGraphics[GeoModel -> "Pluto", GeoProjection -> "Orthographic", GeoRange -> All, GeoCenter -> {40, 180}, Background -> Black, PlotRangePadding -> 0.1, GeoZoomLevel -> 2]