SolveValues
SolveValues[expr,vars]
gives the values of vars determined by the solutions of the system expr.
SolveValues[expr,vars,dom]
uses solutions over the domain dom. Common choices of dom are Reals, Integers and Complexes.
Details and Options
- The system expr can be any logical combination of:
-
lhs==rhs equations lhs!=rhs inequations lhs>rhs or lhs>=rhs inequalities expr∈dom domain specifications {x,y,…}∈reg region specification ForAll[x,cond,expr] universal quantifiers Exists[x,cond,expr] existential quantifiers - SolveValues[{expr1,expr2,…},vars] is equivalent to SolveValues[expr1&&expr2&&…,vars].
- If a single variable is specified, the result is a list of values of the variable for which expr is True.
- If a list of variables is specified, the result is a list of lists of values for the variables for which expr is True.
- When a single variable is specified and a particular root of an equation has multiplicity greater than one, SolveValues gives several copies of the corresponding solution.
- SolveValues[expr,vars] assumes by default that quantities appearing algebraically in inequalities are real, while all other quantities are complex.
- SolveValues[expr,vars,dom] restricts all variables and parameters to belong to the domain dom.
- If dom is Reals or a subset such as Integers or Rationals, then all constants and function values are also restricted to be real.
- SolveValues[expr&&vars∈Reals,vars,Complexes] solves for real values of variables, but function values are allowed to be complex.
- SolveValues[expr,vars,Integers] solves Diophantine equations over the integers.
- SolveValues[…,x∈reg,Reals] constrains x to be in the region reg. The different coordinates for x can be referred to using Indexed[x,i].
- Algebraic variables in expr free of vars and of each other are treated as independent parameters.
- SolveValues deals primarily with linear and polynomial equations.
- When expr involves only polynomial equations and inequalities over real or complex domains, then SolveValues can always in principle solve directly for vars.
- When expr involves transcendental conditions or integer domains, SolveValues will often introduce additional parameters in its results.
- SolveValues can give explicit representations for solutions to all linear equations and inequalities over the integers and can solve a large fraction of Diophantine equations described in the literature.
- When expr involves only polynomial conditions over real or complex domains, SolveValues[expr,vars] will always be able to eliminate quantifiers.
- SolveValues gives generic solutions only. Solutions that are valid only when continuous parameters satisfy equations are removed. Other solutions that are only conditionally valid are expressed as ConditionalExpression objects.
- Conditions included in ConditionalExpression solutions may involve inequalities, Element statements, equations and inequations on non-continuous parameters and equations with full-dimensional solutions. Inequations and NotElement conditions on continuous parameters and variables are dropped.
- SolveValues may use non-equivalent transformations to find solutions of transcendental equations and hence it may not find some solutions and may not establish exact conditions on the validity of the solutions found. If this happens, an error message is issued.
- SolveValues uses special efficient techniques for handling sparse systems of linear equations with approximate numerical coefficients.
- The following options can be given:
-
Assumptions $Assumptions assumptions on parameters Cubics Automatic whether to use explicit radicals to solve all cubics GeneratedParameters C how to name parameters that are generated InverseFunctions Automatic whether to use symbolic inverse functions MaxExtraConditions 0 how many extra equational conditions on continuous parameters to allow MaxRoots Infinity maximum number of roots returned Method Automatic what method should be used Modulus 0 modulus to assume for integers Quartics Automatic whether to use explicit radicals to solve all quartics VerifySolutions Automatic whether to verify solutions obtained using non-equivalent transformations WorkingPrecision Infinity precision to be used in computations - With MaxExtraConditions->Automatic, only solutions that require the minimal number of equational conditions on continuous parameters are included.
- With MaxExtraConditions->All, solutions that require arbitrary conditions on parameters are given and all conditions are included.
- With MaxExtraConditions->k, only solutions that require at most k equational conditions on continuous parameters are included.
- With Method->Reduce, SolveValues uses only equivalent transformations and finds all solutions.
- SolveValues[eqns,…,Modulus->m] solves equations over the integers modulo m. With Modulus->Automatic, SolveValues will attempt to find the largest modulus for which the equations have solutions.
Examples
open all close allBasic Examples (5)
SolveValues[x ^ 2 + a x + 1 == 0, x]Solve simultaneous equations in 
and 
:
SolveValues[a x + y == 7 && b x - y == 1, {x, y}]Solve an equation over the reals:
SolveValues[(x ^ 2 + 2)(x ^ 2 - 2) == 0, x, Reals]Solve an equation over the positive integers:
SolveValues[x ^ 2 + 2y ^ 3 == 3681 && x > 0 && y > 0, {x, y}, Integers]Solve equations in a geometric region:
SolveValues[{x, y}∈InfiniteLine[{{0, 0}, {2, 1}}] && {x, y}∈Circle[], {x, y}]Graphics[{{Blue, InfiniteLine[{{0, 0}, {2, 1}}], Circle[]}, {PointSize[Large], Red, Point[%]}}]Scope (87)
Basic Uses (7)
Solutions are given as lists of values of the specified variables:
sol = SolveValues[x ^ 2 + y ^ 2 == 2 && x - y == 1, {x, y}]Check that solutions satisfy the equations:
x ^ 2 + y ^ 2 == 2 && x - y == 1 /. Thread[{x, y} -> #]& /@ %If there are no solutions, SolveValues returns an empty list:
SolveValues[x == 1 && x == 2, x]Some of the variables may appear in the solutions as free parameters:
SolveValues[x + y == 1, {x, y}]
Find solutions over specified domains:
SolveValues[(x ^ 4 - 1)(x ^ 4 - 4) == 0, x, Complexes]SolveValues[(x ^ 4 - 1)(x ^ 4 - 4) == 0, x, Reals]SolveValues[(x ^ 4 - 1)(x ^ 4 - 4) == 0, x, Integers]Solve equations with coefficients involving a symbolic parameter:
sol = SolveValues[x ^ 2 + y ^ 2 == 1 && x + y == a, {x, y}]Plot the real parts of the solutions for y as a function of the parameter a:
Plot[Evaluate[Re[#[[2]]]& /@ sol], {a, 0, 2}]Solution of this equation over the reals requires conditions on the parameters:
sol = SolveValues[x ^ 2 + a x + b == 0, x, Reals]Use Normal to remove the conditions:
Normal[sol]Solution of this equation over the positive integers requires introduction of a new parameter:
sol = SolveValues[x ^ 2 - 2y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers]First[sol] /. Table[{C[1] -> i}, {i, 10}]//SimplifyComplex Equations in One Variable (16)
Polynomial equations solvable in radicals:
SolveValues[x ^ 4 - x ^ 2 - 5 == 0, x]To use general formulas for solving cubic equations, set CubicsTrue:
SolveValues[x ^ 3 - 2x ^ 2 + 5x + 7 == 0, x, Cubics -> True]By default, SolveValues uses Root objects to represent solutions of general cubic equations:
SolveValues[x ^ 3 - 2x ^ 2 + 5x + 7 == 0, x]SolveValues[x ^ 5 - 2x + 17 == 0, x]Polynomial equations with multiple roots:
SolveValues[(x ^ 2 - 1)(x ^ 4 - 1) == 0, x]Find five roots of a polynomial of a high degree:
SolveValues[x ^ 1234567 + 9x ^ 2 + 7x - 1 == 0, x, MaxRoots -> 5]Polynomial equations with symbolic coefficients:
SolveValues[a x ^ 2 + b x + c == 0, x]SolveValues[a x ^ 5 + b x + c == 0, x]SolveValues[Sqrt[x] + 3x ^ (1 / 3) == 5, x]Complete solutions to transcendental equations:
SolveValues[Sin[x] == 1 / 3, x]SolveValues[(x ^ 5 - 1) ^ x == 0, x]Partial solutions to transcendental equations:
SolveValues[x ^ (2a) + 2x ^ a + 1 == 0, x]
SolveValues[ArcTan[1 / Sqrt[1 + x ^ 2], x / Sqrt[1 + x ^ 2]] == a, x]
SolveValues cannot find all solutions here:
SolveValues[5 == x * 2 ^ (x ^ 2), x]
SolveValues[5 == x * 2 ^ (x ^ 2), x, MaxRoots -> 3]Univariate elementary function equations over bounded regions:
SolveValues[Sin[E ^ x] - Cos[2 x] == 1 && -1 ≤ Re[x] ≤ 1 && -1 ≤ Im[x] ≤ 1, x]Univariate holomorphic function equations over bounded regions:
SolveValues[Gamma[x] - Log[x] == I / 2 && Abs[x - 2] < 3 / 2, x]
Here SolveValues finds some solutions but is not able to prove there are no other solutions:
SolveValues[x == E ^ (1 / x) && Abs[x] < 5, x]
Equation with a purely imaginary period over a vertical stripe in the complex plane:
SolveValues[Cos[Exp[x]] == 3 Exp[-x] + 1 && 0 ≤ Re[x] ≤ 1, x]Find a specified number of roots of an unrestricted complex equation:
SolveValues[Sin[FresnelS[x] + BesselJ[3, x ^ 2 - 1]] == 2 ^ Cos[x] - 3, x, MaxRoots -> 5]SolveValues[f[x] ^ 3 + 2f[x] - 3 == 0, x]
Nonanalytic complex equations:
SolveValues[{Re[x] + Im[x]^2 == 1, Re[x] - Im[x] == -1}, x]SolveValues[{Abs[x] == 1, Arg[x] == π / 4}, x]Systems of Complex Equations in Several Variables (12)
SolveValues[{x + 2y + 3z == 4, 3x + 4y + 5z == 6, 7x + 7y + 8z == 9}, {x, y, z}]Linear equations with symbolic coefficients:
SolveValues[a x + b y + c z == d && 3x + 4y + 5z == 6 && 7x + 7y + 8z == 9, {x, y, z}]Underdetermined systems of linear equations:
SolveValues[x + 2y + 3z == 4 && 3x + 4y + 5z == 6 && 6x + 7y + 8z == 9, {x, y, z}]
Linear equations with no solutions:
SolveValues[x + 2y + 3z == 4 && 3x + 4y + 5z == 6 && 6x + 7y + 8z == 0, {x, y, z}]Systems of polynomial equations:
SolveValues[x ^ 2 + y ^ 2 == 1 && x + 2y == 3, {x, y}]Find five out of a trillion roots of a polynomial system:
SolveValues[x ^ 10000 == y ^ 2 + 3y + 2 && y ^ 10000 == z ^ 2 + 3z + 2 && z ^ 10000 == x ^ 2 + 3x + 2, {x, y, z}, MaxRoots -> 5]Polynomial equations with symbolic coefficients:
SolveValues[a x ^ 2 + b y ^ 2 == c && x + 2y == 3, {x, y}]SolveValues[Sqrt[x y] == Sqrt[x + y] && Sqrt[x] - y ^ (1 / 3) == 1, {x, y}]
SolveValues[Sin[x + y] == 1 && Log[x - y] == 1 / 2, {x, y}]SolveValues[3 ^ x ^ 2 == 7 && x ^ 2 - y ^ 3 == 4, {x, y}]
Find a specified number of solutions of transcendental equations:
SolveValues[Sin[x + y] == x y + 1 && Cos[x - y] == AiryAi[x y] + 2, {x, y}, MaxRoots -> 3]Square analytic systems over bounded boxes:
SolveValues[FresnelS[x - y] - AiryAi[x] + y == (3 + I) / 2 && CosIntegral[x] y - Sin[x y] == -5(1 - I) / 4 && 1 ≤ Re[x] ≤ 2 && 0 ≤ Im[x] ≤ 1 && 1 ≤ Re[y] ≤ 2 && 0 ≤ Im[y] ≤ 1, {x, y}]SolveValues[{Re[x^2] + Im[y] == 1, x^2 - y^2 == 0, Im[x^3] - Im[y]^2 == 2}, {x, y}]Real Equations in One Variable (13)
SolveValues[x ^ 5 - 2x + 1 == 0, x, Reals]Polynomial equations with multiple roots:
SolveValues[(x ^ 2 - 1)(x ^ 4 - 1) == 0, x, Reals]Polynomial equations with symbolic coefficients:
SolveValues[x ^ 3 + a x + a ^ 2 == 0, x, Reals]SolveValues[Sqrt[x] + 3x ^ (1 / 3) == 5, x, Reals]SolveValues[Abs[x] ^ 2 - x + UnitStep[x] == 9, x, Reals]Transcendental equations, solvable using inverse functions:
SolveValues[E ^ x - x == 7, x, Reals]SolveValues[ 27^2x - 1^(1/(x)) == Sqrt[9^2x - 1], x, Reals]SolveValues[JacobiSN[x, y] == 1, x, Reals]Transcendental equations, solvable using special function zeros:
SolveValues[AiryBi[1 - x ^ 2] == 0 && 2 < x < 3, x, Reals]Transcendental inequalities, solvable using special function zeros:
SolveValues[900 < AiryAiZero[2t + 1] ^ 2 < 1000, t, Reals]SolveValues[E ^ (2E ^ x) - Log[x ^ 2 + 1] - 20x == 11, x, Reals]High-degree sparse polynomial equations:
SolveValues[x ^ 1000000 - 2x ^ 777777 + 3x ^ 12345 + 9x ^ 67 - 10 == 0, x, Reals]Algebraic equations involving high-degree radicals:
SolveValues[2x ^ (123451 / 67890) - x ^ 2 + 4Sqrt[x] - 4x - 9 / 8 == 0, x, Reals]Equations involving non-rational real powers:
SolveValues[x ^ Pi - x ^ x ^ Sqrt[2] - Sqrt[3]x + 2 ^ (1 / 3) == 0, x, Reals]SolveValues[E ^ (2x) + x ^ 4 + 4(x ^ 2 + 1) == (2x ^ 2 + 4)E ^ x, x, Reals]Tame elementary function equations:
SolveValues[10Sin[Tan[E ^ -x ^ 2]] - x == 3, x, Reals]Elementary function equations in bounded intervals:
SolveValues[2Sin[Exp[x]] - Cos[Pi x] == 3 / 2 && -1 < x < 1, x, Reals]Holomorphic function equations in bounded intervals:
SolveValues[Cos[x] - BesselJ[5, x] == 1 / 2 && 0 ≤ x ≤ 10, x]
Periodic elementary function equations over the reals:
SolveValues[Exp[Sin[x]] - Sin[3 Cos[x]] == 0, x, Reals]Systems of Real Equations and Inequalities in Several Variables (10)
SolveValues[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3, {y, z}, Reals]SolveValues[x y == z ^ 2 - x && x y z == 2 && x ^ 2 + y ^ 2 + z ^ 2 ≤ 5, {y, z}, Reals]Quantified polynomial systems:
SolveValues[Exists[x, x ^ 2 + a x + b == 0 && 2 x + a == 0], a, Reals]SolveValues[ForAll[x, Exists[y, a x ^ 2 + b y ^ 2 - 3y == 1 && y < 0 && a y - y == b + 1]], {a, b}, Reals]SolveValues[Sqrt[x + 2y] - 3x + 4y ≥ 5 && x + y ^ (1 / 3) == 1, y, Reals]SolveValues[Max[x, y] == Min[y ^ 2 - x, x] + y && z + UnitStep[x - y] == 1, {y, z}, Reals]Transcendental systems, solvable using inverse functions:
SolveValues[Sin[x + y] == 1 / 2 && E ^ x - y ≤ 1, y, Reals]SolveValues[ 3^x - 2^2y == 77 && Sqrt[3^x] - 2^y == 7, {x, y}, Reals]Systems exp-log in the first variable and polynomial in the other variables:
SolveValues[E ^ x y ^ 3 + Log[x]y == 1 && x y + E ^ x / x ≥ 2, y, Reals]SolveValues[Exists[a, a x ^ 2 + Sinh[x ^ 2 + 1]a ^ 2 == 1 && x ^ 2 - a ^ 2 == 1], x, Reals]Systems elementary and bounded in the first variable and polynomial in the other variables:
SolveValues[Sin[x - Cos[x]] y ^ 3 - x == 1 && x ^ 2 + y ^ 2 ≤ 1, y, Reals]SolveValues[Exists[y, y ^ 3 - Cos[x] y + 2 x ^ 2 Sin[x ^ 2 - 1] == 0 && x ^ 2 + y ^ 2 == 2], x, Reals]Systems holomorphic and bounded in the first variable and polynomial in the other variables:
SolveValues[y ^ 3 - BesselJ[2, x + 2] y - y - 3 x == -2 && y < 0 && x ^ 2 < 2, y, Reals]
SolveValues[Exists[y, y ^ 4 - Gamma[x + 2] y - y - 3 ArcSin[x / 3] == 1 && x ^ 2 + y ^ 3 == 1 && 0 < x < 2], x, Reals]
Square systems of analytic equations over bounded regions:
SolveValues[Gamma[x + y + 1] - Sin[x y] == 1 && Erf[x ^ 2 - y] - E ^ y - x + 4 == 0 && 0 < x < 3 && 0 < y < 3, {x, y}, Reals]Diophantine Equations (11)
SolveValues[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3, {x, y, z}, Integers]Linear systems of equations and inequalities:
SolveValues[2 x + 3y == 4 && 3x - 4y ≤ 5 && x - 2y > -21, {x, y}, Integers]Univariate polynomial equations:
SolveValues[x ^ 12345 - 2x ^ 777 + 1 == 0, x, Integers]SolveValues[x ^ 2 + x y + y ^ 2 == 109, {x, y}, Integers]SolveValues[x ^ 2 - 3y ^ 2 == 22 && x > 0 && y > 0, {x, y}, Integers]SolveValues[x ^ 2 - 6 x y + 9y ^ 2 - x + 2y == 1, {x, y}, Integers]SolveValues[x ^ 3 - 2x ^ 2 y + y ^ 3 == 2, {x, y}, Integers]SolveValues[x ^ 2 + 4y ^ 2 + 9z ^ 2 + 16t ^ 2 == 354 && x > 0 && y > 0 && z > 0 && t > 0, {x, y, z, t}, Integers]SolveValues[x ^ 2 + y ^ 2 == z ^ 2, {x, y, z}, Integers]Bounded systems of equations and inequalities:
SolveValues[x ^ 4 + y ^ 4 + z ^ 4 ≤ 500 && x + y ^ 2 + z ^ 3 == 32, {x, y, z}, Integers]High‐degree systems with no solutions:
SolveValues[2x ^ 7 + 8y ^ 15 + 14 x y z == 3, {x, y, z}, Integers]Transcendental Diophantine systems:
SolveValues[Exp[y ^ 2] < x && Abs[x] < 5 && Abs[y] < 5, {x, y}, Integers]SolveValues[Exp[x ^ 2 - 5y ^ 2 + 1] + x ^ 2 - 5y ^ 2 == 0 && x > 0 && y > 0, {x, y}, Integers]Polynomial systems of congruences:
SolveValues[Mod[x ^ 2 + y ^ 2, 2] == 1 && Mod[x - 2y, 3] == 2, {x, y}, Integers]Modular Equations (4)
SolveValues[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3 && 2x - 10y + 3z == 5, {x, y, z}, Modulus -> 12]SolveValues[2 x + 3y - 5z == 1 && 3x - 4y + 7z == 3, {x, y, z}, Modulus -> 12]
Univariate polynomial equations:
SolveValues[x ^ 3 - 2x + 1 == 0, x, Modulus -> 5]Systems of polynomial equations and inequations:
SolveValues[x ^ 2 + y ^ 3 == 1 && x + 2y ^ 2 == 4, {x, y}, Modulus -> 7]SolveValues[x ^ 2 + y ^ 3 == z && x + 2y == 3z + 1 && x y z ≠ 0, {x, y, z}, Modulus -> 7]Quantified polynomial systems:
SolveValues[ForAll[x, Exists[y, a x ^ 2 + b y ^ 2 - 3y == 1 && y ≠ 0]], {a, b}, Modulus -> 3]Equations over Finite Fields (3)
ℱ = FiniteField[53, 4];
SolveValues[x ^ 5 + ℱ[123]x == ℱ[234], x]SolveValues[x ^ 7 + 2 x + 3 == 0, x, ℱ]ℱ = FiniteField[71, 2];
SolveValues[ℱ[123]x + ℱ[234]y == ℱ[345] && ℱ[321]x + ℱ[432]y == ℱ[543], {x, y}]SolveValues[ℱ[1234]x + ℱ[2345]y + ℱ[3456]z == ℱ[4567] && ℱ[1]x + ℱ[2]y + ℱ[3]z == ℱ[4], {y, z}]Systems of polynomial equations:
ℱ = FiniteField[7, 5];
SolveValues[x ^ 2 + y ^ 2 == 3 && x ^ 5 + y ^ 5 == 5, {x, y}, ℱ]SolveValues[ℱ[123]x ^ 2 + ℱ[234]y ^ 3 + ℱ[345]z ^ 4 == ℱ[456] && ℱ[21]x + ℱ[32]y ^ 2 + ℱ[43]z ^ 3 == ℱ[54] && x y z == ℱ[1], {x, y, z}]Systems with Mixed-Variable Domains (2)
Systems with Geometric Region Constraints (9)
Solve over special regions in 2D:
Subscript[ℛ, 1] = Circle[];
Subscript[ℛ, 2] = Line[{{-2, 1}, {1, -2}}];SolveValues[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}]Graphics[{{Blue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[%]}}]Solve over special regions in 3D:
Subscript[ℛ, 1] = Sphere[];
Subscript[ℛ, 2] = InfinitePlane[{{0, 0, 0}, {0, 1, 0}, {1, 0, 1}}];SolveValues[2 x y == z^2 && {x, y, z}∈Subscript[ℛ, 1] && {x, y, z}∈Subscript[ℛ, 2], {x, y, z}, Reals]Show[{ContourPlot3D[2 x y == z^2, {x, -1.2, 1.2}, {y, -1.2, 1.2}, {z, -1.2, 1.2}, Mesh -> None, ContourStyle -> Opacity[0.5]], Graphics3D[{{Opacity[0.5], Green, Subscript[ℛ, 1]}, {Opacity[0.5], Yellow, Subscript[ℛ, 2]}, {PointSize[Large], Red, Point[%]}}]}]ℛ = Cone[{{0, 0, 0}, {1, 2, 3}}, 4];SolveValues[Subscript[∃, z](x^2 + y^2 == z^2 && x + y == z - 1 && {x, y, z}∈ℛ), y, Reals]ℛ = ImplicitRegion[a + 2 b - 3 c ≥ 1 && a b c == 7, {a, b, c}];SolveValues[y^2 + x z == 1 && {x, y, z}∈ℛ, {y, z}, Reals]A parametrically defined region:
ℛ = ParametricRegion[{s + t, s - t, s t}, {s, t}];SolveValues[x y == z && x + 2 y + 3 z == 1 && {x, y, z}∈ℛ, {x, y, z}, Reals]Subscript[ℛ, 1] = Disk[{0, 0}, 2];
Subscript[ℛ, 2] = Circle[{1, 1}, 2];
Subscript[ℛ, 3] = RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]];SolveValues[x^2 == x y + 1 && {x, y}∈Subscript[ℛ, 3], {x, y}, Reals]Show[{ContourPlot[x^2 == x y + 1, {x, -2, 3}, {y, -2, 3}], Graphics[{{Opacity[0.5], Yellow, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[%]}}]}]Eliminate quantifiers over a Cartesian product of regions:
ℛ = RegionProduct[Circle[], Circle[]];SolveValues[Subscript[∃, {a, b}](4 x y a b == 1 && {x, a, y, b}∈ℛ), {x, y}, Reals]Regions dependent on parameters:
Subscript[ℛ, 1] = InfiniteLine[{{2, 0}, {0, t}}];
Subscript[ℛ, 2] = Circle[];The answer depends on the parameter value 
:
SolveValues[{x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2], {x, y}, Reals]Use 
to specify that 
is a vector in 
:
ℛ = RegionIntersection[Circle[], Line[{{-2, -1}, {1, 2}}]];SolveValues[x∈ℛ, x]In this case, 
is a vector in 
:
ℛ = Sphere[];SolveValues[x.{1, 2, 3} == 0 && x.{-3, -2, -1} == 0 && x∈ℛ, x]Options (26)
Assumptions (4)
Specify conditions on parameters using Assumptions:
SolveValues[x ^ 2 == a, x, Reals, Assumptions -> a > 0]SolveValues[x ^ 2 == a, x, Reals, Assumptions -> a < 0]By default, no solutions that require parameters to satisfy equations are produced:
SolveValues[s == (2t) / (1 + t ^ 2) && c == (1 - t ^ 2) / (1 + t ^ 2), t]With an equation on parameters given as an assumption, a solution is returned:
SolveValues[s == (2t) / (1 + t ^ 2) && c == (1 - t ^ 2) / (1 + t ^ 2), t, Assumptions -> s ^ 2 + c ^ 2 == 1]Assumptions that contain solve variables are considered to be a part of the system to solve:
SolveValues[2 ^ x == 8, x, Assumptions -> x > 0]Equivalent statement without using Assumptions:
SolveValues[2 ^ x == 8 && x > 0, x]With parameters assumed to belong to a discrete set, solutions involving arbitrary conditions are returned:
SolveValues[a x ^ 2 + b x + c == 0, x, Assumptions -> Element[a, Integers]]
Cubics (3)
By default, SolveValues uses general formulas for solving cubics in radicals only when symbolic parameters are present:
SolveValues[x ^ 3 + a x ^ 2 + 2 x + 3 == 0, x]For polynomials with numeric coefficients, SolveValues does not use the formulas:
SolveValues[x ^ 3 + 2 x ^ 2 + 3 x + 4 == 0, x]With Cubics->False, SolveValues never uses the formulas:
SolveValues[x ^ 3 + a x ^ 2 + 2 x + 3 == 0, x, Cubics -> False]With Cubics->True, SolveValues always uses the formulas:
SolveValues[x ^ 3 + 2 x ^ 2 + 3 x + 4 == 0, x, Cubics -> True]GeneratedParameters (1)
SolveValues may introduce new parameters to represent the solution:
SolveValues[x ^ 2 - 3y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers]Use GeneratedParameters to control how the parameters are generated:
SolveValues[x ^ 2 - 3y ^ 2 == 1 && x > 0 && y > 0, {x, y}, Integers, GeneratedParameters -> (Subscript[k, #]&)]InverseFunctions (3)
By default, SolveValues uses inverse functions but prints warning messages:
SolveValues[f[x] == 0, x]
SolveValues[x + E ^ x == 1, x]
For symbols with the NumericFunction attribute, symbolic inverses are not used:
SolveValues[Gamma[x] == a, x]
With InverseFunctions->True, SolveValues does not print inverse function warning messages:
SolveValues[f[x] == 0, x, InverseFunctions -> True]SolveValues[x + E ^ x == 1, x, InverseFunctions -> True]Symbolic inverses are used for all symbols:
SolveValues[Gamma[x] == a, x, InverseFunctions -> True]With InverseFunctions->False, SolveValues does not use inverse functions:
SolveValues[f[x] == 0, x, InverseFunctions -> False]
Solving algebraic equations does not require using inverse functions:
SolveValues[x ^ 2 + 1 == 0, x, InverseFunctions -> False]Here, a method based on Reduce is used, as it does not require using inverse functions:
SolveValues[x + E ^ x == 1, x, InverseFunctions -> False]MaxExtraConditions (4)
By default, no solutions requiring extra conditions are produced:
SolveValues[a == 0 && x == 0, x]Unless the parameters are discrete:
SolveValues[a == 0 && x == 0, x, Integers]The default setting, MaxExtraConditions->0, gives no solutions requiring conditions:
SolveValues[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x]SolveValues[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> 0]MaxExtraConditions->1 gives solutions requiring up to one equation on parameters:
SolveValues[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> 1]MaxExtraConditions->2 gives solutions requiring up to two equations on parameters:
SolveValues[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> 2]Give solutions requiring the minimal number of parameter equations:
SolveValues[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> Automatic]SolveValues[(x - a)(x - b) == 0 && (x - c)(x - d) == 0 && (x - a)(x - e) == 0, x, MaxExtraConditions -> All]By default, SolveValues drops inequation conditions on continuous parameters:
Solve[a x == 1, x]With MaxExtraConditions->All, SolveValues includes all conditions:
SolveValues[a x == 1, x, MaxExtraConditions -> All]MaxRoots (4)
Find 
out of 
roots of a polynomial:
SolveValues[x ^ 12345 + x + 1 == 0, x, MaxRoots -> 3]Find 
out of 
roots of a polynomial system:
SolveValues[x ^ 1000 == y ^ 3 + 1 && y ^ 1000 == z ^ 3 + 1 && z ^ 1000 == x ^ 3 + 1, {x, y, z}, MaxRoots -> 3]Find 
solutions of a transcendental system:
SolveValues[Sin[x + y] == 2x + 3y + 1 && AiryAi[x ^ 2 - y] == y ^ 2 - 1, {x, y}, MaxRoots -> 5]When the system contains symbolic parameters, the option value is ignored:
SolveValues[x ^ 4 == a, x, MaxRoots -> 3]
Method (1)
By default, SolveValues uses inverse functions to solve non-polynomial complex equations:
SolveValues[x E ^ x == 1 / 2, x]
With Method->Reduce, SolveValues uses Reduce to find the complete solution set:
SolveValues[x E ^ x == 1 / 2, x, Method -> Reduce]Modulus (1)
Quartics (3)
By default, SolveValues uses the general formulas for solving quartics in radicals only when symbolic parameters are present:
SolveValues[x ^ 4 + a x ^ 2 + 2 x + 3 == 0, x][[1]]For polynomials with numeric coefficients, SolveValues does not use the formulas:
SolveValues[x ^ 4 + 2 x ^ 2 + 3 x + 4 == 0, x]With Quartics->False, SolveValues never uses the formulas:
SolveValues[x ^ 4 + a x ^ 2 + 2 x + 3 == 0, x, Quartics -> False]With Quartics->True, SolveValues always uses the formulas:
SolveValues[x ^ 4 + 2 x ^ 2 + 3 x + 4 == 0, x, Quartics -> True][[1]]VerifySolutions (1)
SolveValues verifies solutions obtained using non-equivalent transformations:
eqns = Sqrt[x + Sqrt[x]] == 2 && y ^ 9 - y - 2 x ^ (1 / 7) == 3;
(sol1 = SolveValues[eqns, {x, y}]);//TimingWith VerifySolutions->False, SolveValues does not verify the solutions:
(sol2 = SolveValues[eqns, {x, y}, VerifySolutions -> False]);//TimingSome of the solutions returned with VerifySolutions->False are not correct:
Length /@ {sol1, sol2}This uses a fast numeric test in an attempt to select correct solutions:
(sol3 = Select[sol2, TrueQ[eqns /. Thread[{x, y} -> N[#, 20]]]&]);//TimingIn this case, numeric verification gives the correct solution set:
sol3 === sol1WorkingPrecision (1)
By default, SolveValues finds exact solutions of equations:
SeedRandom[0];
mat = Table[RandomInteger[{-10 ^ 100, 10 ^ 100}], {200}, {200}];
b = Table[RandomInteger[{-10 ^ 100, 10 ^ 100}], {200}];
vars = x /@ Range[200];
(sol = SolveValues[Thread[mat.vars == b], vars]);//TimingComputing the solution using 100-digit numbers is faster:
(sol1 = SolveValues[Thread[mat.vars == b], vars, WorkingPrecision -> 100]);//TimingThe result agrees with the exact solution in the first 100 digits:
Max[Abs[sol - sol1]]Computing the solution using machine numbers is much faster:
(sol2 = SolveValues[Thread[mat.vars == b], vars, WorkingPrecision -> MachinePrecision]);//TimingThe result is still quite close to the exact solution:
Max[Abs[sol - sol2]]Applications (7)
SolveValues[a x ^ 2 + b x + c == 0, x]Find intersection points of a circle and a parabola:
pts = SolveValues[x ^ 2 + y ^ 2 == 1 && y - 2x ^ 2 + 3 / 2 == 0, {x, y}]Show[{ContourPlot[{x ^ 2 + y ^ 2 == 1, y - 2x ^ 2 + 3 / 2 == 0}, {x, -1.5, 1.5}, {y, -1.5, 1.5}], Graphics[{Red, PointSize[Medium], Point[pts]}]}]Find conditions for a quartic to have all roots equal:
f[x_] := x ^ 4 + a x ^ 3 + b x ^ 2 + c x + dA method using Subresultants:
SolveValues[Thread[Drop[Subresultants[f[x], D[f[x], x], x], -1] == 0], {b, c, d}]A method using quantifier elimination:
SolveValues[Exists[x, f[x] == 0, ForAll[y, f[y] == 0, x == y]], {b, c, d}]Plot a space curve given by an implicit description:
curve = x ^ 2 + y ^ 2 + z ^ 2 == 1 && x ^ 3 + x y ^ 2 == z ^ 2;sol = SolveValues[curve, {y, z}, Reals]cond = Union[#[[2]]& /@ Cases[sol, _ConditionalExpression, Infinity]]{l, u} = N[{cond[[1, 1]], cond[[1, 5]]}]ParametricPlot3D[Prepend[#, x]& /@ sol, {x, l, u}]Plot the projection of the space curve on the {x,y} plane:
proj = SolveValues[Exists[z, curve], y, Reals]ParametricPlot[{x, #}& /@ proj, {x, l, u}]SolveValues[x ^ 2 + y ^ 2 == 5 ^ 2 && y > x > 0, {x, y}, Integers]Find a sequence of Pythagorean triples:
Table[SolveValues[x ^ 2 + y ^ 2 == z ^ 2 && y > x > 0, {x, y}, Integers], {z, 30}]Find how to pay $2.27 postage with 10-, 23-, and 37-cent stamps:
SolveValues[a 10 + b 23 + c 37 == 227 && a >= 0 && b >= 0 && c >= 0, {a, b, c}, Integers]The same task can be accomplished with IntegerPartitions:
IntegerPartitions[227, All, {37, 23, 10}]Find 200 roots of a complex analytic function:
rts = SolveValues[Sin[x ^ 3] - x ^ 5 == 1, x, MaxRoots -> 200];Show the roots on the complex plot for the function:
ComplexPlot[Sin[x ^ 3] - x ^ 5 - 1, {x, -7.5 - 7.5I, 7.5 + 7.5I}, ...]Properties & Relations (15)
Solutions are given as lists and satisfy the equations:
eqns = {x ^ 2 + y ^ 2 == 1 && 2x + 3y == 4};SolveValues[eqns, {x, y}]eqns /. Thread[{x, y} -> #]& /@ %For univariate equations, SolveValues repeats solutions according to their multiplicity:
SolveValues[(x - 1) ^ 2(x - 2) ^ 3 == 0, x]Solutions of algebraic equations are often given in terms of Root objects:
SolveValues[x ^ 5 - 2x + 7 == 0, x]Use N to compute numeric approximations of Root objects:
N[%, 20]Root objects may involve parameters:
SolveValues[x ^ 5 + a x + 1 == 0, x]Use Series to compute series expansions of Root objects:
Series[%[[1]], {a, 0, 10}]The series satisfies the equation up to order 11:
x ^ 5 + a x + 1 /. x -> %SolveValues gives values of the solutions:
SolveValues[x ^ 4 == 4, x]Solve represents solutions in terms of replacement rules:
Solve[x ^ 4 == 4, x]Reduce represents solutions in terms of Boolean combinations of equations and inequalities:
Reduce[x ^ 4 == 4, x]SolveValues uses fast heuristics to solve transcendental equations, but may give incomplete solutions:
SolveValues[x - E ^ x == 1, x]
SolveValues[x Log[x] == a, x]
Reduce uses methods that are often slower, but finds all solutions and gives all necessary conditions:
Reduce[x - E ^ x == 1, x]Reduce[x Log[x] == a, x]Use FindInstance to find solution instances:
FindInstance[x ^ 2 + y ^ 2 + z ^ 2 == 1 && 2x y == z ^ 3, {x, y, z}]Like Reduce, FindInstance can be given inequalities and domain specifications:
FindInstance[x ^ 2 - 3y ^ 2 == 1 && 0 < x < 10 ^ 10, {x, y}, Integers, 3]Use DSolve to solve differential equations:
DSolve[y''[x] == -y[x], y[x], x]DSolve[{y''[x] == -y[x], y[0] == 0, y'[0] == 1}, y[x], x]Use RSolve to solve recurrence equations:
RSolve[f[n + 1] == n f[n], f[n], n]RSolve[{f[n + 1] == n + f[n], f[0] == 0}, f[n], n]SolveAlways gives the values of parameters for which complex equations are always true:
SolveAlways[(a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1, x]The same problem can be expressed using ForAll and solved with SolveValues, Solve or Reduce:
SolveValues[ForAll[x, (a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1], {a, b, c}]Solve[ForAll[x, (a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1], {a, b, c}]Reduce[ForAll[x, (a - 2b + 1)x ^ 2 + (a - b ^ 2 - c)x == a ^ 2 - b + 3c - 1], {a, b, c}]Resolve eliminates quantifiers, possibly without solving the resulting quantifier-free system:
Resolve[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x y > z ^ 3], Reals]Resolve[ForAll[{x, y}, a x ^ 2 + b x + c == 0 && a y ^ 2 + b y + c == 0, x == y]]Eliminate eliminates variables from systems of complex equations:
Eliminate[x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3, x]This solves the same problem using Resolve:
Resolve[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3]]Reduce, Solve and SolveValues additionally solve the resulting equations:
Reduce[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3], {y, z}]Solve[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3], z]SolveValues[Exists[x, x ^ 2 + y ^ 2 + z ^ 2 == 1 && x z == y ^ 3], z]
is bijective iff the equation 
has exactly one solution for each 
:
SolveValues[x ^ 3 + x + 1 == y, x, Reals]SolveValues[x ^ 2 + x + 1 == y, x, Reals]Use FunctionBijective to test whether a function is bijective:
FunctionBijective[x ^ 3 + x + 1, x]FunctionBijective[x ^ 2 + x + 1, x]Use FunctionAnalytic to test whether a function is analytic:
f = Sin[3x ^ 3] - 2x + 1;FunctionAnalytic[f, x, Complexes]An analytic function can have only finitely many zeros in a closed and bounded region:
SolveValues[f == 0 && Abs[x] ≤ 1, x]ComplexPlot[f, {x, -1 - I, 1 + I}, RegionFunction -> (Abs[#] ≤ 1&), Epilog -> {PointSize[Medium], Blue, Point[ReIm[%]]}]SolveValues finds an explicit function of 
satisfying the equation 
:
g = y ^ 3 - x y ^ 2 + 2x ^ 2y - x + 1;y1 = SolveValues[g == 0, y][[1]]Use ImplicitD to find the derivative of an implicitly defined function:
(ImplicitD[g == 0, y, x] /. y -> y1) == D[y1, x]//SimplifyPossible Issues (9)
SolveValues gives generic solutions; solutions involving equations on parameters are not given:
SolveValues[a x ^ 2 + x == 1, x]Reduce gives all solutions, including those that require equations on parameters:
Reduce[a x ^ 2 + x == 1, x]With MaxExtraConditions->All, SolveValues also gives non-generic solutions:
SolveValues[a x ^ 2 + x == 1, x, MaxExtraConditions -> All]SolveValues results do not depend on whether some of the input equations contain only parameters. The following two systems are equivalent and have no generic solutions:
SolveValues[x == 1 && a == 2, x]SolveValues[x == 1 && x + a == x + 2, x]Use MaxExtraConditions to specify the number of parameter conditions allowed:
SolveValues[x == 1 && a == 2, x, MaxExtraConditions -> 1]SolveValues[x == 1 && x + a == x + 2, x, MaxExtraConditions -> 1]Use the Exists quantifier to find solutions that are valid for some value of parameter 
:
SolveValues[Exists[a, x == 1 && a == 2], x]SolveValues[Exists[a, x == 1 && x + a == x + 2], x]SolveValues does not eliminate solutions that are neither generically correct nor generically incorrect:
SolveValues[Sqrt[((1 - z) / (1 + z)) ^ 2] == (1 - a) / (1 + a), z]The solutions are correct for 
and incorrect for 
:
Sqrt[((1 - z) / (1 + z)) ^ 2] - (1 - a) / (1 + a) /. z -> #& /@ %% /. {{a -> (2 + 3I) / 4}, {a -> 2 + 3I}}For transcendental equations, SolveValues may not give all solutions:
SolveValues[x + E ^ x == 1 / 2, x]
Use Reduce to get all solutions:
Reduce[x + E ^ x == 1 / 2, x]SolveValues with Method->"Reduce" uses Reduce to find solutions, but returns solution values:
SolveValues[x + E ^ x == 1 / 2, x, Method -> "Reduce"]Using inverse functions allows SolveValues to find some solutions fast:
SolveValues[x ^ n == 1, x]//Timing
Finding the complete solution may take much longer, and the solution may be large:
(red = Reduce[x ^ n == 1, x])//LeafCount//TimingThis finds the values of n for which x==2 is a solution:
Reduce[red /. x -> 2, n]Simplify[x ^ n /. {x -> 2, n -> 2I Pi C[1] / Log[2]}, Element[C[1], Integers]]Interpretation of assumptions depends on their syntactic properties. Here the solution is generic in the parameter space restricted by the assumptions:
SolveValues[x == a && x == b, x, Assumptions -> a == b]This mathematically equivalent assumption contains the solve variable, and hence is treated as a part of the system to solve:
SolveValues[x == a && x == b, x, Assumptions -> a + x == b + x]There are no generic solutions, because the input is interpreted as:
SolveValues[x == a && x == b && a + x == b + x, x]The solution is non-generic, since it requires the parameters to satisfy an equation:
SolveValues[x == a && x == b && a + x == b + x, x, MaxExtraConditions -> All]When parameters are restricted to a discrete set, the notion of genericity is not well defined, and all solutions are returned:
SolveValues[a x ^ 2 + b x == 1, x, Assumptions -> Element[a | b, Integers]]Removable singularities of input equations are generally not considered valid solutions:
SolveValues[(x ^ 2 - 2Sqrt[2]x + 2) / (x - Sqrt[2]) == 0, x]Limit[(x ^ 2 - 2Sqrt[2]x + 2) / (x - Sqrt[2]), x -> Sqrt[2]]However, solutions may include removable singularities that are cancelled by automatic simplification:
SolveValues[x ^ 2 / x == 0, x]The removable singularity at 
is cancelled by evaluation:
x ^ 2 / x == 0Here the removable singularity at 
is cancelled by Together, which is used to preprocess the equation:
SolveValues[(x ^ 2 - 2x + 1) / (x - 1) == 0, x]Together[(x ^ 2 - 2x + 1) / (x - 1) == 0]The value of MaxRoots is used only for systems with numeric coefficients:
SolveValues[x ^ 4 == y, {x, y}, MaxRoots -> 3]When symbolic parameters are present, the option value is ignored:
SolveValues[x ^ 4 == y, {x}, MaxRoots -> 3]
Expressions given as variables are treated as atomic objects and not as functions of their subexpressions:
SolveValues[x + Sin[x] == 1, Sin[x]]Effectively, variables are replaced with new symbols before the equations are solved:
SolveValues[f[x] + Integrate[f[x], {x, 0, 1}] == 2x, f[x]]f[x] + Integrate[f[x], {x, 0, 1}] == 2x /. f[x] -> zText
Wolfram Research (2021), SolveValues, Wolfram Language function, https://reference.wolfram.com/language/ref/SolveValues.html (updated 2024).
CMS
Wolfram Language. 2021. "SolveValues." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/SolveValues.html.
APA
Wolfram Language. (2021). SolveValues. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SolveValues.html