Visitar URL original
VarianceGammaDistribution—Wolfram Documentation

WOLFRAM

Wolfram Language & System Documentation Center

VarianceGammaDistribution[λ,α,β,μ]

represents a variance‐gamma distribution with location parameter μ, skewness parameter β, and shape parameters λ and α.

Details
Details and Options Details and Options
Background & Context
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

VarianceGammaDistribution

VarianceGammaDistribution[λ,α,β,μ]

represents a variance‐gamma distribution with location parameter μ, skewness parameter β, and shape parameters λ and α.

Details

  • The probability density for value in a variance‐gamma distribution is proportional to TemplateBox[{{x, -, mu}}, Abs]^(lambda-1/2) exp(beta (x-mu)) TemplateBox[{{lambda, -, {1, /, 2}}, {alpha, , TemplateBox[{{x, -, mu}}, Abs]}}, BesselK].
  • VarianceGammaDistribution allows α and λ to be any positive real numbers, μ any real number, and β a real number such that -α<β<α.
  • VarianceGammaDistribution allows α and β to be any quantities of the same unit dimensions, and μ and λ to be quantities such that α*μ, and λ are dimensionless. »
  • VarianceGammaDistribution can be used with such functions as Mean, CDF, and RandomVariate.

Background & Context

  • VarianceGammaDistribution[λ,α,β,μ] represents a continuous statistical distribution defined and supported on the set of real numbers and parametrized by positive real numbers α and λ (called "shape parameters") and by real numbers μ and β (called a "location parameter" and a "skewness parameter", respectively), , which together determine the overall behavior of its probability density function (PDF). In general, the PDF of a variance-gamma distribution is unimodal with a single "peak" (i.e. a global maximum) at , though its overall shape (its height, its spread, and the horizontal location of its maximum) is determined by the values of λ, α, β, and μ. In addition, the tails of the PDF are "fat", in the sense that the PDF decreases algebraically rather than decreasing exponentially for large values of . (This behavior can be made quantitatively precise by analyzing the SurvivalFunction of the distribution.) The variance-gamma distribution is sometimes referred to as the generalized Laplace distribution and as the Bessel function distribution.
  • The variance-gamma distribution was established in a 1990 paper by Madan and Seneta as a model for stock market returns. Obtained from a normal distribution (NormalDistribution) by mixing on the variance parameter, the variance-gamma distribution satisfies a number of desirable probabilistic properties that make it desirable both for financial applications (as was shown by its founders) and for modeling phenomena outside of finance. In statistics, the variance-gamma distribution is the foundation for the so-called variance-gamma stochastic process, while it has also been used to model various phenomena, including wind turbulence, mortality, and image segmentation.
  • RandomVariate can be used to give one or more machine- or arbitrary-precision (the latter via the WorkingPrecision option) pseudorandom variates from a variance-gamma distribution. Distributed[x,VarianceGammaDistribution[λ,α,β,μ]], written more concisely as xVarianceGammaDistribution[λ,α,β,μ], can be used to assert that a random variable x is distributed according to a variance-gamma distribution. Such an assertion can then be used in functions such as Probability, NProbability, Expectation, and NExpectation.
  • The probability density and cumulative distribution functions for variance-gamma distributions may be given using PDF[VarianceGammaDistribution[λ,α,β,μ],x] and CDF[VarianceGammaDistribution[λ,α,β,μ],x]. The mean, median, variance, raw moments, and central moments may be computed using Mean, Median, Variance, Moment, and CentralMoment, respectively.
  • DistributionFitTest can be used to test if a given dataset is consistent with a variance-gamma distribution, EstimatedDistribution to estimate a parametric variance-gamma distribution from given data, and FindDistributionParameters to fit data to a variance-gamma distribution. ProbabilityPlot can be used to generate a plot of the CDF of given data against the CDF of a symbolic variance-gamma, and QuantilePlot to generate a plot of the quantiles of given data against the quantiles of a symbolic variance-gamma distribution.
  • TransformedDistribution can be used to represent a transformed variance-gamma distribution, CensoredDistribution to represent the distribution of values censored between upper and lower values, and TruncatedDistribution to represent the distribution of values truncated between upper and lower values. CopulaDistribution can be used to build higher-dimensional distributions that contain a variance-gamma distribution, and ProductDistribution can be used to compute a joint distribution with independent component distributions involving variance-gamma distributions.
  • VarianceGammaDistribution is related to a number of other distributions. VarianceGammaDistribution generalizes LaplaceDistribution in the sense that the PDF of VarianceGammaDistribution[1,α,0,μ] is precisely the same as that of LaplaceDistribution[μ,1/α] for . VarianceGammaDistribution can be realized as transformations (TransformedDistribution) of ExponentialDistribution, GammaDistribution, and NormalDistribution and is closely related to HyperbolicDistribution, LogNormalDistribution, BetaDistribution, and PearsonDistribution.

Examples

open all close all

Basic Examples  (4)

Probability density function:

Wolfram Language code: Plot[Table[PDF[VarianceGammaDistribution[λ, .8, .3, 0], x], {λ, {.5, 1, 2}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[VarianceGammaDistribution[1.2, α, .3, 0], x], {α, {.5, 1, 2}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[VarianceGammaDistribution[1.2, .8, β, 0], x], {β, {-.6, 0, .4}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: PDF[VarianceGammaDistribution[λ, α, β, μ], x]

Cumulative distribution function:

Wolfram Language code: Plot[Table[CDF[VarianceGammaDistribution[λ, .8, .3, 0], x], {λ, {.5, 1, 2}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[VarianceGammaDistribution[1.2, α, .3, 0], x], {α, {.5, 1, 2}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[VarianceGammaDistribution[1.2, .8, β, 0], x], {β, {-.6, 0, .4}}]//Evaluate, {x, -2, 2}, Filling -> Axis]

Mean and variance:

Wolfram Language code: Mean[VarianceGammaDistribution[λ, α, β, μ]]
Wolfram Language code: Variance[VarianceGammaDistribution[λ, α, β, μ]]

Median is available numerically:

Wolfram Language code: Median[VarianceGammaDistribution[3, 2, 1, 2]]//N

Scope  (8)

Generate a sample of pseudorandom numbers from a variance-gamma distribution:

Wolfram Language code: 𝒹 = VarianceGammaDistribution[1.2, .8, -0.3, 0]
Wolfram Language code: data = RandomVariate[𝒹, 10 ^ 4];

Compare its histogram to the PDF:

Wolfram Language code: Show[ Histogram[data, {-10, 5, .5}, "PDF"], Plot[PDF[𝒹, x], {x, -10, 5}, PlotStyle -> Thick]]

Distribution parameters estimation:

Wolfram Language code: sample = RandomVariate[VarianceGammaDistribution[1.4, 1.3, .3, 0.3], 10 ^ 4];

Estimate the distribution parameters from sample data:

Wolfram Language code: edist = EstimatedDistribution[sample, VarianceGammaDistribution[λ, α, β, μ], ParameterEstimator -> "MethodOfMoments"]

Compare a density histogram of the sample with the PDF of the estimated distribution:

Wolfram Language code: Show[Histogram[sample, {-2, 4, .2}, "PDF"], Plot[PDF[edist, x], {x, -2, 4}, PlotStyle -> Thick]]

Skewness:

Wolfram Language code: Plot3D[Skewness[VarianceGammaDistribution[λ, α, -.1, 0]], {λ, 0.1, 2}, {α, .3, 2}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-2, 1, 0.5}]
Wolfram Language code: Skewness[VarianceGammaDistribution[λ, α, β, μ]]

Kurtosis:

Wolfram Language code: Plot3D[Kurtosis[VarianceGammaDistribution[1.2, α, β, 0]], {α, 0.1, 2}, {β, -α, α}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {2, 0.4, 0.5}]
Wolfram Language code: Kurtosis[VarianceGammaDistribution[λ, α, β, μ]]

Limiting value:

Wolfram Language code: Limit[Kurtosis[VarianceGammaDistribution[λ, α, β, μ]], λ -> ∞]

Different moments with closed forms as functions of parameters:

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[VarianceGammaDistribution[λ, α, β, μ], k]//Simplify, {k, 3}], M]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[VarianceGammaDistribution[λ, α, β, μ], k], {k, 3}]//Simplify, CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[VarianceGammaDistribution[λ, α, β, μ], k]//Simplify, {k, 3}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[VarianceGammaDistribution[λ, α, β, μ], k], {k, 3}], C]

Closed form for symbolic order:

Wolfram Language code: Cumulant[VarianceGammaDistribution[λ, α, β, μ], r]

Hazard function:

Wolfram Language code: Plot[Table[HazardFunction[VarianceGammaDistribution[λ, .8, .3, 0], x], {λ, {.5, 1, 2}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[VarianceGammaDistribution[1.2, α, .3, 0], x], {α, {.5, 1, 2}}]//Evaluate, {x, -2, 2}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[VarianceGammaDistribution[1.2, .8, β, 0], x], {β, {-.6, 0, .4}}]//Evaluate, {x, -2, 2}, Filling -> Axis]

Quantile function:

Wolfram Language code: Plot[Table[Quantile[VarianceGammaDistribution[λ, .8, .3, 0], q], {λ, {.5, 1, 2}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Consistent use of Quantity in parameters yields QuantityDistribution:

Wolfram Language code: returnAmount𝒟 = VarianceGammaDistribution[0.83, Quantity[47.12, 1/"USDollars"], Quantity[1.03, 1/"USDollars"], Quantity[0.11, "USDollars"]]

Find the spread of the return:

Wolfram Language code: StandardDeviation[returnAmount𝒟]

Applications  (1)

Variance gamma distribution can be used to model returns of financial instruments:

Wolfram Language code: data = FinancialData["AAPL", "Return", {{2001, 1, 1}, {2011, 1, 1}}, "Value"];
Wolfram Language code: Length[data]

Fit the distribution to the data:

Wolfram Language code: edist = EstimatedDistribution[data, VarianceGammaDistribution[λ, α, β, μ], ParameterEstimator -> "MethodOfMoments"]

Compare the histogram to the PDF:

Wolfram Language code: Show[Histogram[data, 30, "PDF"], Plot[PDF[edist, x], {x, -.1, .15}, PlotStyle -> Thick, PlotRange -> All]]

Find the average return for this period of time:

Wolfram Language code: Mean[edist]

Find the median return:

Wolfram Language code: Median[edist]

Simulate returns for the next 100 trading days:

Wolfram Language code: ListLinePlot[RandomVariate[edist, 100]]

Properties & Relations  (8)

For same second and third parameters, variance-gamma distribution is closed under addition:

Wolfram Language code: TransformedDistribution[u + v, {uVarianceGammaDistribution[Subscript[λ, 1], α, β, Subscript[μ, 1]], vVarianceGammaDistribution[Subscript[λ, 2], α, β, Subscript[μ, 2]]}]

Variance-gamma distribution is closed under translation and scaling by a positive factor:

Wolfram Language code: TransformedDistribution[k u + loc, uVarianceGammaDistribution[λ, α, β, μ]]

Relationships to other distributions:

Difference of ExponentialDistribution follows variance-gamma distribution:

Wolfram Language code: TransformedDistribution[u - v, {uExponentialDistribution[ Subscript[λ, 1]], vExponentialDistribution[Subscript[λ, 2]]}]

Difference of two variables with GammaDistribution follows variance-gamma distribution:

Wolfram Language code: TransformedDistribution[u - v, {uGammaDistribution[α, Subscript[β, 1]], vGammaDistribution[α, Subscript[β, 2]]}]

LaplaceDistribution is a special case of variance-gamma distribution:

Wolfram Language code: PDF[VarianceGammaDistribution[1, α, 0, μ], x]//Simplify[#, α > 0]&
Wolfram Language code: PDF[LaplaceDistribution[μ, 1 / α], x]
Wolfram Language code: FullSimplify[% - %%]

Variance-gamma distribution is related to GammaDistribution and NormalDistribution:

Wolfram Language code: dist = TransformedDistribution[μ + β * v + Sqrt[v] * u, {uNormalDistribution[0, 1], vGammaDistribution[λ, 2 / (α - β) / (α + β)]}];
Wolfram Language code: MomentGeneratingFunction[dist, x]

Rewrite to simplify:

Wolfram Language code: E^x μ(1 / (1 + (2 x β/-α^2 + β^2)) / (1 + (x^2/-α^2 + β (2 x + β))))^λ//Simplify
Wolfram Language code: MomentGeneratingFunction[VarianceGammaDistribution[λ, α, β, μ], x]//Simplify
Wolfram Language code: %% / %//FullSimplify[#, λ > 0 && β > 0]&

The variance-gamma distribution admits parameter mixture representation:

Wolfram Language code: varΓdist = ParameterMixtureDistribution[NormalDistribution[μ + β u, Sqrt[u]], uGammaDistribution[λ, 2 / (α^2 - β^2)], Assumptions -> λ > 0 && α > 0 && -α < β < α && μ∈Reals];
Wolfram Language code: pdf = PDF[varΓdist, x]

Check that densities are generically equal:

Wolfram Language code: FullSimplify[PDF[VarianceGammaDistribution[λ, α, β, μ], x] == pdf, x > μ && DistributionParameterAssumptions[varΓdist]]

Neat Examples  (1)

PDFs for different λ values with CDF contours:

Wolfram Language code: dist = VarianceGammaDistribution[λ, .7, .3, 0];cdf = Function[{x, λ}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, -4, 4}, {λ, 1 / 10, 1 / 5}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2012), VarianceGammaDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/VarianceGammaDistribution.html (updated 2016).

Text

Wolfram Research (2012), VarianceGammaDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/VarianceGammaDistribution.html (updated 2016).

CMS

Wolfram Language. 2012. "VarianceGammaDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/VarianceGammaDistribution.html.

APA

Wolfram Language. (2012). VarianceGammaDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VarianceGammaDistribution.html

BibTeX

@misc{reference.wolfram_2026_variancegammadistribution, author="Wolfram Research", title="{VarianceGammaDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/VarianceGammaDistribution.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_variancegammadistribution, organization={Wolfram Research}, title={VarianceGammaDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/VarianceGammaDistribution.html}, note=[Accessed: 14-November-2026]}