Solve
Details and Options
- The system expr can be any logical combination of:
-
lhs==rhs equations lhs!=rhs inequations lhs>rhs or lhs>=rhs inequalities expr∈dom domain specifications {x,y,…}∈reg region specification ForAll[x,cond,expr] universal quantifiers Exists[x,cond,expr] existential quantifiers - Solve[{expr1,expr2,…},vars] is equivalent to Solve[expr1&&expr2&&…,vars].
- A single variable or a list of variables can be specified.
- Solve gives solutions in terms of rules of the form:
-
{} no solutions {{x->solx,y->soly,…},…} several solutions {{}} solution set is full dimensional - When a single variable is specified and a particular root of an equation has multiplicity greater than one, Solve gives several copies of the corresponding solution.
- Solve[expr,vars] assumes by default that quantities appearing algebraically in inequalities are real, while all other quantities are complex.
- Solve[expr,vars,dom] restricts all variables and parameters to belong to the domain dom.
- If dom is Reals, or a subset such as Integers or Rationals, then all constants and function values are also restricted to be real.
- Solve[expr&&vars∈Reals,vars,Complexes] solves for real values of variables, but function values are allowed to be complex.
- Solve[expr,vars,Integers] solves Diophantine equations over the integers.
- Solve[…,x∈reg,Reals] constrains x to be in the region reg. The different coordinates for x can be referred to using Indexed[x,i].
- Algebraic variables in expr free of vars and of each other are treated as independent parameters.
- Solve deals primarily with linear and polynomial equations.
- When expr involves only polynomial equations and inequalities over real or complex domains, then Solve can always in principle solve directly for vars.
- When expr involves transcendental conditions or integer domains, Solve will often introduce additional parameters in its results.
- Solve can give explicit representations for solutions to all linear equations and inequalities over the integers and can solve a large fraction of Diophantine equations described in the literature.
- When expr involves only polynomial conditions over real or complex domains, Solve[expr,vars] will always be able to eliminate quantifiers.
- Solve gives generic solutions only. Solutions that are valid only when continuous parameters satisfy equations are removed. Other solutions that are only conditionally valid are expressed as ConditionalExpression objects.
- Conditions included in ConditionalExpression solutions may involve inequalities, Element statements, equations and inequations on non-continuous parameters, and equations with full-dimensional solutions. Inequations and NotElement conditions on continuous parameters and variables are dropped.
- Solve may use non-equivalent transformations to find solutions of transcendental equations and hence it may not find some solutions and may not establish exact conditions on the validity of the solutions found. If this happens, an error message is issued.
- Solve uses special efficient techniques for handling sparse systems of linear equations with approximate numerical coefficients.
- The following options can be given:
-
Assumptions $Assumptions assumptions on parameters Cubics Automatic whether to use explicit radicals to solve all cubics GeneratedParameters C how to name parameters that are generated InverseFunctions Automatic whether to use symbolic inverse functions MaxExtraConditions 0 how many extra equational conditions on continuous parameters to allow MaxRoots Infinity maximum number of roots returned Method Automatic what method should be used Modulus 0 modulus to assume for integers Quartics Automatic whether to use explicit radicals to solve all quartics VerifySolutions Automatic whether to verify solutions obtained using non-equivalent transformations WorkingPrecision Infinity precision to be used in computations - With MaxExtraConditions->Automatic, only solutions that require the minimal number of equational conditions on continuous parameters are included.
- With MaxExtraConditions->All, solutions that require arbitrary conditions on parameters are given and all conditions are included.
- With MaxExtraConditions->k, only solutions that require at most k equational conditions on continuous parameters are included.
- With Method->Reduce, Solve uses only equivalent transformations and finds all solutions.
- Solve[eqns,…,Modulus->m] solves equations over the integers modulo m. With Modulus->Automatic, Solve will attempt to find the largest modulus for which the equations have solutions.
Examples
open all close allBasic Examples (5)
Solve[x ^ 2 + a x + 1 == 0, x]Solve simultaneous equations in 
and 
:
Solve[a x + y == 7 && b x - y == 1, {x, y}]Solve an equation over the reals:
Solve[(x ^ 2 + 2)(x ^ 2 - 2) == 0, x, Reals]Solve an equation over the positive integers:
Solve[x ^ 2 + 2y ^ 3 == 3681 && x > 0 && y > 0, {x, y}, Integers]Solve equations in a geometric region:
Solve[{x, y}∈InfiniteLine[{{0, 0}, {2, 1}}] && {x, y}∈Circle[], {x, y}]Graphics[{{Blue, InfiniteLine[{{0, 0}, {2, 1}}], Circle[]}, {PointSize[Large], Red, Point[{x, y}] /. %}}]Scope (85)
Basic Uses (6)
Solutions are given as lists of replacements:
sol = Solve[x ^ 2 + y ^ 2 == 2 && x - y == 1, {x, y}]Use ReplaceAll (/.) to replace 
by solutions:
x /. solCheck that solutions satisfy the equations:
x ^ 2 + y ^ 2 == 2 && x - y == 1 /. solSolve uses {} to represent the empty solution or no solution:
Solve[x == 1 && x == 2, x]Solve uses {{}} to represent the universal solution or all points satisfying the equations:
Solve[x == x, x]Find solutions over specified domains:
Solve[(x ^ 4 - 1)(x ^ 4 - 4) == 0, x, Complexes]Solve[(x ^ 4 - 1)(x ^ 4 - 4) == 0, x, Reals]Solve[(x ^ 4 - 1)(x ^ 4 - 4) == 0, x, Integers]Solve equations with coefficients involving a symbolic parameter:
sol = Solve[x ^ 2 + y ^ 2 == 1 && x + y == a, {x, y}]Plot the real parts of the solutions for y as a function of the parameter a:
Plot[Evaluate[Re[y /. sol]], {a, 0, 2}]Solution of this equation over the reals requires conditions on the parameters:
sol = Solve[x ^ 2 + a x + b == 0, x, Reals]Replace x by solutions and simplify the results:
x ^ 2 + a x /. sol//SimplifyUse Normal to remove the conditions:
Normal[sol]Solution of this equation over the positive integers requires introduction of a new parameter:
sol = Solve[x ^ 2 - 2y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers]{x, y} /. First[sol] /. Table[{C[1] -> i}, {i, 10}]//SimplifyComplex Equations in One Variable (15)
Polynomial equations solvable in radicals:
Solve[x ^ 4 - x ^ 2 - 5 == 0, x]To use general formulas for solving cubic equations, set CubicsTrue:
Solve[x ^ 3 - 2x ^ 2 + 5x + 7 == 0, x, Cubics -> True]By default, Solve uses Root objects to represent solutions of general cubic equations with numeric coefficients:
Solve[x ^ 3 - 2x ^ 2 + 5x + 7 == 0, x]Solve[x ^ 5 - 2x + 17 == 0, x]Polynomial equations with multiple roots:
Solve[(x ^ 2 - 1)(x ^ 4 - 1) == 0, x]Find five roots of a polynomial of a high degree:
Solve[x ^ 1234567 + 9x ^ 2 + 7x - 1 == 0, x, MaxRoots -> 5]Polynomial equations with symbolic coefficients:
Solve[a x ^ 2 + b x + c == 0, x]Solve[a x ^ 5 + b x + c == 0, x]Solve[Sqrt[x] + 3x ^ (1 / 3) == 5, x]Solve[Sin[x] == 1 / 3, x]Solve[x ^ (2a) + 2x ^ a + 1 == 0, x]
Solve[(x ^ 5 - 1) ^ x == 0, x]Solve[ArcTan[1 / Sqrt[1 + x ^ 2], x / Sqrt[1 + x ^ 2]] == a, x]
Solve cannot find all solutions here:
Solve[5 == x * 2 ^ (x ^ 2), x]
Solve[5 == x * 2 ^ (x ^ 2), x, MaxRoots -> 3]Univariate elementary function equations over bounded regions:
Solve[Sin[E ^ x] - Cos[2 x] == 1 && -1 ≤ Re[x] ≤ 1 && -1 ≤ Im[x] ≤ 1, x]Univariate holomorphic function equations over bounded regions:
Solve[Gamma[x] - Log[x] == I / 2 && Abs[x - 2] < 3 / 2, x]Here Solve finds some solutions but is not able to prove there are no other solutions:
Solve[x == E ^ (1 / x) && Abs[x] < 5, x]
Equation with a purely imaginary period over a vertical stripe in the complex plane:
Solve[Cos[Exp[x]] == 3 Exp[-x] + 1 && 0 ≤ Re[x] ≤ 1, x]Find a specified number of roots of an unrestricted complex equation:
Solve[Sin[FresnelS[x] + BesselJ[3, x ^ 2 - 1]] == 2 ^ Cos[x] - 3, x, MaxRoots -> 5]Solve[f[x] ^ 3 + 2f[x] - 3 == 0, x]
Nonanalytic complex equations:
Solve[{Re[x] + Im[x]^2 == 1, Re[x] - Im[x] == -1}, x]Solve[{Abs[x] == 1, Arg[x] == π / 4}, x]Systems of Complex Equations in Several Variables (12)
Solve[{x + 2y + 3z == 4, 3x + 4y + 5z == 6, 7x + 7y + 8z == 9}, {x, y, z}]Linear equations with symbolic coefficients:
Solve[a x + b y + c z == d && 3x + 4y + 5z == 6 && 7x + 7y + 8z == 9, {x, y, z}]Underdetermined systems of linear equations:
Solve[x + 2y + 3z == 4 && 3x + 4y + 5z == 6 && 6x + 7y + 8z == 9, {x, y, z}]
Linear equations with no solutions:
Solve[x + 2y + 3z == 4 && 3x + 4y + 5z == 6 && 6x + 7y + 8z == 0, {x, y, z}]Systems of polynomial equations:
Solve[x ^ 2 + y ^ 2 == 1 && x + 2y == 3, {x, y}]Find five out of a trillion roots of a polynomial system:
Solve[x ^ 10000 == y ^ 2 + 3y + 2 && y ^ 10000 == z ^ 2 + 3z + 2 && z ^ 10000 == x ^ 2 + 3x + 2, {x, y, z}, MaxRoots -> 5]Polynomial equations with symbolic coefficients:
Solve[a x ^ 2 + b y ^ 2 == c && x + 2y == 3, {x, y}]Solve[Sqrt[x y] == Sqrt[x + y] && Sqrt[x] - y ^ (1 / 3) == 1, {x, y}]
Solve[Sin[x + y] == 1 && Log[x - y] == 1 / 2, {x, y}]Solve[3 ^ x ^ 2 == 7 && x ^ 2 - y ^ 3 == 4, {x, y}]
Solve[x ^ a + y ^ b == 1 && (x y) ^ (a b) == 2, {x, y}]
Find a specified number of solutions of transcendental equations:
Solve[Sin[x + y] == x y + 1 && Cos[x - y] == AiryAi[x y] + 2, {x, y}, MaxRoots -> 3]Square analytic systems over bounded boxes:
Solve[FresnelS[x - y] - AiryAi[x] + y == (3 + I) / 2 && CosIntegral[x] y - Sin[x y] == -5(1 - I) / 4 && 1 ≤ Re[x] ≤ 2 && 0 ≤ Im[x] ≤ 1 && 1 ≤ Re[y] ≤ 2 && 0 ≤ Im[y] ≤ 1, {x, y}]Solve[{Re[x^2] + Im[y] == 1, x^2 - y^2 == 0, Im[x^3] - Im[y]^2 == 2}, {x, y}]Real Equations in One Variable (13)
Solve[x ^ 5 - 2x + 1 == 0, x, Reals]Polynomial equations with multiple roots:
Solve[(x ^ 2 - 1)(x ^ 4 - 1) == 0, x, Reals]Polynomial equations with symbolic coefficients:
Solve[x ^ 3 + a x + a ^ 2 == 0, x, Reals]Solve[Sqrt[x] + 3x ^ (1 / 3) == 5, x, Reals]Solve[Abs[x] ^ 2 - x + UnitStep[x] == 9, x, Reals]Transcendental equations, solvable using inverse functions:
Solve[E ^ x - x == 7, x, Reals]Solve[ 27^2x - 1^(1/(x)) == Sqrt[9^2x - 1], x, Reals]Solve[JacobiSN[x, y] == 1, x, Reals]Transcendental equations, solvable using special function zeros:
Solve[AiryBi[1 - x ^ 2] == 0 && 2 < x < 3, x, Reals]Transcendental inequalities, solvable using special function zeros:
Solve[900 < AiryAiZero[2t + 1] ^ 2 < 1000, t, Reals]Solve[E ^ (2E ^ x) - Log[x ^ 2 + 1] - 20x == 11, x, Reals]High-degree sparse polynomial equations:
Solve[x ^ 1000000 - 2x ^ 777777 + 3x ^ 12345 + 9x ^ 67 - 10 == 0, x, Reals]Algebraic equations involving high-degree radicals:
Solve[2x ^ (123451 / 67890) - x ^ 2 + 4Sqrt[x] - 4x - 9 / 8 == 0, x, Reals]Equations involving non-rational real powers:
Solve[x ^ Pi - x ^ x ^ Sqrt[2] - Sqrt[3]x + 2 ^ (1 / 3) == 0, x, Reals]Solve[E ^ (2x) + x ^ 4 + 4(x ^ 2 + 1) == (2x ^ 2 + 4)E ^ x, x, Reals]Tame elementary function equations:
Solve[10Sin[Tan[E ^ -x ^ 2]] - x == 3, x, Reals]Elementary function equations in bounded intervals:
Solve[2Sin[Exp[x]] - Cos[Pi x] == 3 / 2 && -1 < x < 1, x, Reals]Holomorphic function equations in bounded intervals:
Solve[Cos[x] - BesselJ[5, x] == 1 / 2 && 0 ≤ x ≤ 10, x]Periodic elementary function equations over the reals:
Solve[Exp[Sin[x]] - Sin[3 Cos[x]] == 0, x, Reals]Systems of Real Equations and Inequalities in Several Variables (10)
Solve[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3, {y, z}, Reals]Solve[x y == z ^ 2 - x && x y z == 2 && x ^ 2 + y ^ 2 + z ^ 2 ≤ 5, {y, z}, Reals]Quantified polynomial systems:
Solve[Exists[x, x ^ 2 + a x + b == 0 && 2 x + a == 0], a, Reals]Solve[ForAll[x, Exists[y, a x ^ 2 + b y ^ 2 - 3y == 1 && y < 0 && a y - y == b + 1]], {a, b}, Reals]Solve[Sqrt[x + 2y] - 3x + 4y ≥ 5 && x + y ^ (1 / 3) == 1, y, Reals]Solve[Max[x, y] == Min[y ^ 2 - x, x] + y && z + UnitStep[x - y] == 1, {y, z}, Reals]Transcendental systems, solvable using inverse functions:
Solve[Sin[x + y] == 1 / 2 && E ^ x - y ≤ 1, y, Reals]Solve[ 3^x - 2^2y == 77 && Sqrt[3^x] - 2^y == 7, {x, y}, Reals]Systems exp-log in the first variable and polynomial in the other variables:
Solve[E ^ x y ^ 3 + Log[x]y == 1 && x y + E ^ x / x ≥ 2, y, Reals]Solve[Exists[a, a x ^ 2 + Sinh[x ^ 2 + 1]a ^ 2 == 1 && x ^ 2 - a ^ 2 == 1], x, Reals]Systems elementary and bounded in the first variable and polynomial in the other variables:
Solve[Sin[x - Cos[x]] y ^ 3 - x == 1 && x ^ 2 + y ^ 2 ≤ 1, y, Reals]Solve[Exists[y, y ^ 3 - Cos[x] y + 2 x ^ 2 Sin[x ^ 2 - 1] == 0 && x ^ 2 + y ^ 2 == 2], x, Reals]Systems analytic and bounded in the first variable and polynomial in the other variables:
Solve[y ^ 3 - BesselJ[2, x + 2] y - y - 3 x == -2 && y < 0 && x ^ 2 < 2, y, Reals]Solve[Exists[y, y ^ 4 - Gamma[x + 2] y - y - 3 ArcSin[x / 3] == 1 && x ^ 2 + y ^ 3 == 1 && 0 < x < 2], x, Reals]Square systems of analytic equations over bounded regions:
Solve[Gamma[x + y + 1] - Sin[x y] == 1 && Erf[x ^ 2 - y] - E ^ y - x + 4 == 0 && 0 < x < 3 && 0 < y < 3, {x, y}, Reals]Diophantine Equations (11)
Solve[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3, {x, y, z}, Integers]Linear systems of equations and inequalities:
Solve[2 x + 3y == 4 && 3x - 4y ≤ 5 && x - 2y > -21, {x, y}, Integers]Univariate polynomial equations:
Solve[x ^ 12345 - 2x ^ 777 + 1 == 0, x, Integers]Solve[x ^ 2 + x y + y ^ 2 == 109, {x, y}, Integers]Solve[x ^ 2 - 3y ^ 2 == 22 && x > 0 && y > 0, {x, y}, Integers]Solve[x ^ 2 - 6 x y + 9y ^ 2 - x + 2y == 1, {x, y}, Integers]Solve[x ^ 3 - 2x ^ 2 y + y ^ 3 == 2, {x, y}, Integers]Solve[x ^ 2 + 4y ^ 2 + 9z ^ 2 + 16t ^ 2 == 354 && x > 0 && y > 0 && z > 0 && t > 0, {x, y, z, t}, Integers]Solve[x ^ 2 + y ^ 2 == z ^ 2, {x, y, z}, Integers]Bounded systems of equations and inequalities:
Solve[x ^ 4 + y ^ 4 + z ^ 4 ≤ 500 && x + y ^ 2 + z ^ 3 == 32, {x, y, z}, Integers]High‐degree systems with no solutions:
Solve[2x ^ 7 + 8y ^ 15 + 14 x y z == 3, {x, y, z}, Integers]Transcendental Diophantine systems:
Solve[Exp[y ^ 2] < x && Abs[x] < 5 && Abs[y] < 5, {x, y}, Integers]Solve[Exp[x ^ 2 - 5y ^ 2 + 1] + x ^ 2 - 5y ^ 2 == 0 && x > 0 && y > 0, {x, y}, Integers]Polynomial systems of congruences:
Solve[Mod[x ^ 2 + y ^ 2, 2] == 1 && Mod[x - 2y, 3] == 2, {x, y}, Integers]Modular Equations (4)
Solve[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3 && 2x - 10y + 3z == 5, {x, y, z}, Modulus -> 12]Solve[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3, {x, y, z}, Modulus -> 12]
Univariate polynomial equations:
Solve[x ^ 3 - 2x + 1 == 0, x, Modulus -> 5]Systems of polynomial equations and inequations:
Solve[x ^ 2 + y ^ 3 == 1 && x + 2y ^ 2 == 4, {x, y}, Modulus -> 7]Solve[x ^ 2 + y ^ 3 == z && x + 2y == 3z + 1 && x y z ≠ 0, {x, y, z}, Modulus -> 7]Quantified polynomial systems:
Solve[ForAll[x, Exists[y, a x ^ 2 + b y ^ 2 - 3y == 1 && y ≠ 0]], {a, b}, Modulus -> 3]Equations over Finite Fields (3)
ℱ = FiniteField[53, 4];
Solve[x ^ 5 + ℱ[123]x == ℱ[234], x]Solve[x ^ 7 + 2 x + 3 == 0, x, ℱ]ℱ = FiniteField[71, 2];
Solve[ℱ[123]x + ℱ[234]y == ℱ[345] && ℱ[321]x + ℱ[432]y == ℱ[543], {x, y}]Solve[ℱ[1234]x + ℱ[2345]y + ℱ[3456]z == ℱ[4567] && ℱ[1]x + ℱ[2]y + ℱ[3]z == ℱ[4], {y, z}]Systems of polynomial equations:
ℱ = FiniteField[7, 5];
Solve[x ^ 2 + y ^ 2 == 3 && x ^ 5 + y ^ 5 == 5, {x, y}, ℱ]Solve[ℱ[123]x ^ 2 + ℱ[234]y ^ 3 + ℱ[345]z ^ 4 == ℱ[456] && ℱ[21]x + ℱ[32]y ^ 2 + ℱ[43]z ^ 3 == ℱ[54] && x y z == ℱ[1], {x, y, z}]Systems with Mixed Variable Domains (2)
Systems with Geometric Region Constraints (9)
Solve over special regions in 2D:
Subscript[ℛ, 1] = Circle[];
Subscript[ℛ, 2] = Line[{{-2, 1}, {1, -2}}];Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]Graphics[{{Blue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}] /. %}}]Solve over special regions in 3D:
Subscript[ℛ, 1] = Sphere[];
Subscript[ℛ, 2] = InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 0, 1}}];Solve[2 x y == z^2 && {x, y, z}∈Subscript[ℛ, 1] && {x, y, z}∈Subscript[ℛ, 2], {x, y, z}, Reals]Show[{ContourPlot3D[2 x y == z^2, {x, -1.2, 1.2}, {y, -1.2, 1.2}, {z, -1.2, 1.2}, Mesh -> None, ContourStyle -> Opacity[0.5]], Graphics3D[{{Opacity[0.5], Green, Subscript[ℛ, 1]}, {Opacity[0.5], Yellow, Subscript[ℛ, 2]}, {PointSize[Large], Red, Point[{x, y, z} /. %]}}]}]ℛ = Cone[{{0, 0, 0}, {1, 2, 3}}, 4];Solve[Subscript[∃, z](x^2 + y^2 == z^2 && x + y == z - 1 && {x, y, z}∈ℛ), y, Reals]ℛ = ImplicitRegion[a + 2 b - 3 c ≥ 1 && a b c == 7, {a, b, c}];Solve[y^2 + x z == 1 && {x, y, z}∈ℛ, {y, z}, Reals]A parametrically defined region:
ℛ = ParametricRegion[{s + t, s - t, s t}, {s, t}];Solve[x y == z && x + 2 y + 3 z == 1 && {x, y, z}∈ℛ, {x, y, z}, Reals]Subscript[ℛ, 1] = Disk[{0, 0}, 2];
Subscript[ℛ, 2] = Circle[{1, 1}, 2];
Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];Solve[x^2 == x y + 1 && {x, y}∈Subscript[ℛ, 3], {x, y}, Reals]Show[{ContourPlot[x^2 == x y + 1, {x, -2, 3}, {y, -2, 3}], Graphics[{{Opacity[0.5], Yellow, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{x, y} /. %]}}]}]Eliminate quantifiers over a Cartesian product of regions:
ℛ = RegionProduct[Circle[], Circle[]];Solve[Subscript[∃, {a, b}](4 x y a b == 1 && {x, a, y, b}∈ℛ), {x, y}, Reals]Regions dependent on parameters:
Subscript[ℛ, 1] = InfiniteLine[{{2, 0}, {0, t}}];
Subscript[ℛ, 2] = Circle[];The answer depends on the parameter value 
:
Solve[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}, Reals]Use 
to specify that 
is a vector in 
:
ℛ = RegionIntersection[Circle[], Line[{{-2, -1}, {1, 2}}]];Solve[x∈ℛ, x]
ℛ = Sphere[];Solve[x.{1, 2, 3} == 0 && x.{-3, -2, -1} == 0 && x∈ℛ, x]Generalizations & Extensions (1)
Options (28)
Assumptions (4)
Specify conditions on parameters using Assumptions:
Solve[x ^ 2 == a, x, Reals, Assumptions -> a > 0]Solve[x ^ 2 == a, x, Reals, Assumptions -> a < 0]By default, no solutions that require parameters to satisfy equations are produced:
Solve[s == (2t) / (1 + t ^ 2) && c == (1 - t ^ 2) / (1 + t ^ 2), t]With an equation on parameters given as an assumption, a solution is returned:
Solve[s == (2t) / (1 + t ^ 2) && c == (1 - t ^ 2) / (1 + t ^ 2), t, Assumptions -> s ^ 2 + c ^ 2 == 1]Assumptions that contain solve variables are considered to be a part of the system to solve:
Solve[2 ^ x == 8, x, Assumptions -> x > 0]Equivalent statement without using Assumptions:
Solve[2 ^ x == 8 && x > 0, x]With parameters assumed to belong to a discrete set, solutions involving arbitrary conditions are returned:
Solve[a x ^ 2 + b x + c == 0, x, Assumptions -> Element[a, Integers]]
Cubics (4)
By default, Solve uses general formulas for solving cubics in radicals only when symbolic parameters are present:
Solve[x ^ 3 + a x ^ 2 + 2 x + 3 == 0, x]For polynomials with numeric coefficients, Solve does not use the formulas:
Solve[x ^ 3 + 2 x ^ 2 + 3 x + 4 == 0, x]With Cubics->False, Solve never uses the formulas:
Solve[x ^ 3 + a x ^ 2 + 2 x + 3 == 0, x, Cubics -> False]With Cubics->True, Solve always uses the formulas:
Solve[x ^ 3 + 2 x ^ 2 + 3 x + 4 == 0, x, Cubics -> True]Real roots of irreducible cubics still contain I in their algebraic forms by casus irreducibilis:
Solve[-61 + 110x - 60 x^2 + 10 x^3 == 0, x, Cubics -> True]Machine-precision numerical evaluation gives a spurious imaginary part:
N[%]Arbitrary-precision evaluation still leaves an imaginary part:
N[%%, 20]With the default setting CubicsAutomatic, explicitly real results are obtained:
Solve[-61 + 110x - 60 x^2 + 10 x^3 == 0, x]N[%]GeneratedParameters (1)
Solve may introduce new parameters to represent the solution:
Solve[x ^ 2 - 3y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers]Use GeneratedParameters to control how the parameters are generated:
Solve[x ^ 2 - 3y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers, GeneratedParameters -> (Subscript[k, #]&)]InverseFunctions (3)
By default, Solve uses inverse functions but prints warning messages:
Solve[f[x] == 0, x]
Solve[x + E ^ x == 1, x]
For symbols with the NumericFunction attribute, symbolic inverses are not used:
Solve[Gamma[x] == a, x]
With InverseFunctions->True, Solve does not print inverse function warning messages:
Solve[f[x] == 0, x, InverseFunctions -> True]Solve[x + E ^ x == 1, x, InverseFunctions -> True]Symbolic inverses are used for all symbols:
Solve[Gamma[x] == a, x, InverseFunctions -> True]With InverseFunctions->False, Solve does not use inverse functions:
Solve[f[x] == 0, x, InverseFunctions -> False]
Solving algebraic equations does not require using inverse functions:
Solve[x ^ 2 + 1 == 0, x, InverseFunctions -> False]Here, a method based on Reduce is used, as it does not require using inverse functions:
Solve[x + E ^ x == 1, x, InverseFunctions -> False]MaxExtraConditions (4)
By default, no solutions requiring extra conditions are produced:
Solve[a == 0 && x == 0, x]Unless the parameters are discrete:
Solve[a == 0 && x == 0, x, Integers]The default setting, MaxExtraConditions->0, gives no solutions requiring conditions:
Solve[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x]Solve[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> 0]MaxExtraConditions->1 gives solutions requiring up to one equation on parameters:
Solve[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> 1]MaxExtraConditions->2 gives solutions requiring up to two equations on parameters:
Solve[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> 2]Give solutions requiring the minimal number of parameter equations:
Solve[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> Automatic]Solve[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> All]By default, Solve drops inequation conditions on continuous parameters:
Solve[a x == 1, x]With MaxExtraConditions->All, Solve includes all conditions:
Solve[a x == 1, x, MaxExtraConditions -> All]MaxRoots (4)
Find 
out of 
roots of a polynomial:
Solve[x ^ 12345 + x + 1 == 0, x, MaxRoots -> 3]Find 
out of 
roots of a polynomial system:
Solve[x ^ 1000 == y ^ 3 + 1 && y ^ 1000 == z ^ 3 + 1 && z ^ 1000 == x ^ 3 + 1, {x, y, z}, MaxRoots -> 3]Find 
solutions of a transcendental system:
Solve[Sin[x + y] == 2x + 3y + 1 && AiryAi[x ^ 2 - y] == y ^ 2 - 1, {x, y}, MaxRoots -> 5]When the system contains symbolic parameters, the option value is ignored:
Solve[x ^ 4 == a, x, MaxRoots -> 3]
Method (1)
Modulus (2)
Solve equations over the integers modulo 9:
Solve[x ^ 2 + 3y ^ 2 == 4 && 3x ^ 3 - 4y ^ 2 + x y == 1, {x, y}, Modulus -> 9]Find a modulus for which a system of equations has a solution:
Solve[x ^ 2 + y ^ 2 == 1 && 2x + 3y == 5 && x ^ 3 - x y == 7, {x, y}, Modulus -> Automatic]Quartics (3)
By default, Solve uses the general formulas for solving quartics in radicals only when symbolic parameters are present:
Solve[x ^ 4 + a x ^ 2 + 2 x + 3 == 0, x][[1]]For polynomials with numeric coefficients, Solve does not use the formulas:
Solve[x ^ 4 + 2 x ^ 2 + 3 x + 4 == 0, x]With Quartics->False, Solve never uses the formulas:
Solve[x ^ 4 + a x ^ 2 + 2 x + 3 == 0, x, Quartics -> False]With Quartics->True, Solve always uses the formulas:
Solve[x ^ 4 + 2 x ^ 2 + 3 x + 4 == 0, x, Quartics -> True][[1]]VerifySolutions (1)
Solve verifies solutions obtained using non-equivalent transformations:
eqns = Sqrt[x + Sqrt[x]] == 2 && y ^ 9 - y - 2 x ^ (1 / 7) == 3;
(sol1 = Solve[eqns, {x, y}]);//TimingWith VerifySolutions->False, Solve does not verify the solutions:
(sol2 = Solve[eqns, {x, y}, VerifySolutions -> False]);//TimingSome of the solutions returned with VerifySolutions->False are not correct:
Length /@ {sol1, sol2}This uses a fast numeric test in an attempt to select correct solutions:
(sol3 = Select[sol2, TrueQ[eqns /. N[#, 20]]&]);//TimingIn this case numeric verification gives the correct solution set:
sol3 === sol1WorkingPrecision (1)
By default, Solve finds exact solutions of equations:
SeedRandom[0];
mat = Table[RandomInteger[{-10 ^ 100, 10 ^ 100}], {200}, {200}];
b = Table[RandomInteger[{-10 ^ 100, 10 ^ 100}], {200}];
vars = x /@ Range[200];
(sol = Solve[Thread[mat.vars == b], vars]);//TimingComputing the solution using 100-digit numbers is faster:
(sol1 = Solve[Thread[mat.vars == b], vars, WorkingPrecision -> 100]);//TimingThe result agrees with the exact solution in the first 100 digits:
Max[Abs[(vars /. sol) - (vars /. sol1)]]Computing the solution using machine numbers is much faster:
(sol2 = Solve[Thread[mat.vars == b], vars, WorkingPrecision -> MachinePrecision]);//TimingThe result is still quite close to the exact solution:
Max[Abs[(vars /. sol) - (vars /. sol2)]]Applications (7)
Solve[a x ^ 2 + b x + c == 0, x]Find intersection points of a circle and a parabola:
pts = Solve[x ^ 2 + y ^ 2 == 1 && y - 2x ^ 2 + 3 / 2 == 0, {x, y}]Show[{ContourPlot[{x ^ 2 + y ^ 2 == 1, y - 2x ^ 2 + 3 / 2 == 0}, {x, -1.5, 1.5}, {y, -1.5, 1.5}], Graphics[{Red, PointSize[Medium], Point[{x, y} /. pts]}]}]Find conditions for a quartic to have all roots equal:
f[x_] := x ^ 4 + a x ^ 3 + b x ^ 2 + c x + dA method using Subresultants:
Solve[Thread[Drop[Subresultants[f[x], D[f[x], x], x], -1] == 0], {b, c, d}]A method using quantifier elimination:
Solve[Exists[x, f[x] == 0, ForAll[y, f[y] == 0, x == y]], {b, c, d}]Plot a space curve given by an implicit description:
curve = x ^ 2 + y ^ 2 + z ^ 2 == 1 && x ^ 3 + x y ^ 2 == z ^ 2;sol = Solve[curve, {y, z}, Reals]cond = Union[#[[2]]& /@ Cases[sol, _ConditionalExpression, Infinity]]{l, u} = N[{cond[[1, 1]], cond[[1, 5]]}]ParametricPlot3D[{x, y, z} /. sol, {x, l, u}]Plot the projection of the space curve on the {x,y} plane:
proj = Solve[Exists[z, curve], y, Reals]ParametricPlot[{x, y} /. proj, {x, l, u}]Solve[x ^ 2 + y ^ 2 == 5 ^ 2 && y > x > 0, {x, y}, Integers]Find a sequence of Pythagorean triples:
Table[Solve[x ^ 2 + y ^ 2 == z ^ 2 && y > x > 0, {x, y}, Integers], {z, 30}]Find how to pay $2.27 postage with 10-, 23-, and 37-cent stamps:
Solve[a 10 + b 23 + c 37 == 227 && a >= 0 && b >= 0 && c >= 0, {a, b, c}, Integers]The same task can be accomplished with IntegerPartitions:
IntegerPartitions[227, All, {37, 23, 10}]Find 200 roots of a complex analytic function:
rts = Solve[Sin[x ^ 3] - x ^ 5 == 1, x, MaxRoots -> 200];Show the roots on the complex plot for the function:
ComplexPlot[Sin[x ^ 3] - x ^ 5 - 1, {x, -7.5 - 7.5I, 7.5 + 7.5I}, ...]Properties & Relations (15)
Solutions satisfy the equations:
eqns = {x ^ 2 + y ^ 2 == 1 && 2x + 3y == 4};
Solve[eqns, {x, y}]Solutions are given as replacement rules and can be directly used for substitution:
eqns /. %Solve uses {} to represent the empty solution or no solution:
Solve[x == 1 && x == 2, x]Solve uses {{}} to represent the universal solution or all points satisfying the equations:
Solve[x == x, x]For univariate equations, Solve repeats solutions according to their multiplicity:
Solve[(x - 1) ^ 2(x - 2) ^ 3 == 0, x]Solutions of algebraic equations are often given in terms of Root objects:
Solve[x ^ 5 - 2x + 7 == 0, x]Use N to compute numeric approximations of Root objects:
N[%, 20]Root objects may involve parameters:
Solve[x ^ 5 + a x + 1 == 0, x]Use Series to compute series expansions of Root objects:
Series[x /. %[[1]], {a, 0, 10}]The series satisfies the equation up to order 11:
x ^ 5 + a x + 1 /. x -> %Solve represents solutions in terms of replacement rules:
Solve[x ^ 4 == 4, x]Reduce represents solutions in terms of Boolean combinations of equations and inequalities:
Reduce[x ^ 4 == 4, x]Solve uses fast heuristics to solve transcendental equations, but may give incomplete solutions:
Solve[x - E ^ x == 1, x]
Solve[x Log[x] == a, x]
Reduce uses methods that are often slower, but finds all solutions and gives all necessary conditions:
Reduce[x - E ^ x == 1, x]Reduce[x Log[x] == a, x]Use FindInstance to find solution instances:
FindInstance[x ^ 2 + y ^ 2 + z ^ 2 == 1 && 2x y == z ^ 3, {x, y, z}]Like Reduce, FindInstance can be given inequalities and domain specifications:
FindInstance[x ^ 2 - 3y ^ 2 == 1 && 0 < x < 10 ^ 10, {x, y}, Integers, 3]Use DSolve to solve differential equations:
DSolve[y''[x] == -y[x], y[x], x]DSolve[{y''[x] == -y[x], y[0] == 0, y'[0] == 1}, y[x], x]Use RSolve to solve recurrence equations:
RSolve[f[n + 1] == n f[n], f[n], n]RSolve[{f[n + 1] == n + f[n], f[0] == 0}, f[n], n]SolveAlways gives the values of parameters for which complex equations are always true:
SolveAlways[(a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1, x]The same problem can be expressed using ForAll and solved with Solve or Reduce:
Solve[ForAll[x, (a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1], {a, b, c}]Reduce[ForAll[x, (a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1], {a, b, c}]Resolve eliminates quantifiers, possibly without solving the resulting quantifier-free system:
Resolve[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x y > z ^ 3], Reals]Resolve[ForAll[{x, y}, a x ^ 2 + b x + c == 0 && a y ^ 2 + b y + c == 0, x == y]]Eliminate eliminates variables from systems of complex equations:
Eliminate[x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3, x]This solves the same problem using Resolve:
Resolve[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3]]Reduce and Solve additionally solve the resulting equations:
Reduce[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3], {y, z}]Solve[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3], z]
is bijective iff the equation 
has exactly one solution for each 
:
Solve[x ^ 3 + x + 1 == y, x, Reals]Solve[x ^ 2 + x + 1 == y, x, Reals]Use FunctionBijective to test whether a function is bijective:
FunctionBijective[x ^ 3 + x + 1, x]FunctionBijective[x ^ 2 + x + 1, x]Use FunctionAnalytic to test whether a function is analytic:
f = Sin[3x ^ 3] - 2x + 1;FunctionAnalytic[f, x, Complexes]An analytic function can have only finitely many zeros in a closed and bounded region:
Solve[f == 0 && Abs[x] ≤ 1, x]ComplexPlot[f, {x, -1 - I, 1 + I}, RegionFunction -> (Abs[#] ≤ 1&), Epilog -> {PointSize[Medium], Blue, Point[{Re[x], Im[x]}] /. %}]Possible Issues (9)
Solve gives generic solutions; solutions involving equations on parameters are not given:
Solve[a x ^ 2 + x == 1, x]Reduce gives all solutions, including those that require equations on parameters:
Reduce[a x ^ 2 + x == 1, x]With MaxExtraConditions->All, Solve also gives non-generic solutions:
Solve[a x ^ 2 + x == 1, x, MaxExtraConditions -> All]Solve results do not depend on whether some of the input equations contain only parameters. The following two systems are equivalent and have no generic solutions:
Solve[x == 1 && a == 2, x]Solve[x == 1 && x + a == x + 2, x]Use MaxExtraConditions to specify the number of parameter conditions allowed:
Solve[x == 1 && a == 2, x, MaxExtraConditions -> 1]Solve[x == 1 && x + a == x + 2, x, MaxExtraConditions -> 1]Use the Exists quantifier to find solutions that are valid for some value of parameter 
:
Solve[Exists[a, x == 1 && a == 2], x]Solve[Exists[a, x == 1 && x + a == x + 2], x]Solve does not eliminate solutions that are neither generically correct nor generically incorrect:
Solve[Sqrt[((1 - z) / (1 + z)) ^ 2] == (1 - a) / (1 + a), z]The solutions are correct for 
and incorrect for 
:
Sqrt[((1 - z) / (1 + z)) ^ 2] - (1 - a) / (1 + a) /. % /. {{a -> (2 + 3I) / 4}, {a -> 2 + 3I}}For transcendental equations, Solve may not give all solutions:
Solve[x + E ^ x == 1 / 2, x]
Use Reduce to get all solutions:
Reduce[x + E ^ x == 1 / 2, x]Solve with Method->"Reduce" uses Reduce to find solutions, but returns replacement rules:
Solve[x + E ^ x == 1 / 2, x, Method -> "Reduce"]Using inverse functions allows Solve to find some solutions fast:
Solve[x ^ n == 1, x]//Timing
Finding the complete solution may take much longer, and the solution may be large:
(red = Reduce[x ^ n == 1, x])//LeafCount//TimingThis finds the values of n for which x==2 is a solution:
Reduce[red /. x -> 2, n]Simplify[x ^ n /. {x -> 2, n -> 2I Pi C[1] / Log[2]}, Element[C[1], Integers]]Interpretation of assumptions depends on their syntactic properties. Here the solution is generic in the parameter space restricted by the assumptions:
Solve[x == a && x == b, x, Assumptions -> a == b]This mathematically equivalent assumption contains the solve variable, and hence is treated as a part of the system to solve:
Solve[x == a && x == b, x, Assumptions -> a + x == b + x]There are no generic solutions, because the input is interpreted as:
Solve[x == a && x == b && a + x == b + x, x]The solution is non-generic, since it requires the parameters to satisfy an equation:
Solve[x == a && x == b && a + x == b + x, x, MaxExtraConditions -> All]When parameters are restricted to a discrete set, the notion of genericity is not well defined, and all solutions are returned:
Solve[a x ^ 2 + b x == 1, x, Assumptions -> Element[a | b, Integers]]Removable singularities of input equations are generally not considered valid solutions:
Solve[(x ^ 2 - 2Sqrt[2]x + 2) / (x - Sqrt[2]) == 0, x]Limit[(x ^ 2 - 2Sqrt[2]x + 2) / (x - Sqrt[2]), x -> Sqrt[2]]However, solutions may include removable singularities that are cancelled by automatic simplification:
Solve[x ^ 2 / x == 0, x]The removable singularity at 
is cancelled by evaluation:
x ^ 2 / x == 0Here the removable singularity at 
is cancelled by Together, which is used to preprocess the equation:
Solve[(x ^ 2 - 2x + 1) / (x - 1) == 0, x]Together[(x ^ 2 - 2x + 1) / (x - 1) == 0]The value of MaxRoots is used only for systems with numeric coefficients:
Solve[x ^ 4 == y, {x, y}, MaxRoots -> 3]When symbolic parameters are present, the option value is ignored:
Solve[x ^ 4 == y, {x}, MaxRoots -> 3]
Expressions given as variables are treated as atomic objects and not as functions of their subexpressions:
Solve[x + Sin[x] == 1, Sin[x]]Effectively, variables are replaced with new symbols before the equations are solved:
Solve[f[x] + Integrate[f[x], {x, 0, 1}] == 2x, f[x]]f[x] + Integrate[f[x], {x, 0, 1}] == 2x /. f[x] -> zText
Wolfram Research (1988), Solve, Wolfram Language function, https://reference.wolfram.com/language/ref/Solve.html (updated 2024).
CMS
Wolfram Language. 1988. "Solve." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/Solve.html.
APA
Wolfram Language. (1988). Solve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Solve.html