Wolfram Language & System Documentation Center

Tan

Tan[z]

gives the tangent of .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
The argument of Tan is assumed to be in radians. (Multiply by Degree to convert from degrees.)
Sin[z]/Cos[z] is automatically converted to Tan[z]. TrigFactorList[expr] does decomposition.
Tan is automatically evaluated when its argument is a simple rational multiple of ; for more complicated rational multiples, FunctionExpand can sometimes be used.
For certain special arguments, Tan automatically evaluates to exact values.
Tan can be evaluated to arbitrary numerical precision.
Tan automatically threads over lists. »
Tan can be used with Interval and CenteredInterval objects. »

Background & Context

Tan is the tangent function, which is one of the basic functions encountered in trigonometry. Tan[x] is defined as the ratio of the corresponding sine and cosine functions: . The equivalent schoolbook definition of the tangent of an angle in a right triangle is the ratio of the length of the leg opposite to the length of the leg adjacent to it.
Tan automatically evaluates to exact values when its argument is a simple rational multiple of . For more complicated rational multiples, FunctionExpand can sometimes be used to obtain an explicit exact value. TrigFactorList can be used to factor expressions involving Tan into terms containing Sin and Cos. To specify an argument using an angle measured in degrees, the symbol Degree can be used as a multiplier (e.g. Tan[30 Degree]). When given exact numeric expressions as arguments, Tan may be evaluated to arbitrary numeric precision. Other operations useful for manipulation of symbolic expressions involving Tan include TrigToExp, TrigExpand, Simplify, and FullSimplify.
Tan threads element-wise over lists and matrices. In contrast, MatrixFunction can be used to give the tangent of a square matrix (i.e. the power series for the tangent function with ordinary powers replaced by matrix powers) as opposed to the tangent of the individual matrix elements.
Tan is periodic with period , as reported by FunctionPeriod. Tan satisfies the identity , which is equivalent to the Pythagorean theorem. The definition of the tangent function is extended to complex arguments using the definition , where is the base of the natural logarithm. Tan has poles at values for an integer and evaluates to ComplexInfinity at these points. Tan[z] has series expansion $sum_(k=0)^infty((-1)^(k-1) 2^(2 k)(2^(2k)-1) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ about the origin that may be expressed in terms of the Bernoulli numbers BernoulliB.
The inverse function of Tan is ArcTan. The hyperbolic tangent is given by Tanh. Other related mathematical functions include Cot.

Examples

open all close all

Basic Examples (6)

The argument is given in radians:

Wolfram Language code: Tan[Pi / 6]

Use Degree to specify an argument in degrees:

Wolfram Language code: Tan[30Degree]

Plot over a subset of the reals:

Wolfram Language code: Plot[Tan[x], {x, 0, 2Pi}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Tan[z], {z, -π - 2 I, π + 2 I}, PlotLegends -> Automatic, PlotRange -> {-2π, 2π}]

Series expansion at 0:

Wolfram Language code: Series[Tan[x], {x, 0, 10}]

Asymptotic expansion at a singular point:

Wolfram Language code: Series[Tan[x], {x, π / 2, 5}]

Scope (46)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: Tan[1.2]

Evaluate to high precision:

Wolfram Language code: N[Tan[12 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Tan[1.20000000000000000000000]

Tan can take complex number inputs:

Wolfram Language code: Tan[2.5 + I]

Evaluate Tan efficiently at high precision:

Wolfram Language code: Tan[1.2`500]//Timing

Wolfram Language code: Tan[1.2`100000];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: Tan[ {{5π / 6, π}, {π / 3, -π}}]

Or compute the matrix Tan function using MatrixFunction:

Wolfram Language code: MatrixFunction[Tan[#]&, {{5π / 6, π}, {π / 3, -π}}]

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: Tan[Interval[{0, π / 3}]]

Wolfram Language code: Tan[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Tan[CenteredInterval[2 + 3I, (1 + I) / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: Tan[Around[2, 0.02]]

Specific Values (5)

Values of Tan at fixed points:

Wolfram Language code: Table[Tan[n (π/6)], {n, -2, 2}]

Values at infinity:

Wolfram Language code: Tan[Infinity]

Wolfram Language code: Tan[ComplexInfinity]

Zeros of Tan:

Wolfram Language code: Assuming[m∈Integers, Refine[Tan[π m]]]

Find one zero using Solve:

Wolfram Language code: sol = Solve[Tan[x] == 0 && -(π/2) < x < (π/2), x]

Substitute in the result:

Wolfram Language code: xzero = x /. First[sol]

Visualize the result:

Wolfram Language code: Plot[Tan[x], {x, -π / 2, π / 2}, Epilog -> Style[Point[{xzero, Tan[xzero]}], PointSize[Large], Red]]

Singular points of Tan:

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Tan[π ((1/2) + m)]]]]

Simple, exact values are generated automatically:

Wolfram Language code: Tan[Pi / 5]

More complicated cases require explicit use of FunctionExpand:

Wolfram Language code: Tan[Pi / 8]

Wolfram Language code: FunctionExpand[%]

Visualization (3)

Plot the Tan function:

Wolfram Language code: Plot[Tan[x], {x, -π, π}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[Tan[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[Tan[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

Polar plot with :

Wolfram Language code:

Table[PolarPlot[Tan[k ϕ], {ϕ, -π, π}, Frame -> True, Exclusions -> All, FrameTicks -> {{{-1, -0.5, 0, 0.5, 1}, None}, {{-1, -0.5, 0, 0.5, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-1, 1}, {-1, 1}}], {k, 1, 4}]

Function Properties (13)

Real domain of Tan:

Wolfram Language code: FunctionDomain[Tan[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[Tan[z], z, Complexes]

Tan achieves all real values:

Wolfram Language code: FunctionRange[Tan[x], x, y]

Tan is a periodic function with a period :

Wolfram Language code: FunctionPeriod[Tan[x], x]

Tan is an odd function:

Wolfram Language code: Tan[-x]

Tan has the mirror property :

Wolfram Language code: FullSimplify[Tan[Conjugate[z]] == Conjugate[Tan[z]]]

Tan is not an analytic function:

Wolfram Language code: FunctionAnalytic[Tan[x], x]

However, it is meromorphic:

Wolfram Language code: FunctionMeromorphic[Tan[x], x]

Tan is monotonic in a specific range:

Wolfram Language code: FunctionMonotonicity[Tan[x], x]

Wolfram Language code: FunctionMonotonicity[{Tan[x], 0 < x < π / 2}, x]

Tan is not injective:

Wolfram Language code: FunctionInjective[Tan[x], x]

Wolfram Language code: Plot[{Tan[x], 1}, {x, -2π, 2π}]

Tan is surjective:

Wolfram Language code: FunctionSurjective[Tan[x], x]

Wolfram Language code: Plot[{Tan[x], 20}, {x, -2π, 2π}]

Tan is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[Tan[x], x]

It has both singularities and discontinuities in points multiple to π/2:

Wolfram Language code: FunctionSingularities[Tan[x], x]

Wolfram Language code: FunctionDiscontinuities[Tan[x], x]

Tan is neither convex nor concave:

Wolfram Language code: FunctionConvexity[Tan[x], x]

TraditionalForm formatting:

Wolfram Language code: Tan[α]//TraditionalForm

Differentiation (3)

First derivative:

Wolfram Language code: D[Tan[x], x]

Higher derivatives:

Wolfram Language code: Table[D[Tan[x], {x, n}], {n, 1, 3}]

Wolfram Language code: Plot[Evaluate[%], {x, -π, π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the derivative:

Wolfram Language code: D[Tan[x], {x, n}]

Wolfram Language code: Table[%, {n, 1, 3}]//Activate//Simplify

Integration (3)

Indefinite integral of Tan:

Wolfram Language code: Integrate[Tan[x], x]

Definite integral of Tan over a period is 0:

Wolfram Language code: Integrate[Tan[x], {x, 0, π}, PrincipalValue -> True]

More integrals:

Wolfram Language code: Integrate[Tan[x]Cos[x], x]

Wolfram Language code: Integrate[Tan[z] ^ a, z]

Series Expansions (3)

Taylor expansion:

Wolfram Language code: Series[Tan[x], {x, 0, 7}]

Plot the first three approximations for Tan around :

Wolfram Language code:

terms = Normal@Table[Series[Tan[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Tan[x], terms}, {x, -(π/2), (π/2)}, PlotRange -> {{-(π/2), (π/2)}, Automatic}]

General term in the series expansion of Tan:

Wolfram Language code: SeriesCoefficient[Tan[x], {x, 0, n}]

Tan can be applied to power series:

Wolfram Language code: Tan[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

Function Identities and Simplifications (6)

Tan of a double angle:

Wolfram Language code: Expand[Tan[2x] , Trig -> True]

Tan of a sum:

Wolfram Language code: Expand[Tan[x + y] , Trig -> True]

Convert multiple‐angle expressions:

Wolfram Language code: TrigExpand[Tan[4x]]

Wolfram Language code: TrigReduce[%]

Convert sums of trigonometric functions to products:

Wolfram Language code: TrigFactor[Tan[x] + Tan[y]]

Expand assuming real variables and :

Wolfram Language code: ComplexExpand[Tan[x + I y]]

Convert to complex exponentials:

Wolfram Language code: TrigToExp[Tan[z]]

Function Representations (4)

Representation through Cot:

Wolfram Language code: Simplify[Cot[(Pi/2) - x]]

Representation through Jacobi functions:

Wolfram Language code: Simplify[JacobiSC[z, 0]]

Wolfram Language code: Simplify[-I JacobiSN[I z, 1]]

Representation through SphericalHarmonicY:

Wolfram Language code: Simplify[Sqrt[2]SphericalHarmonicY[1, -1, θ, 0] / SphericalHarmonicY[1, 0, θ, 0]]

Representation through Mathieu functions:

Wolfram Language code: Simplify[(MathieuS[1, 0, z]/MathieuC[1, 0, z])]

Applications (4)

Generate a plot over the complex argument plane:

Wolfram Language code: Plot3D[Re[Tan[x + I y]], {x, 0, 2Pi}, {y, 0, 3}]

Differential equation solution with a movable singularity:

Wolfram Language code: DSolve[Derivative[1][w][z] - w[z]^2 - 1 == 0, w[z], z]

The tangent function conformally maps a parabola into the unit disk:

Wolfram Language code:

parabola = Table[1 - x ^ 2 / 4 + I x, {x, 0, 20, 1 / 10}];{Graphics[Point[{Re[#], Im[#]}]& /@ parabola, AspectRatio -> 1, Axes -> True], Graphics[Point[{Re[#], Im[#]}]& /@ (Tan[π / 4. Sqrt[parabola]] ^ 2), PlotRange -> All, Axes -> True]}

Pursuit curve in the reference frame of the predator with prey moving half as fast along a line:

Wolfram Language code: s = DSolve[{ℓ'[ϕ] == ℓ[ϕ] (Sin[ϕ] - 2) / Cos[ϕ], ℓ[0] == 1}, ℓ[ϕ], ϕ]//FullSimplify

Wolfram Language code: PolarPlot[Evaluate[ℓ[ϕ] /. s], {ϕ, 0, π / 2}, AspectRatio -> 1]

Properties & Relations (13)

Basic parity and periodicity properties of the tangent function get automatically applied:

Wolfram Language code: Tan[x + 2Pi]

Wolfram Language code: Tan[-x]

Wolfram Language code: Tan[I x]

Wolfram Language code: 1 / Tan[x]

Use TrigFactorList to factor Tan into Sin and Cos:

Wolfram Language code: Sin[x] / Cos[x]

Wolfram Language code: TrigFactorList[Tan[x]]

Complicated expressions containing trigonometric functions do not simplify automatically:

Wolfram Language code: Tan[z] + Cot[z]

Wolfram Language code: Simplify[%]

Simplify under assumptions on parameters:

Wolfram Language code: Tan[-x + k Pi]

Wolfram Language code: Simplify[%, k∈Integers]

Compose with inverse functions:

Wolfram Language code: {Tan[ArcTan[z]], Tan[2ArcTan[z]], Tan[3ArcTan[z]], Tan[4ArcTan[z]]}

Wolfram Language code: FunctionExpand[%]//Together

1 radian is degrees:

Wolfram Language code: Tan[1] == TanDegrees[180 / π]//Simplify

Solve a trigonometric equation:

Wolfram Language code: Reduce[Tan[z]^2 - 2 Tan[z + Pi / 4] == 4, z]

Solve for zeros and poles:

Wolfram Language code: Reduce[Tan[α x + β] == 0, x]

Wolfram Language code: Reduce[1 / Tan[α x + β] == 0, x]

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[Tan[z]^2 + 3 Tan[z + Pi / 6] + z == 4, {z, 2}]

Integrals:

Wolfram Language code: ∫Tan[z]^aⅆz

Tan appears in special cases of many mathematical functions:

Wolfram Language code:

{(MathieuS[1, 0, z]/MathieuC[1, 0, z]), JacobiSC[z, 0], JacobiCS[(π/2) - z, 0], JacobiSN[I z, 1], JacobiNS[(π I/2) - I z, 1], HypergeometricPFQ[{}, {(3/2)}, -z] / HypergeometricPFQ[{}, {(1/2)}, -z], MeijerG[{{}, {}}, {{(1/2)}, {0}}, z] / MeijerG[{{}, {}}, {{-(1/2)}, {0}}, z]}

Calculate residue symbolically and numerically:

Wolfram Language code: Table[Residue[Tan[z]^k, {z, (π/2)}], {k, 5}]

Wolfram Language code: (1/2π I)NIntegrate[Tan[z], {z, (π/2) - (1/4), (π/2) - (I/4), (π/2) + (1/4), (π/2) + (I/4), (π/2) - (1/4)}]

Tan is a numeric function:

Wolfram Language code: Attributes[Tan]

Wolfram Language code: NumericQ[Tan[2 + E]]

Possible Issues (4)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: Tan[10. ^ 30]

With exact input, the answer is correct:

Wolfram Language code: N[Tan[10 ^ 30], 20]

A larger setting for $MaxExtraPrecision is needed:

Wolfram Language code: N[Tan[10 ^ 100], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Tan[10 ^ 100], 20]]

The precision of the output can be much smaller than the precision of the input:

Wolfram Language code: Tan[1.5707963267948966192213216916397514421]

In TraditionalForm, parentheses are needed around the argument:

Wolfram Language code: tan x

Wolfram Language code: tan(x)

Neat Examples (7)

Compute a product of tangents:

Wolfram Language code: Underoverscript[∏, k = 1, n - 1] Tan[z + (k π/n)]

Integrate a function of the tangent:

Wolfram Language code: Integrate[Tan[ArcCot[z]], z]

Plot Tan at integer points:

Wolfram Language code: ArrayPlot[Table[ArcTan[Abs[Tan[x y]]], {x, -20, 20}, {y, -20, 20}]]

Give a nested radical representation:

Wolfram Language code: Tan[(π/2^12)]//FunctionExpand

The continued fraction is highly regular:

Wolfram Language code: ContinuedFraction[Tan[1], 22]

Cot[n] is a transcendental number at nonzero integer n:

Wolfram Language code: Element[Tan[1], Algebraics]

Plot a 2D function of tangent:

Wolfram Language code:

Plot3D[Tan[y ^ 2 - x ^ 3 + 3 x - 3], {x, -2, 2}, {y, -2, 2}, Exclusions -> {Cos[y ^ 2 - x ^ 3 + 3 x - 3] == 0}, PlotPoints -> 30, Mesh -> None]

Top

More Learning

Tech Support

Data Science, Finance & Business

Engineering

Science & Technology

Technology for Education

Education Initiatives

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Tan

Details

Background & Context

Examples

Basic Examples (6)

Scope (46)

Numerical Evaluation (6)

Specific Values (5)

Visualization (3)

Function Properties (13)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (6)

Function Representations (4)

Applications (4)

Properties & Relations (13)

Possible Issues (4)

Neat Examples (7)

Text

CMS

APA

BibTeX

BibLaTeX

Tan

Details

Background & Context

Examples

Basic Examples (6)

Scope (46)

Numerical Evaluation (6)

Specific Values (5)

Visualization (3)

Function Properties (13)

Differentiation (3)

Integration (3)

Series Expansions (3)

Function Identities and Simplifications (6)

Function Representations (4)

Applications (4)

Properties & Relations (13)

Possible Issues (4)

Neat Examples (7)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX