StreamPlot
StreamPlot[{vx,vy},{x,xmin,xmax},{y,ymin,ymax}]
generates a stream plot of the vector field {vx,vy} as a function of x and y.
StreamPlot[{{vx,vy},{wx,wy},…},{x,xmin,xmax},{y,ymin,ymax}]
generates plots of several vector fields.
StreamPlot[…,{x,y}∈reg]
takes the variables {x,y} to be in the geometric region reg.
Details and Options
- StreamPlot is known as a streamline plot.
- StreamPlot plots streamlines
defined by 
and 
, where 
and 
is an initial stream point. The streamline 
is the curve passing through point 
, and whose tangents correspond to the vector field 
at each point. - The streamlines are colored by default according to the magnitude
of the vector field 
and have an arrow in the direction of increasing value of 
. - StreamPlot by default shows enough streamlines to achieve a roughly uniform density throughout the plot, and shows no background scalar field.
- StreamPlot does not show streamlines at any positions for which the vi etc. do not evaluate to real numbers.
- StreamPlot treats the variables x and y as local, effectively using Block.
- StreamPlot has attribute HoldAll, and evaluates the vi etc. only after assigning specific numerical values to x and y.
- In some cases it may be more efficient to use Evaluate to evaluate the vi etc. symbolically before specific numerical values are assigned to x and y.
- StreamPlot has the same options as Graphics, with the following additions and changes: [List of all options]
-
AspectRatio 1 ratio of height to width EvaluationMonitor None expression to evaluate at every function evaluation Frame True whether to draw a frame around the plot FrameTicks Automatic frame tick marks Method Automatic methods to use for the plot PerformanceGoal $PerformanceGoal aspects of performance to try to optimize PlotLayout Automatic how to position fields PlotLegends None legends to include PlotRange {Full,Full} range of x, y values to include PlotRangePadding Automatic how much to pad the range of values PlotTheme $PlotTheme overall theme for the plot RegionBoundaryStyle Automatic how to style plot region boundaries RegionFillingStyle Automatic how to style plot region interiors RegionFunction (True&) determine what region to include ScalingFunctions None how to scale individual coordinates StreamColorFunction Automatic how to color streamlines StreamColorFunctionScaling True whether to scale the argument to StreamColorFunction StreamMarkers Automatic shape to use for streams StreamPoints Automatic determine number, placement, and closeness of streamlines StreamScale Automatic determine sizes and segmenting of individual streamlines StreamStyle Automatic how to draw streamlines WorkingPrecision MachinePrecision precision to use in internal computations - The arguments supplied to functions in RegionFunction and StreamColorFunction are x, y, vx, vy, Norm[{vx,vy}].
- Possible settings for PlotLayout that show single streamlines in multiple plot panels include:
-
"Column" use separate streamlines in a column of panels "Row" use separate streamlines in a row of panels {"Column",k},{"Row",k} use k columns or rows {"Column",UpTo[k]},{"Row",UpTo[k]} use at most k columns or rows - Possible settings for ScalingFunctions are:
-
{sx,sy} scale x and y axes - Common built-in scaling functions s include:
-
"Log" 
log scale with automatic tick labeling "Log10" 
base-10 log scale with powers of 10 for ticks "SignedLog" 
log-like scale that includes 0 and negative numbers "Reverse" 
reverse the coordinate direction "Infinite" 
infinite scale
List of all options
Examples
open all close allBasic Examples (4)
Plot the streamlines with arrows for the field 
:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Include a legend for the field magnitude:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]Visualize streamlines as unbroken lines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> None]Use a multi-panel layout to show multiple vector fields at the same time:
StreamPlot[{{x + y, y - x}, {y, x + y}}, {x, -3, 3}, {y, -3, 3}, PlotLayout -> "Row"]Scope (22)
Sampling (10)
Plot a vector field with streamlines placed with specified densities:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> p, StreamPoints -> p], {p, {Coarse, Medium, Automatic, Fine}}]Plot the streamlines that go through a set of seed points:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> Tuples[{-2, 0, 2}, 2], Epilog -> Point[Tuples[{-2, 0, 2}, 2]]]Use both automatic and explicit seeding with styles for explicitly seeded streamlines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamPoints -> {{{{1, 0}, Red}, {{-1, -1}, Green}, Automatic}}]Plot streamlines over a specified region:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, x y < 0]]StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None]Use a specific number of mesh lines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{2, 4, 5}}]Use Evaluate to evaluate the vector field symbolically before numeric assignment:
StreamPlot[Evaluate[D[Sin[x y], {{x, y}}]], {x, 0, 1}, {y, 0, 1}]The domain may be specified by a region:
StreamPlot[{y, -x}, {x, y}∈Disk[]]The domain may be specified by a MeshRegion:
𝒟 = MeshRegion[{{0, 0}, {5, -2}, {3, 0}, {5, 2}}, Polygon[{1, 2, 3, 4}]];StreamPlot[{Sin[x], Cos[y]}, {x, y}∈𝒟]Presentation (12)
Specify different dashings and arrowheads by setting to StreamScale:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> ToString@s, StreamScale -> s], {s, {Automatic, None, Full}}]Plot the streamlines with arrows colored according to the magnitude of the field:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Automatic]Apply a variety of streamline styles:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> s], {s, {"Toothpick", "Dart", Directive[Orange, Dashed], Arrowheads[{{0.03, Automatic, Graphics[Circle[]]}}]}}]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Scientific"]Override the style from the theme:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Scientific", StreamColorFunction -> None, StreamStyle -> StandardBlue]Use a named appearance to draw the streamlines:
StreamPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop"]Style the streamlines as well:
StreamPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop", StreamColorFunction -> None, StreamStyle -> Red]Specify mesh lines with different styles:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{{2, Thick}, {4, Green}, {5, {Thick, Red, Dashed}}}}]Specify global mesh line styles:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshStyle -> s], {s, {Red, Thick, Directive[Red, Dashed]}}]Shade mesh regions cyclically:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, Yellow, Green, None}]Apply a variety of styles to region boundaries:
regionFn = Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2];Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn, RegionBoundaryStyle -> b], {b, {Red, Thick, Directive[Red, Dashed]}}]Show multiple functions as densities in separate panels:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, PlotLayout -> "Row"]Use a column instead of a row:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, PlotLayout -> "Column"]Add a legend with placeholder text:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic, StreamColorFunction -> None]Use the vector fields as legend labels:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, PlotLegends -> "Expressions"]Use explicit labels for each vector field:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, PlotLegends -> {"radial", "angular"}]Use a log scale for the x axis:
StreamPlot[{x, y}, {x, 1, 100}, {y, 1, 10}, ScalingFunctions -> {"Log", None}]Reverse the y scale so it increases toward the bottom:
StreamPlot[{x, y}, {x, 1, 100}, {y, 1, 100}, ScalingFunctions -> {None, "Reverse"}]Options (97)
AspectRatio (3)
By default, StreamPlot uses the same width and height:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -2, 2}]Use numerical value to specify the height to width ratio:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -2, 2}, AspectRatio -> 1 / 2]AspectRatioAutomatic determines the ratio from the plot ranges:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -2, 2}, AspectRatio -> Automatic]Axes (4)
By default, StreamPlot uses a frame instead of axes:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True]Use AxesOrigin to specify where the axes intersect:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesOrigin -> {1, 1}]Turn each axis on individually:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> {True, False}], StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> {False, True}]}AxesLabel (3)
No axes labels are drawn by default:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True]
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesLabel -> y]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesLabel -> {x, y}]AxesOrigin (2)
The position of the axes is determined automatically:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True]Specify an explicit origin for the axes:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesOrigin -> {2, 2}]AxesStyle (4)
Change the style for the axes:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesStyle -> Red]Specify the style of each axis:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesStyle -> {Red, Blue}]Use different styles for the ticks and the axes:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesStyle -> Green, TicksStyle -> StandardGray]Use different styles for the labels and the axes:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, Frame -> False, Axes -> True, AxesStyle -> Green, LabelStyle -> Red]Background (1)
EvaluationMonitor (2)
Show where the vector field function is sampled:
ListPlot[Reap[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, EvaluationMonitor :> Sow[{x, y}]]][[-1, 1]]]Count the number of times the vector field function is evaluated:
Block[{k = 0}, StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, EvaluationMonitor :> k++];k]ImageSize (5)
Use named sizes such as Tiny, Small, Medium and Large:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> Tiny], StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> Small]}Specify the width of the plot:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> 150], StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, AspectRatio -> 1.5, ImageSize -> 150]}Specify the height of the plot:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> {Automatic, 150}], StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, AspectRatio -> 2, ImageSize -> {Automatic, 150}]}Allow the width and height to be up to a certain size:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> UpTo[200]], StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, AspectRatio -> 2, ImageSize -> UpTo[200]]}Specify the width and height for a graphic, padding with space if necessary:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> {300, 200}, Background -> StandardGray]Use maximum sizes for the width and height:
{StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, ImageSize -> {UpTo[150], UpTo[100]}], StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -2, 2}, {y, -3, 3}, AspectRatio -> 2, ImageSize -> {UpTo[150], UpTo[100]}]}Mesh (5)
By default, no mesh lines are displayed:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> None]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> All]Use a specific number of mesh lines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 5]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{2, 4, 5}}]Use different styles for different mesh lines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> {{{2, Thick}, {4, Green}, {5, {Thick, Red, Dashed}}}}]MeshFunctions (3)
By default, mesh lines correspond to the magnitude of the field:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, n], Mesh -> 5]Use the 
value as the mesh function:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, x], Mesh -> 5]Use mesh lines corresponding to fixed distances from the origin:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, MeshFunctions -> Function[{x, y, vx, vy, n}, Sqrt[x ^ 2 + y ^ 2]], Mesh -> 5]MeshShading (3)
Use None to remove regions:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, None}]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> {Red, Yellow, Green, None}]Use indexed colors from ColorData cyclically:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, Mesh -> 10, MeshShading -> ColorData[51, "ColorList"]]MeshStyle (1)
PerformanceGoal (2)
Generate a higher-quality plot:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PerformanceGoal -> "Quality"]Emphasize performance, possibly at the cost of quality:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PerformanceGoal -> "Speed"]PlotLayout (2)
Place each group of vectors in a separate panel using shared axes:
StreamPlot[{{y, -x}, {x, y}}, {x, -3, 3}, {y, -3, 3}, ImageSize -> Medium, PlotLayout -> "Column"]Use a row instead of a column:
StreamPlot[{{y, -x}, {x, y}}, {x, -3, 3}, {y, -3, 3}, ImageSize -> Medium, PlotLayout -> "Row"]StreamPlot[{{y, -x}, {x, y}, {y, x + y}, {x, x - y}}, {x, -3, 3}, {y, -3, 3}, ImageSize -> Medium, PlotLayout -> {"Column", 2}]StreamPlot[{{y, -x}, {x, y}, {y, x + y}, {x, x - y}, {x + y, x}, {y - x, x + y}}, {x, -3, 3}, {y, -3, 3}, ImageSize -> Medium, PlotLayout -> {"Column", UpTo[4]}]StreamPlot[{{y, -x}, {x, y}, {y, x + y}, {x, x - y}, {x + y, x}, {y - x, x + y}}, {x, -3, 3}, {y, -3, 3}, ImageSize -> Medium, PlotLayout -> {"Column", 4}]PlotLegends (6)
No legends are included by default:
StreamPlot[{y, Exp[-x]}, {x, -3, 3}, {y, -3, 3}]Include a legend to show the color range of field norms:
StreamPlot[{y, Exp[-x]}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic]Control the placement of the legend:
StreamPlot[{y, Exp[-x]}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Placed[Automatic, Below]]Include a legend for multiple fields:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> {"one", "two"}, StreamColorFunction -> None]Use the vector fields as the legend text:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> "Expressions", StreamColorFunction -> None]StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, PlotLegends -> Automatic, StreamColorFunction -> None]Change the appearance of the legend:
StreamPlot[{{x, y}, {y, -x}}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamStyle -> {Red, Blue}, PlotLegends -> SwatchLegend["Expressions", LegendMarkerSize -> {40, 10}]]PlotRange (5)
The full plot range is used by default:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> Full]Specify an explicit limit for both 
and 
ranges:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> 2]
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{0, Full}, Automatic}]
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {Full, {0, 2}}]
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotRange -> {{-2, 1.5}, {-1, 2}}]PlotTheme (2)
Use a theme with simpler ticks and brighter colors:
StreamPlot[{Cos[x], Sin[y]}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Web"]Use a theme with dense streamlines:
StreamPlot[{{Cos[x], Sin[y]}, {-Sin[y], Cos[x]}}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Detailed"]StreamPlot[{{Cos[x], Sin[y]}, {-Sin[y], Cos[x]}}, {x, -3, 3}, {y, -3, 3}, PlotTheme -> "Detailed", StreamStyle -> {Red, Blue}, StreamColorFunction -> None]RegionBoundaryStyle (2)
By default, region boundaries are styled:
regionFn = Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2];StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn]Show no boundaries and filling:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn, RegionBoundaryStyle -> None, RegionFillingStyle -> None]Apply a variety of styles to region boundaries:
regionFn = Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2];Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn, RegionBoundaryStyle -> b], {b, {Red, Thick, Directive[Red, Dashed]}}]RegionFillingStyle (1)
By default, region filling is styled:
regionFn = Function[{x, y, vx, vy, n}, 4 < n < 6 || 0 < n < 2];StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> regionFn, RegionFillingStyle -> None]RegionFunction (3)
Plot streamlines only over certain quadrants:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, x y < 0]]Plot streamlines only over regions where the field magnitude is above a given threshold:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, n < 6]]Use any logical combination of conditions:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, RegionFunction -> Function[{x, y, vx, vy, n}, 3 < n < 6 || 0 < n < 2]]ScalingFunctions (2)
StreamColorFunction (5)
By default, color streamlines according to the norm of the vector field:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use any named color gradient from ColorData:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> "Rainbow"]Use ColorData for predefined color gradients:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData["AvocadoColors"][x y]]]Specify a color function that blends two colors by the 
coordinate:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Blend[{Blue, Red}, x]]]Use StreamColorFunctionScaling->False to get unscaled values:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunctionScaling -> False, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]StreamColorFunctionScaling (4)
By default, scaled values are used:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Blend[{Blue, Red}, x]]]Use StreamColorFunctionScaling->False to get unscaled values:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunctionScaling -> False, StreamColorFunction -> Function[{x, y, vx, vy, n}, ColorData[22][Round[n]]]]Use unscaled coordinates in the 
direction and scaled coordinates in the 
direction:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Hue[x, y, 1]], StreamColorFunctionScaling -> {False, True}]Explicitly specify the scaling for each color function argument:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> Function[{x, y, vx, vy, n}, Hue[n, y, 1]], StreamColorFunctionScaling -> {True, True, True, True, False}]StreamMarkers (7)
Streamlines are drawn as arrows by default:
StreamPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}]Use a named appearance to draw the streamlines:
StreamPlot[{y, -x}, {x, -3, 3}, {y, -3, 3}, StreamMarkers -> "Drop"]Use different markers for different vector fields:
StreamPlot[{{y, -x}, {x, y}}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, StreamPoints -> Coarse, StreamMarkers -> {"Drop", "Dart"}]Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.05}, StreamMarkers -> s], {s, {"Arrow", "ArrowArrow", "CircleArrow"}}]Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"BarDot", "Dot", "DotArrow", "DotDot"}}]Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"Drop", "BackwardPointer", "Pointer", "Toothpick"}}]Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> s, StreamScale -> {Full, All, 0.03}, StreamMarkers -> s], {s, {"Dart", "PinDart", "DoubleDart"}}]StreamPoints (6)
Specify a specific maximum number of streamlines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 10]Use symbolic names to specify the number of streamlines:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> p, PlotLabel -> p], {p, {Automatic, Coarse, Fine}}]Use both automatic and explicit seeding with styles for explicitly seeded streamlines:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamColorFunction -> None, StreamPoints -> {{{{1, 0}, Red}, {{-1, -1}, Green}, Automatic}}]Specify the minimum distance between streamlines:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> d, StreamPoints -> {Automatic, d}], {d, {Automatic, 1, Scaled[0.05]}}]Specify the minimum distance between streamlines at the start and end of a streamline:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> d, StreamPoints -> {Automatic, d}], {d, {Automatic, {Scaled[0.1], Scaled[0.5]}}}]Control the maximum length that each streamline can have:
points = Tuples[{-2, 0, 2}, 2]Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> {points, Automatic, maxlen}, Epilog -> Point[points]], {maxlen, {2.5, Scaled[0.2]}}]StreamScale (9)
Create full streamlines without segmentation:
StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, StreamScale -> Full]StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, StreamScale -> None]Use symbolic names to control the lengths of streamlines:
Table[StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> s, StreamScale -> s], {s, {Tiny, Large}}]Table[StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> s, StreamScale -> s], {s, {0.1, 0.2, 0.4}}]Specify an explicit dashing pattern for streamlines:
StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamScale -> {{0.1, 0.1}, Automatic}]Specify the number of points rendered on each streamline segment:
Table[StreamPlot[{y, -x}, {x, -Pi, Pi}, {y, -Pi, Pi}, PlotLabel -> n, StreamScale -> {Full, n}], {n, {12, 24, All}}]Specify absolute aspect ratios relative to the longest line segment:
Table[StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, PlotLabel -> a, StreamScale -> {Automatic, Automatic, a}], {a, {.02, .04}}]Specify relative aspect ratios relative to each line segment:
Table[StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamPoints -> 10, PlotLabel -> a, StreamScale -> {Automatic, Automatic, a}], {a, {Scaled[0.5], Scaled[1], Scaled[1.5]}}]Scale the length of the arrows by the 
coordinate:
StreamPlot[{Sin[x], Cos[y]}, {x, -Pi, Pi}, {y, -Pi, Pi}, StreamScale -> {Automatic, 2, Automatic, Function[{x, y, vx, vy, n}, y]}]StreamStyle (5)
StreamColorFunction has precedence over colors specified in StreamStyle:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamStyle -> Orange]Set StreamColorFunctionNone to specify colors with StreamStyle:
StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamStyle -> Orange, StreamColorFunction -> None]Apply a variety of styles to the streamlines:
Table[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> s, StreamColorFunction -> None], {s, {Orange, Thick, Directive[Orange, Dashed]}}]StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Full, StreamStyle -> Arrowheads[{{0.03, Automatic, Graphics[Circle[]]}}]]Set the style for multiple vector fields:
StreamPlot[{{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {-(1 + x - y ^ 2), -1 - x ^ 2 + y}}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 30, StreamStyle -> {Red, Blue}, StreamColorFunction -> None]Applications (16)
Streamlines for the gradient field of 
over the unit square:
StreamPlot[Evaluate[D[Sin[x y], {{x, y}}]], {x, 0, 1}, {y, 0, 1}, StreamScale -> Large]Streamlines for the Hamiltonian vector field of 
:
StreamPlot[Evaluate@{D[Sin[x y], {y}], -D[Sin[x y], {x}]}, {x, 0, 2Pi}, {y, 0, 2Pi}, StreamScale -> Large]Global attractor of damped conservative system:
StreamPlot[{y, -y + x - x ^ 3}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large]Combine several examples into a tabbed view:
fields = | | |
| ---------------------------- | --------------------------------------------------- |
| "positive invariant set" | {y, -x + y(1 - x ^ 2 - 2y ^ 2)} |
| "structurally stable system" | {2x + y - x(x ^ 2 + y ^ 2), -y - y(x ^ 2 + y ^ 2)} |
| "transcritical bifurcation" | {x ^ 2, -y} |
| "reaction-diffusion" | {2(y - x) + x(1 - x ^ 2), -2(y - x) + y(1 - y ^ 2)} |
| "Duffing's equation" | {y, x - x ^ 3} |;fieldIcon[f_] := Image[StreamPlot[f, {x, -3, 3}, {y, -3, 3}, Axes -> False, Frame -> False, StreamPoints -> 20, StreamStyle -> Thick], ImageSize -> 40]Mouse over the tabs to get a description of the vector field:
TabView[Table[Tooltip[fieldIcon[f[[2]]], f[[1]]] -> StreamPlot[f[[2]], {x, -3, 3}, {y, -3, 3}, StreamScale -> 0.2, PlotLabel -> TraditionalForm[Column@f[[2]]]], {f, fields}]]Quadratic system with two limit cycles:
p[x_, y_] := 169(x - 1) ^ 2 - 16(y - 1) ^ 2 - 153;
q[x_, y_] := 144(x - 1) ^ 2 - 9(y - 1) ^ 2 - 135;With[{λ = 0.8}, StreamPlot[Evaluate@{p[x, y]Cos[λ] - q[x, y]Sin[λ], p[x, y]Sin[λ] + q[x, y]Cos[λ]}, {x, -1, 3}, {y, -1, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ}]]]Table[StreamPlot[{y, -x + λ(1 - x ^ 2)y}, {x, -3, 3}, {y, -3, 3}, PlotLabel -> Row[{"λ = ", λ}], StreamScale -> Large], {λ, {-1, 0, 1, 5}}]Characterize linear planar systems interactively:
Manipulate[Row[{Text["m"] == MatrixForm[m], StreamPlot[Evaluate[m.{x, y}], {x, -1, 1}, {y, -1, 1}, StreamScale -> Large, ImageSize -> Small]}], {{m, (| | |
| - | - |
| 1 | 0 |
| 0 | 2 |)}, {(| | |
| - | - |
| 1 | 0 |
| 0 | 2 |) -> "Nodal source", (| | |
| - | - |
| 1 | 1 |
| 0 | 1 |) -> "Degenerate source", (| | |
| -- | - |
| 0 | 1 |
| -1 | 1 |) -> "Spiral source", (| | |
| -- | -- |
| -1 | 0 |
| 0 | -2 |) -> "Nodal sink", (| | |
| -- | -- |
| -1 | 1 |
| 0 | -1 |) -> "Degenerate sink", (| | |
| -- | -- |
| 0 | 1 |
| -1 | -1 |) -> "Spiral sink", (| | |
| -- | - |
| 0 | 1 |
| -1 | 0 |) -> "Center", (| | |
| - | -- |
| 1 | 0 |
| 0 | -2 |) -> "Saddle"}}]Use a stream plot as a background for an interactive differential equation solution plotter:
Manipulate[
splot = StreamPlot[{y, -Sin[x] - .25 y}, {x, -4, 4}, {y, -3, 3}];
Dynamic[Show[splot,
ParametricPlot[Evaluate[First[{x[t], y[t]} /. NDSolve[{x'[t] == y[t], y'[t] == -Sin[x[t]] - .25y[t], Thread[{x[0], y[0]} == point]}, {x, y}, {t, 0, T}]]], {t, 0, T}, PlotStyle -> Red]]],
{{T, 10}, 1, 100}, {{point, {1, 0}}, Locator}]Unfolding a double zero eigenvalue:
f1[x_, y_] := {y, λ1 + λ2 x + y ^ 2 + x y};Grid@Table[StreamPlot[Evaluate@f1[x, y], {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ1 = ", λ1, " λ2 = ", λ2}]], {λ1, {-1, 0, 1}}, {λ2, {-1, 0, 1}}]Manipulate[StreamPlot[{y, (Cos[x] - λ)Sin[x]}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ}]], {λ, -5, 5}]Manipulate[StreamPlot[{y, -λ - μ x + x ^ 3}, {x, -3, 3}, {y, -3, 3}, StreamScale -> Large, PlotLabel -> Row[{"λ = ", λ, " , μ = ", μ}]], {λ, -1, 1}, {μ, -1, 1}]Generate a list of rasterized stream plots for animation:
labeledImage[g_, λ_] := Row[{Image[g, ImageSize -> 175], Row[{" λ = ", λ}]}]options = {StreamScale -> Large, StreamStyle -> "BackwardPointer"};g = Table[labeledImage[StreamPlot[{-(x Sin[λ] + y Cos[λ]) + (1 - x ^ 2 - y ^ 2) ^ 2(x Cos[λ] - y Sin[λ]), (x Cos[λ] - y Sin[λ]) + (1 - x ^ 2 - y ^ 2) ^ 2(x Sin[λ] + y Cos[λ])}, {x, -3, 3}, {y, -3, 3}, Evaluate@options], λ], {λ, 0, 2π, π / 16}];Animating a list of rasters instead of the original vector graphics may reduce memory usage:
ListAnimate[g]Create an animation that shifts the streamline colors in the direction of the vector norms:
frames = Table[Image[StreamPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamScale -> 0.06, StreamColorFunction -> (Hue[k + #5]&)], ImageSize -> 175], {k, 0, 1, 0.1}];ListAnimate[frames]Explore various streamline styles and scales with several examples:
fields = {{x + y ^ 2 + y ^ 3, -x + y + y x ^ 2}, {x - x y ^ 2 + y ^ 3, 3y - y x ^ 2 + x ^ 3}, {(2 - x - 2y)x, (2 - 2x - y)y}, {y, (1 - x ^ 2 - y ^ 2)y / 20 - x}, {2 x y, 1 + x ^ 2 - y ^ 2}, {y, x - x ^ 2 + (1 + x)y}};styles = {"Arrow", "ArrowArrow", "CircleArrow", "BarDot", "Dot", "DotDot", "DotArrow", "Dart", "Drop", "BackwardPointer", "Pointer", "Toothpick", "Dart", "PinDart", "DoubleDart", "Segment", "Line"};Generate icons to graphically represent field choices:
icons = Table[f -> Image[StreamPlot[f, {x, -3, 3}, {y, -3, 3}, Axes -> False, Frame -> False, StreamPoints -> 20, StreamStyle -> "Line"], ImageSize -> 42], {f, fields}];Click on the field icons to switch field plots:
Manipulate[StreamPlot[field, {x, -3, 3}, {y, -3, 3}, ImageSize -> 300, StreamStyle -> style, StreamScale -> scale, StreamColorFunction -> color], {style, styles}, {color, ColorData["Gradients"]}, {{scale, 0.2}, 0.05, 0.5, 0.05}, {{field, icons[[1, 1]]}, icons, Setter}]Generate a list of stream plots of varying 
:
values = {-1, 0, 1};plots = MapIndexed[Function[{λ, i}, StreamPlot[{y, λ - x ^ 2}, {x, -3, 3}, {y, -3, 3}, StreamPoints -> 16, StreamScale -> 0.07, StreamColorFunction -> None, StreamStyle -> ColorData["SolarColors"][0.3i[[1]]]]], values]stackPlots[plots2D : {__Graphics}, dh_, o : OptionsPattern[Graphics3D]] := Graphics3D[MapIndexed[Function[{g, index}, g[[1]] /. Arrow[v2d_] :> Arrow[v2d /. {x_ ? NumericQ, y_ ? NumericQ} :> {x, y, dh index[[1]]}]], plots2D], o]plotSpacing = 5;
stackPlots[plots, plotSpacing, Axes -> True, Boxed -> False, Ticks -> {Automatic, Automatic, MapIndexed[{plotSpacing#2[[1]], Row[{"λ = ", #1}]}&, values]}]Specify the geometry for a fluid flow:
Ω = RegionUnion[Rectangle[{0, 0.01}, {0.02, 0.02}], Rectangle[{0.02, 0}, {0.08, 0.03}], Rectangle[{0.08, 0}, {0.1, 0.01}], Rectangle[{0.08, .02}, {0.1, 0.03}]];
RegionPlot[Ω, AspectRatio -> Automatic]Specify the boundary conditions for a flow that enters at the left-hand channel and exits through the two right-hand channels:
inflowBC = DirichletCondition[{u[x, y] == 4000(y - 0.01)(0.02 - y), v[x, y] == 0}, x == 0];outflowBC = DirichletCondition[p[x, y] == 0, x == 0.1];wallBC = DirichletCondition[{u[x, y] == 0, v[x, y] == 0}, 0 < x < 0.1];bcs = {inflowBC, outflowBC, wallBC};Define the Navier–Stokes equations:
navierstokes = {
Inactive[Div][(-μ Inactive[Grad][u[x, y], {x, y}]), {x, y}] + ρ {u[x, y], v[x, y]}.Inactive[Grad][u[x, y], {x, y}] + p^(1, 0)[x, y] == 0,
Inactive[Div][(-μ Inactive[Grad][v[x, y], {x, y}]), {x, y}] + ρ {u[x, y], v[x, y]}.Inactive[Grad][v[x, y], {x, y}] + p^(0, 1)[x, y] == 0,
u^(1, 0)[x, y] + v^(0, 1)[x, y] == 0} /. {ρ -> 1, μ -> 2 10^-5};Use the finite element method to solve for the steady flow velocities and pressure:
{uVel, vVel, pressure} = NDSolveValue[{navierstokes, bcs}, {u, v, p}, {x, y}∈Ω, Method -> {"FiniteElement", "InterpolationOrder" -> {u -> 2, v -> 2, p -> 1}, "MeshOptions" -> {"MaxCellMeasure" -> 0.00000025}}];Use DensityPlot to plot the pressure and StreamPlot to plot the flow:
Show[
DensityPlot[pressure[x, y], {x, y}∈uVel["ElementMesh"], PlotRange -> All, Frame -> None, Axes -> None, AspectRatio -> Automatic, ColorFunction -> "DeepSeaColors", PlotLegends -> Placed[BarLegend[Automatic, LegendLabel -> Placed["pressure", Above]], Above]], StreamPlot[{uVel[x, y], vVel[x, y]}, {x, y}∈Ω, AspectRatio -> Automatic, StreamColorFunction -> "SolarColors", PlotLegends -> BarLegend[Automatic, LegendLabel -> Placed["speed", Below]], StreamPoints -> Fine], ImageSize -> Medium
]Properties & Relations (11)
Use ListStreamPlot for plotting data:
data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.2}, {y, -3, 3, 0.2}];ListStreamPlot[data]Use VectorPlot to plot with vectors instead of streamlines:
VectorPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use ListVectorPlot to generate a plot based on data:
data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.1}, {y, -3, 3, 0.1}];ListVectorPlot[data]Use StreamPlot3D to plot streamlines of 3D vector fields:
StreamPlot3D[{z, -x, y}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]Use ListStreamPlot3D to plot streamlines based on data:
data = Table[{z, -x, y}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}];ListStreamPlot3D[data]Use StreamDensityPlot to add a density plot of the scalar field:
StreamDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use VectorDensityPlot to plot vectors instead of streamlines:
VectorDensityPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use ListStreamDensityPlot to generate a plot based on data:
data = Table[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3, 0.1}, {y, -3, 3, 0.1}];ListStreamDensityPlot[data]Use ListVectorDensityPlot to plot arrows instead of streamlines:
ListVectorDensityPlot[data]Use LineIntegralConvolutionPlot to plot the line integral convolution of a vector field:
LineIntegralConvolutionPlot[{-1 - x ^ 2 + y, 1 + x - y ^ 2}, {x, -3, 3}, {y, -3, 3}]Use VectorDisplacementPlot to visualize the deformation of a region associated with a displacement vector field:
VectorDisplacementPlot[{y, x - x^3}, {x, y}∈Disk[], VectorPoints -> Automatic]Use ListVectorDisplacementPlot to visualize the same deformation based on data:
data = Table[{{x, y} = RandomReal[{-1, 1}, {2}], {y, x - x ^ 3}}, {300}];ListVectorDisplacementPlot[data, Disk[], VectorPoints -> Automatic]Use VectorPlot3D to visualize 3D vector fields:
VectorPlot3D[{x, y, z}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]Use ListVectorPlot3D to generate a plot based on data:
data = Table[{x, y, z}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}];ListVectorPlot3D[data]Plot vectors on surfaces with SliceVectorPlot3D:
SliceVectorPlot3D[{-y, x, z}, "CenterSphere", {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]data = Table[{-y, x, z}, {x, -1, 1, 0.1}, {y, -1, 1, 0.1}, {z, -1, 1, 0.1}];ListSliceVectorPlot3D[data, "CenterSphere"]Use VectorDisplacementPlot3D to visualize the deformation of a 3D region associated with a displacement vector field:
VectorDisplacementPlot3D[{y, x, -z}, {x, 0, 1}, {y, 0, 1}, {z, 0, 1}, VectorPoints -> "Boundary"]Use ListVectorDisplacementPlot3D to visualize the same deformation based on data:
data = Table[{{x, y, z} = RandomReal[{0, 1}, {3}], {y, x, -z}}, {300}];ListVectorDisplacementPlot3D[data, Cuboid[], VectorPoints -> "Boundary"]Plot a complex function as a vector field using streamlines:
ComplexStreamPlot[z^2, {z, 2}]Use vectors instead of streamlines:
ComplexVectorPlot[z^2, {z, 2}]Use GeoVectorPlot to plot vectors on a map:
GeoVectorPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567},
{-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851},
{7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864},
{ ... 904, "AngularDegrees"]},
{0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]},
{0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]},
{0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]Use GeoStreamPlot to plot streamlines instead of vectors:
GeoStreamPlot[GeoVector[GeoPosition[{{-54.79801473961214, -111.85053058521567},
{-65.56940402358214, 162.89657500795147}, {-81.67990688759895, -93.36222177594851},
{7.785750774919734, 95.44840765141487}, {-6.86571958448036, -40.946398330539864},
{ ... 904, "AngularDegrees"]},
{0.9366099079317551, Quantity[357.70482317743733, "AngularDegrees"]},
{0.8256817194791912, Quantity[242.07227508889662, "AngularDegrees"]},
{0.2661401145642981, Quantity[152.90003252279325, "AngularDegrees"]}}]]Text
Wolfram Research (2008), StreamPlot, Wolfram Language function, https://reference.wolfram.com/language/ref/StreamPlot.html (updated 2022).
CMS
Wolfram Language. 2008. "StreamPlot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/StreamPlot.html.
APA
Wolfram Language. (2008). StreamPlot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StreamPlot.html