StreamDensityPlot
StreamDensityPlot[{{vx,vy},r},{x,xmin,xmax},{y,ymin,ymax}]
generates a stream plot of the vector field {vx,vy} as a function of x and y, superimposed on a background density plot of the scalar field r.
StreamDensityPlot[{vx,vy},{x,xmin,xmax},{y,ymin,ymax}]
takes the scalar field to be the norm of the vector field.
StreamDensityPlot[{{vx,vy},{wx,wy},…,r},{x,xmin,xmax},{y,ymin,ymax}]
generates plots of several vector fields.
StreamDensityPlot[…,{x,y}∈reg]
takes the variables {x,y} to be in the geometric region reg.
Details and Options
- StreamDensityPlot plots streamlines that show the local direction of the vector field at every point.
- StreamDensityPlot generates a stream plot of the vector field {vx,vy}, superimposed on a background density plot of the scalar field r.
- StreamDensityPlot plots streamlines
defined by 
and 
where 
is an interpolated function of the vector data and 
is an initial stream point. The streamline 
is the curve passing through point 
, and whose tangents correspond to the vector field 
at each point. - The streamlines are drawn over a density plot of the scalar field
, whose default value is the magnitude 
of the vector field. - The streamlines are colored by default according to the magnitude
of the vector field 
and have an arrow in the direction of increasing value of 
. - StreamDensityPlot by default shows enough streamlines to achieve a roughly uniform density throughout the plot.
- StreamDensityPlot does not show streamlines at any positions for which the vi etc. do not evaluate to real numbers.
- StreamDensityPlot treats the variables x and y as local, effectively using Block.
- StreamDensityPlot has attribute HoldAll, and evaluates the vi etc. only after assigning specific numerical values to x and y.
- In some cases it may be more efficient to use Evaluate to evaluate the vi etc. symbolically before specific numerical values are assigned to x and y.
- StreamDensityPlot has the same options as Graphics, with the following additions and changes: [List of all options]
-
AspectRatio 1 ratio of height to width BoundaryStyle None how to draw RegionFunction boundaries BoxRatios Automatic effective 3D box ratios for simulated lighting ColorFunction Automatic how to color background densities ColorFunctionScaling True whether to scale arguments to ColorFunction EvaluationMonitor None expression to evaluate at every function evaluation Frame True whether to draw a frame around the plot FrameTicks Automatic frame tick marks LightingAngle None effective angle for simulated lighting MaxRecursion Automatic the maximum number of recursive subdivisions allowed for the scalar field Mesh None how many mesh lines to draw in the background MeshFunctions {#5&} how to determine the placement of mesh lines MeshShading None how to shade regions between mesh lines MeshStyle Automatic the style of mesh lines Method Automatic methods to use for the plot PerformanceGoal $PerformanceGoal aspects of performance to try to optimize PlotLegends None legends to include PlotRange {Full,Full} range of x, y values to include PlotRangePadding Automatic how much to pad the range of values PlotTheme $PlotTheme overall theme for the plot RegionFunction True& determine what region to include ScalingFunctions None how to scale individual coordinates StreamColorFunction Automatic how to color streamlines StreamColorFunctionScaling True whether to scale the argument to StreamColorFunction StreamMarkers Automatic shape to use for streams StreamPoints Automatic determine number, placement, and closeness of streamlines StreamScale Automatic determine sizes and segmenting of individual streamlines StreamStyle Automatic how to draw streamlines WorkingPrecision MachinePrecision precision to use in internal computations - The arguments supplied to functions in MeshFunctions, RegionFunction, ColorFunction, and StreamColorFunction are x, y, vx, vy, r.
- The default setting MeshFunctions->{#5&} draws mesh lines for the scalar field r.
- Possible settings for ScalingFunctions are:
-
{sx,sy} scale x and y axes - Common built-in scaling functions s include:
-
"Log" 
log scale with automatic tick labeling "Log10" 
base-10 log scale with powers of 10 for ticks "SignedLog" 
log-like scale that includes 0 and negative numbers "Reverse" 
reverse the coordinate direction "Infinite" 
infinite scale
List of all options
Examples
open all close allBasic Examples (4)
Plot the streamlines for a vector field with background based on field magnitude:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Add a legend for the scalar field:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]Plot the streamlines for a vector field with background based on a logarithm of field magnitude:
StreamDensityPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, Log[Norm[{-1 - x ^ 2 + y, 1 + x - y ^ 2}] + 1]}, {x, -3, 3}, {y, -3, 3}]Plot the streamlines for two fields with a background based on the first field's magnitude:
StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}]Scope (24)
Sampling (11)
Visualize streamlines for a vector field with the background based on 
:
StreamDensityPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, Cos[x]}, {x, -3, 3}, {y, -3, 3}]Plot streamlines for two vector fields with background color based on the first field's magnitude:
StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}]Use Evaluate to evaluate the vector field symbolically before numeric assignment:
StreamDensityPlot[Evaluate[D[Sin[x y], {{x, y}}]], {x, 0, 1}, {y, 0, 1}]Plot a vector field with streamlines placed with specified densities:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> None, PlotLabel -> p, StreamPoints -> p], {p, {Coarse, Medium, Automatic, Fine}}]Plot the streamlines that go through a set of seed points:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> Tuples[{-2, 0, 2}, 2], Epilog -> Point[Tuples[{-2, 0, 2}, 2]]]Use both automatic and explicit seeding with styles for explicitly seeded streamlines:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamPoints -> {{{{1, 0}, Red}, {{-1, -1}, Green}, Automatic}}]Plot streamlines over a specified region:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, x y < 0]]Use a specific number of mesh lines:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5]StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{2, 4, 5}}]The domain may be specified by a region:
StreamDensityPlot[{{y, -x}, x + y}, {x, y}∈Disk[]]The domain may be specified by a MeshRegion:
𝒟 = MeshRegion[{{0, 0}, {5, -2}, {3, 0}, {5, 2}}, Polygon[{1, 2, 3, 4}]];StreamDensityPlot[{{Sin[x], Cos[y]}, x^2 + y^2}, {x, y}∈𝒟]Presentation (13)
Specify different dashings and arrowheads by settings to StreamScale:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> ToString@s, StreamScale -> s], {s, {Automatic, None, 0.2, Full}}]Color the background scalar field with a color function:
v = {-1 - x ^ 2 + y, 1 + x - y ^ 2};
s = Exp[Norm[v] / 10];Table[StreamDensityPlot[f, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"], {f, {v, {v, s}}}]Change the color function for the streamlines to reflect the field magnitude:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Hue]Apply a variety of streamline styles:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> s], {s, {"Toothpick", "Dart", Dashed, Arrowheads[{{0.03, Automatic, Graphics[Circle[]]}}]}}]Use different themes for the plot:
{StreamDensityPlot[{x, y}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Detailed"], StreamDensityPlot[{x, y}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Monochrome"]}Use a named appearance to draw the streamlines:
StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop"]Style the streamlines as well:
StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop", StreamStyle -> Blue, StreamColorFunction -> None]Specify mesh lines with different styles:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{{2, Thick}, {4, Green}, {5, {Thick, Red, Dashed}}}}]Specify global mesh line styles:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshStyle -> s], {s, {Red, Thick, Directive[Red, Dashed]}}]Shade mesh regions cyclically:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, Yellow, Green, None}]Apply a variety of styles to region boundaries:
regionFn = Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2];Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn, BoundaryStyle -> b], {b, {Red, Thick, Directive[Red, Dashed]}}]Include a legend for the scalar field:
StreamDensityPlot[{x, y^2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]Include a legend for the streamlines:
StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, PlotLegends -> LineLegend[97, {"one", "two"}]]Reverse the y scale so it increases toward the bottom:
StreamDensityPlot[{x, y}, {x, 1, 100}, {y, 1, 100}, ScalingFunctions -> {None, "Reverse"}]Options (85)
Background (1)
BoundaryStyle (2)
By default, region boundaries have no style:
StreamDensityPlot[{Sin[x + y], Cos[y - x]}, {x, -3, 3}, {y, -3, 3}]Change the style of the boundary:
StreamDensityPlot[{Sin[x + y], Cos[y - x]}, {x, -3, 3}, {y, -3, 3}, BoundaryStyle -> Directive[Thick, Purple]]ColorFunction (6)
Color the field magnitude using Hue:
StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> Hue]Color using Hue based on 
:
StreamDensityPlot[{{y, -x}, Sin[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 2, ColorFunction -> Hue]Use any named color gradient from ColorData:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"]Use ColorData for predefined color gradients:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> Function[{x, y, vx, vy, n}, ColorData["SolarColors"][x y]]]Specify a color function that blends two colors by the 
coordinate:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> Function[{x, y, vx, vy, n}, Blend[{Green, Red}, x]]]Use ColorFunctionScaling->False to get unscaled values:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 4, ColorFunctionScaling -> False, ColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]ColorFunctionScaling (4)
By default, scaled values are used:
StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 2, ColorFunction -> GrayLevel]Use ColorFunctionScaling->False to get unscaled values:
StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 4, ColorFunctionScaling -> False, ColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]Use unscaled coordinates in the 
direction and scaled coordinates in the 
direction:
StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, ColorFunctionScaling -> {False, True}, ColorFunction -> Function[{x, y, vx, vy, n}, Hue[x, y, 1]]]Explicitly specify the scaling for each color function argument:
StreamDensityPlot[{y Cos[x y], x Cos[x y]}, {x, -3, 3}, {y, -3, 3}, MaxRecursion -> 3, ColorFunctionScaling -> {True, True, True, True, False}, ColorFunction -> Function[{x, y, vx, vy, n}, Hue[n, y, 1]]]EvaluationMonitor (2)
Show where the vector field function is sampled:
ListPlot[Reap[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, EvaluationMonitor :> Sow[{x, y}]]][[-1, 1]]]Count the number of times the vector field function is evaluated:
Block[{k = 0}, StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, EvaluationMonitor :> k++];k]MaxRecursion (1)
Mesh (5)
By default, no mesh lines are displayed:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> None]StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]Use a specific number of mesh lines:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5]StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{2, 4, 5}}]Use different styles for different mesh lines:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{{2, Thick}, {4, Yellow}, {5, {Thick, Red, Dashed}}}}]MeshFunctions (3)
By default, mesh lines correspond to the magnitude of the field:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, n], Mesh -> 5]Use the 
value as the mesh function:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, x], Mesh -> 5]Use mesh lines corresponding to fixed distances from the origin:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, Sqrt[x ^ 2 + y ^ 2]], Mesh -> 5]MeshShading (3)
Use None to remove regions:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, None}]StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, Yellow, Green, None}]Use indexed colors from ColorData cyclically:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> ColorData[51, "ColorList"]]MeshStyle (1)
NormalsFunction (2)
Do not use normals in shading:
StreamDensityPlot[{Cos[x ^ 2 + y], 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, LightingAngle -> Pi / 4, NormalsFunction -> None]Randomly vary the effective normals:
StreamDensityPlot[{Cos[x ^ 2 + y], 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, LightingAngle -> Pi / 4, NormalsFunction -> Function[{x, y, vx, vy, n}, RandomReal[{0, 1}, {3}]]]PerformanceGoal (2)
Generate a higher-quality plot:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PerformanceGoal -> "Quality"]Emphasize performance, possibly at the cost of quality:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PerformanceGoal -> "Speed"]PlotLegends (4)
No legends are included, by default:
StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}]Include a legend for the scalar field:
StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]Include a legend for the streamlines:
StreamDensityPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, PlotLegends -> {None, {"one", "two"}}]Control the placement of the legend:
StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Placed[Automatic, Below]]PlotRange (7)
The full plot range is used by default:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> Full]Specify an explicit limit for both 
and 
ranges:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> 2]
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{-1, 2}, Automatic}]Specify an explicit 
minimum range:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{0, Full}, Automatic}]
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {Full, {0, 2}}]Specify an explicit 
maximum range:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {Full, {Full, 5}}]
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{-2, 1.5}, {-1, 2}}]PlotTheme (2)
RegionFunction (3)
Plot streamlines only over certain quadrants:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, x y < 0]]Plot streamlines only over regions where the field magnitude is above a given threshold:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, n < 6]]Use any logical combination of conditions:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2]]StreamColorFunction (6)
Color streamlines according to the norm of the vector field:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Hue]Color streamlines according to a different scalar field:
StreamDensityPlot[{{Sin[x], Cos[y]}, x}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Hue]Use any named color gradient from ColorData:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> "Rainbow"]Use ColorData for predefined color gradients:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData["RedGreenSplit"][x y]]]Specify a color function that blends two colors by the 
coordinate:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Blend[{Green, Red}, x]]]Use StreamColorFunctionScaling->False to get unscaled values:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunctionScaling -> False, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]StreamColorFunctionScaling (4)
By default, scaled values are used:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> GrayLevel]Use StreamColorFunctionScaling->False to get unscaled values:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunctionScaling -> False, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]Use unscaled coordinates in the 
direction and scaled coordinates in the 
direction:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Hue[x, y, 1]], StreamColorFunctionScaling -> {False, True}]Explicitly specify the scaling for each color function argument:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Hue[n, y, 1]], StreamColorFunctionScaling -> {True, True, True, True, False}]StreamMarkers (7)
Streamlines are drawn as arrows by default:
StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}]Use a named appearance to draw the streamlines:
StreamDensityPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop"]Use different markers for different vector fields:
StreamDensityPlot[{{y, -x}, {x, y}}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> {"Drop", "Dart"}]Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.05}, StreamMarkers -> s], {s, {"Arrow", "ArrowArrow", "CircleArrow"}}]Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"BarDot", "Dot", "DotArrow", "DotDot"}}]Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"Drop", "BackwardPointer", "Pointer", "Toothpick"}}]Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"Dart", "PinDart", "DoubleDart"}}]StreamPoints (6)
Specify a maximum number of streamlines:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 10]Use symbolic names to specify the number of streamlines:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> p, PlotLabel -> p], {p, {Automatic, Coarse, Fine}}]Use both automatic and explicit seeding with styles for explicitly seeded streamlines:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamPoints -> {{{{1, 0}, Red}, {{-1, -1}, Green}, Automatic}}]Specify the minimum distance between streamlines:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> d, StreamPoints -> {Automatic, d}], {d, {Automatic, 1, Scaled[0.05]}}]Specify the minimum distance between streamlines at the start and end of a streamline:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> d, StreamPoints -> {Automatic, d}], {d, {Automatic, {Scaled[0.1], Scaled[0.5]}}}]Control the maximum length that each streamline can have:
points = Tuples[{-2, 0, 2}, 2]Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> {points, Automatic, maxlen}, Epilog -> Point[points]], {maxlen, {2.5, Scaled[0.5]}}]StreamScale (9)
Create full streamlines without segmentation:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, StreamScale -> Full]StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, StreamScale -> None]Use symbolic names to control the lengths of streamlines:
Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> s, StreamScale -> s], {s, {Tiny, Large}}]Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> s, StreamScale -> s], {s, {0.1, 0.2, 0.4}}]Specify an explicit dashing pattern for streamlines:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamScale -> {{0.1, 0.1}, Automatic}]Specify the number of points rendered on each streamline segment:
Table[StreamDensityPlot[{y, -x}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> n, StreamScale -> {Full, n}], {n, {12, 24, All}}]Specify absolute aspect ratios relative to the longest line segment:
Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, PlotLabel -> a, StreamScale -> {Automatic, Automatic, a}], {a, {.02, .04}}]Specify relative aspect ratios relative to each line segment:
Table[StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, PlotLabel -> a, StreamScale -> {Automatic, Automatic, a}], {a, {Scaled[0.5], Scaled[1], Scaled[1.5]}}]Scale the length of the arrows by the 
coordinate:
StreamDensityPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamScale -> {Automatic, 2, Automatic, Function[{x, y, vx, vy, n}, y]}]StreamStyle (5)
StreamColorFunction has precedence over colors in StreamStyle:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamStyle -> Black]Set StreamColorFunctionNone to specify colors with StreamStyle:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamStyle -> Black, StreamColorFunction -> None]Apply a variety of styles to the streamlines:
Table[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> s, StreamColorFunction -> None], {s, {Black, Thick, Directive[Black, Dashed]}}]StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> Arrowheads[{{0.03, Automatic, Graphics[Circle[]]}}]]Set the style for multiple vector fields:
StreamDensityPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {-(1 + x - y ^ 2), -1 - x ^ 2 + y}}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 30, StreamStyle -> {Red, Black}, StreamColorFunction -> None]Applications (16)
Visualize a vector field with the background based on the field's divergence:
f = {Sin[x] ^ 3, -Cos[y] ^ 2};
StreamDensityPlot[Evaluate@{f, Div[f, {x, y}]}, {x, -3, 3}, {y, -3, 3}]Visualize a vector field with the background based on the magnitude of the field's curl:
f = {Sin[y], -Sin[x] - y / 4};
StreamDensityPlot[Evaluate@{f, Norm[{0, 0, Curl[f, {x, y}]}]}, {x, -3, 3}, {y, -3, 3}]Show streamlines superimposed on the Hamiltonian for a 2D Hamiltonian system:
H[x_, y_] = y ^ 2 / 2 + x ^ 2( x ^ 2 - 2) / 4;
V[x_, y_] = Expand[-Curl[H[x, y], {x, y}]]StreamDensityPlot[{V[x, y], H[x, y]}, {x, -2, 2}, {y, -2, 2}]Check how closely NDSolve conserves the invariant:
sol = First[NDSolve[{x'[t] == y[t], y'[t] == x[t] - x[t] ^ 3, Thread[{x[0], y[0]} == RandomReal[{-2, 2}, {2}]]}, {x, y}, {t, 0, 10}, InterpolationOrder -> All]];
Plot[Evaluate[(H[x[t], y[t]] - H[x[0], y[0]]) /. sol], {t, 0, 10}]Characterize linear planar systems interactively:
Manipulate[Row[{Text["m"] == MatrixForm[m], StreamDensityPlot[Evaluate[m.{x, y}], {x, -1, 1}, {y, -1, 1}, StreamScale -> Large, StreamColorFunction -> "Rainbow"
]}], {{m, (| | |
| - | - |
| 1 | 0 |
| 0 | 2 |)}, {(| | |
| - | - |
| 1 | 0 |
| 0 | 2 |) -> "Nodal source", (| | |
| - | - |
| 1 | 1 |
| 0 | 1 |) -> "Degenerate source", (| | |
| -- | - |
| 0 | 1 |
| -1 | 1 |) -> "Spiral source", (| | |
| -- | -- |
| -1 | 0 |
| 0 | -2 |) -> "Nodal sink", (| | |
| -- | -- |
| -1 | 1 |
| 0 | -1 |) -> "Degenerate sink", (| | |
| -- | -- |
| 0 | 1 |
| -1 | -1 |) -> "Spiral sink", (| | |
| -- | - |
| 0 | 1 |
| -1 | 0 |) -> "Center", (| | |
| - | -- |
| 1 | 0 |
| 0 | -2 |) -> "Saddle"}}]Use a stream plot as a background for an interactive differential equation demo:
Manipulate[
splot = StreamDensityPlot[{y, -Sin[x] - .25 y}, {x, -4, 4}, {y, -3, 3}];
Dynamic[Show[splot,
ParametricPlot[Evaluate[First[{x[t], y[t]} /. NDSolve[{x'[t] == y[t], y'[t] == -Sin[x[t]] - .25y[t], Thread[{x[0], y[0]} == point]}, {x, y}, {t, 0, T}]]], {t, 0, T}, PlotStyle -> Red]]],
{{T, 10}, 1, 100}, {{point, {1, 0}}, Locator}]Combine several examples into a tabbed view:
fields = | | |
| ---------------------------- | --------------------------------------------------- |
| "positive invariant set" | {y, -x + y(1 - x ^ 2 - 2y ^ 2)} |
| "structurally stable system" | {2x + y - x(x ^ 2 + y ^ 2), -y - y(x ^ 2 + y ^ 2)} |
| "transcritical bifurcation" | {x ^ 2, -y} |
| "reaction-diffusion" | {2(y - x) + x(1 - x ^ 2), -2(y - x) + y(1 - y ^ 2)} |
| "Duffing's equation" | {y, x - x ^ 3} |;fieldIcon[f_] := Image[StreamDensityPlot[f, {x, -3, 3}, {y, -3, 3}, Axes -> False, Frame -> False, ColorFunction -> Hue, StreamPoints -> 20], ImageSize -> 40]Mouse over the tabs to get a description of the field:
TabView[Table[Tooltip[fieldIcon[f[[2]]], f[[1]]] -> StreamDensityPlot[f[[2]], {x, -3, 3}, {y, -3, 3}, StreamScale -> 0.2, ColorFunction -> Hue, PlotLabel -> TraditionalForm[Column@f[[2]]]], {f, fields}]]Quadratic system with two limit cycles:
p[x_, y_] := 169(x - 1) ^ 2 - 16(y - 1) ^ 2 - 153;
q[x_, y_] := 144(x - 1) ^ 2 - 9(y - 1) ^ 2 - 135;With[{λ = 0.8}, StreamDensityPlot[Evaluate@{p[x, y]Cos[λ] - q[x, y]Sin[λ], p[x, y]Sin[λ] + q[x, y]Cos[λ]}, {x, -1, 3}, {y, -1, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ}]]]Table[StreamDensityPlot[{2y, 2x - 3x ^ 2 + λ y(x ^ 2 - x ^ 2 + y ^ 2)}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> Row[{"λ = ", λ}]], {λ, {-1, 0, 1, 5}}]Unfolding a double zero eigenvalue with odd symmetry:
f1[x_, y_] := {y, λ1 x + λ2 y + x ^ 3 + x ^ 2 y};Grid@Table[StreamDensityPlot[Evaluate@f1[x, y], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, StreamStyle -> Black, StreamColorFunction -> None, PlotLabel -> Row[{"λ1 = ", λ1, " λ2 = ", λ2}]], {λ1, {-1, 0, 1}}, {λ2, {-1, 0, 1}}]Explore a parameterized vector field using Manipulate:
Manipulate[StreamDensityPlot[{y, λ + μ x - x ^ 3}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> {λ, μ}], {λ, -1, 1}, {μ, -1, 1}]Manipulate[StreamDensityPlot[{-x ^ 2 - λ x y ^ 2 + x, -y ^ 3 - λ x ^ 2 y + y}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ}]], {λ, -5, 5}]Unfolding a function and its gradient field:
Manipulate[StreamDensityPlot[Evaluate[-D[1 / 3(x ^ 3 + y ^ 3) - λ1 x y - λ2 x - λ3 y, {{x, y}}]], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> {λ1, λ2, λ3}], {λ1, -1, 1}, {λ2, -1, 1}, {λ3, -1, 1}]Generate a list of rasterized plots for animation:
labeledImage[g_, λ_] := Row[{Image[g, ImageSize -> 175], Row[{" λ = ", λ}]}]g = Table[labeledImage[StreamDensityPlot[{y, -1 + λ + Cos[x]}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large], λ], {λ, -5, 5, 5 / 16}];Animating a list of rasters instead of the original vector graphics may reduce memory usage:
ListAnimate[g]Create an animation that shifts the streamline colors in the direction of the vector norms:
frames = Table[Image[StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> 0.03, StreamColorFunction -> (Hue[k + #5]&)], ImageSize -> 175], {k, 0, 1, 0.1}];ListAnimate[frames]Explore various streamline styles and scales with several examples:
fields = {{x + y ^ 2 + y ^ 3, -x + y + y x ^ 2}, {x - x y ^ 2 + y ^ 3, 3y - y x ^ 2 + x ^ 3}, {(2 - x - 2y)x, (2 - 2x - y)y}, {y, (1 - x ^ 2 - y ^ 2)y / 20 - x}, {2 x y, 1 + x ^ 2 - y ^ 2}, {y, x - x ^ 2 + (1 + x)y}};styles = {"Arrow", "ArrowArrow", "CircleArrow", "BarDot", "Dot", "DotDot", "DotArrow", "Dart", "Drop", "BackwardPointer", "Pointer", "Toothpick", "Dart", "PinDart", "DoubleDart", "Segment", "Line"};Generate icons to graphically represent field choices:
icons = Table[f -> Image[StreamPlot[f, {x, -3, 3}, {y, -3, 3}, Axes -> False, Frame -> False, StreamPoints -> 20, StreamStyle -> "Line"], ImageSize -> 42], {f, fields}];Click the field icons to switch field plots:
Manipulate[StreamDensityPlot[field, {x, -3, 3}, {y, -3, 3}, StreamStyle -> style, StreamScale -> scale, ColorFunction -> color, ImageSize -> 300], {style, styles}, {{color, "SandyTerrain"}, ColorData["Gradients"]}, {{scale, 0.2}, 0.05, 0.5, 0.05}, {{field, icons[[1, 1]]}, icons, Setter}]Generate a list of stream plots of varying 
:
values = {-1, 0, 1};
plots = MapIndexed[Function[{λ, i}, StreamDensityPlot[{y, -1 + λ + Cos[x]}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 16, StreamScale -> 0.07, StreamStyle -> ColorData["DeepSeaColors"][0.3i[[1]]]]], values]make3D[GraphicsComplex[pts_, rr___], h_] := GraphicsComplex[PadRight[pts, {Length@pts, 3}, h], rr]make3D[Arrow[pts_, rr___], h_] := Arrow[PadRight[pts, {Length@pts, 3}, h], rr]stackPlots[plots2D : {__Graphics}, dh_, o : OptionsPattern[Graphics3D]] := Graphics3D[MapIndexed[Function[{g, index}, g[[1]] /. p : _GraphicsComplex | _Arrow :> make3D[p, dh index[[1]]]], plots2D], o]plotSpacing = 5;
stackPlots[plots, plotSpacing, Axes -> True, Boxed -> False, Ticks -> {Automatic, Automatic, MapIndexed[{plotSpacing#2[[1]], Row[{"λ = ", #1}]}&, values]}]Properties & Relations (12)
Use ListStreamDensityPlot for plotting data:
data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];ListStreamDensityPlot[data]Use StreamPlot for plotting only streamlines without a plot of the scalar field:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use VectorDensityPlot to plot functions with vectors instead of streamlines:
VectorDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use ListVectorDensityPlot to plot data with vectors instead of streamlines:
data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];ListVectorDensityPlot[data]Use VectorPlot to plot with vectors instead of streamlines without a plot of the scalar field:
VectorPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use VectorPlot3D to visualize 3D vector fields:
VectorPlot3D[{x, y, z}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]Use SliceVectorPlot3D to visualize 3D vector fields on a surface:
SliceVectorPlot3D[{-y, x, z}, Sphere[], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]StreamDensityPlot samples more points where it needs to:
StreamDensityPlot[{y, -x ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]Scalar fields can be plotted by themselves with DensityPlot:
f = {-1 - x ^ 2 + y, 1 + x - y ^ 2};
s = Exp[Norm[f] / 10];{DensityPlot[s, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"],
StreamDensityPlot[{f, s}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Pastel"]}Use LineIntegralConvolutionPlot to plot the line integral convolution of a vector field:
LineIntegralConvolutionPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Plot complex functions as a vector field:
ComplexVectorPlot[z + 1 / z, {z, 2}]GeoStreamPlot plots streamlines on a map of the Earth:
GeoStreamPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567},
{-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851},
{7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864},
{ ... 904, "AngularDegrees"]},
{0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]},
{0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]},
{0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]Properties & Relations (12)
Use VectorDensityPlot to plot with vectors instead of streamlines:
VectorDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use StreamPlot or VectorPlot for plotting functions without a density plot of the scalar field:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}],
VectorPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]}Use ListStreamDensityPlot to plot with data:
data = Table[{x^2 - y^2, x + y}, {x, -2, 2, 0.1}, {y, -2, 2, 0.1}];ListStreamDensityPlot[data]Use ListStreamPlot for plotting data without a density plot:
ListStreamPlot[data]Use ListVectorPlot to plot vectors instead of streamlines:
ListVectorPlot[data]Use ListVectorDensityPlot to add the density plot to the vectors:
ListVectorDensityPlot[data]Use VectorDisplacementPlot to visualize the deformation of a region associated with a displacement vector field:
VectorDisplacementPlot[{y, x - x^3}, {x, y}∈Disk[], VectorPoints -> Automatic]Use ListVectorDisplacementPlot to visualize the same deformation based on data:
data = Table[{{x, y} = RandomReal[{-1, 1}, {2}], {y, x - x ^ 3}}, {300}];ListVectorDisplacementPlot[data, Disk[], VectorPoints -> Automatic]Use VectorDisplacementPlot3D to visualize the deformation of a 3D region associated with a displacement vector field:
VectorDisplacementPlot3D[{y, x, -z}, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, VectorPoints -> "Boundary"]Use ListVectorDisplacementPlot3D to visualize the same deformation based on data:
data = Table[{{x, y, z} = RandomReal[{0, 1}, {3}], {y, x, -z}}, {300}];ListVectorDisplacementPlot3D[data, Cuboid[], VectorPoints -> "Boundary"]Use VectorPlot3D or StreamPlot3D to visualize a 3D vector field:
{VectorPlot3D[{z, -x, y}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}],
StreamPlot3D[{z, -x, y}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]}Use ListVectorPlot3D or ListStreamPlot3D to visualize the same 3D vector field based data:
data = Table[{z, -x, y}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}];{ListVectorPlot3D[data], ListStreamPlot3D[data]}Use SliceVectorPlot3D to visualize a 3D vector field data along a surface:
SliceVectorPlot3D[{x, y, z}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]Use ListSliceVectorPlot3D to visualize the same 3D vector field data based on data:
ListSliceVectorPlot3D[Table[{x, y, z}, {x, -1, 1, .1}, {y, -1, 1, .1}, {z, -1, 1, .1}]]StreamDensityPlot samples more points where it needs to:
StreamDensityPlot[{y, -x^2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]Scalar fields can be plotted by themselves with ListDensityPlot:
f = {-1 - x ^ 2 + y, 1 + x - y ^ 2};
s = Exp[Norm[f] / 10];data = Table[{f, s}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];
scalarData = Table[s, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];{ListDensityPlot[scalarData, ColorFunction -> "Pastel"],
ListStreamDensityPlot[data, ColorFunction -> "Pastel"]}Use ListLineIntegralConvolutionPlot to plot the line integral convolution of vector field data:
data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, .2}, {y, -3, 3, .2}];ListLineIntegralConvolutionPlot[data]Use ComplexVectorPlot or ComplexStreamPlot to visualize a complex function of a complex variable as a vector field or with streamlines:
{ComplexVectorPlot[Sin[3z], {z, 2}], ComplexStreamPlot[Sin[3z], {z, 2}]}Use GeoVectorPlot to plot vectors on a map:
GeoVectorPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567},
{-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851},
{7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864},
{ ... 904, "AngularDegrees"]},
{0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]},
{0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]},
{0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]Use GeoStreamPlot to plot streamlines instead of vectors:
GeoStreamPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567},
{-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851},
{7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864},
{ ... 904, "AngularDegrees"]},
{0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]},
{0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]},
{0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]Neat Examples (3)
Plot streamlines with the divergence as the background density:
vf = {Cos[x + y ^ 3], Sin[y + x ^ 3]};
StreamDensityPlot[Evaluate[{vf, Div[vf, {x, y}]}], {x, -3, 3}, {y, -3, 3}, StreamPoints -> Fine, StreamScale -> Large, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None]vf = { 1, Sin[x^3 + y^3]};StreamDensityPlot[Evaluate[{vf, Div[vf, {x, y}]}], {x, -3, 3}, {y, -3, 3}, StreamPoints -> Fine, StreamScale -> Large, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None]vf = {Sin[Cos[3 y] + Sin[3 x]], 3 Cos[Cos[3 y] + 3 x]};StreamDensityPlot[Evaluate[{vf, Div[vf, {x, y}]}], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None]Plot streamlines with the absolute value of the vorticity as the background density:
vf = {Cos[x + y ^ 3], Sin[y + x ^ 3]};
StreamDensityPlot[Evaluate[{vf, Abs[Curl[vf, {x, y}]]}], {x, -2, 2}, {y, -2, 2}, StreamPoints -> Fine, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamScale -> Large, StreamColorFunction -> None]vf = { 1, Sin[x^3 + y^3]};StreamDensityPlot[Evaluate[{vf, Abs[Curl[vf, {x, y}]]}], {x, -3, 3}, {y, -3, 3}, ColorFunction -> "Rainbow", MaxRecursion -> 3, StreamStyle -> Black, StreamColorFunction -> None, StreamPoints -> Fine]vf = {Sin[Cos[3 y] + Sin[3 x]], 3 Cos[Cos[3 y] + 3 x]};
StreamDensityPlot[Evaluate[{vf, Abs[Curl[vf, {x, y}]]}], {x, -3, 3}, {y, -3, 3}, StreamPoints -> Fine, ColorFunction -> "Rainbow", MaxRecursion -> 2, StreamStyle -> Black, StreamColorFunction -> None, StreamScale -> Large]Constrain the stream plot to a variety of regions:
StreamDensityPlot[{y, -x}, {x, -2, 2}, {y, -2, 2}, RegionFunction -> Function[{x, y}, 0.55 < x ^ 2 + y ^ 2 < 4.2], ColorFunction -> "RedBlueTones", Frame -> False, StreamScale -> Medium, BoundaryStyle -> {Cyan, Thick}]StreamDensityPlot[{Cos[x ^ 2 + y], 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, ColorFunction -> "BeachColors", StreamColorFunction -> "DeepSeaColors", StreamScale -> {Automatic, Automatic, Scaled[0.8]}, Frame -> False, RegionFunction -> Function[(#1 + 3) ≥ 0.45 #2 ^ 2], BoundaryStyle -> {Blue, Thick}]Text
Wolfram Research (2008), StreamDensityPlot, Wolfram Language function, https://reference.wolfram.com/language/ref/StreamDensityPlot.html (updated 2022).
CMS
Wolfram Language. 2008. "StreamDensityPlot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/StreamDensityPlot.html.
APA
Wolfram Language. (2008). StreamDensityPlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StreamDensityPlot.html